recopier ou regrouper plusieurs colonnes en 1 seul

[breakers]

bonjour à tous !

je suis devant un dilemne, je souhaite afin de me simplifier la vie regrouper de façon automatique plusieurs colonnes considérer comme fixe (en gros colonne C, F et ainsi de suite) mais avec un nombre de cellules variable, dans une autre feuille en colonne A le tout à la suite de façon verticale et non horizontale !

cela est il possible ?

je reste à votre dispo si le fichier n'est pas assez clair.

un grand merci par avance pour votre aide !!

 

[breakers]

recopier ou regrouper plusieurs colonnes en 1 seul [RESOLU]

yep

je viens de trouver ce bout de code qui m'irait bien, mais comment rajouter dedans et surtout ou pour qu'il fasse un copier valeur ?
voici le code :

Sub copiecolonne()

Dim Ligne As Long, I As Integer
Dim Colonnes
Sheets("SUIVI QTE").Select
  Colonnes = Array("a", "D", "g")
  Ligne = Range("eo" & Rows.Count).End(xlUp).Row
  If Ligne > 1 Then Ligne = Ligne + 1
  For I = 0 To UBound(Colonnes)
    Range(Cells(1, Colonnes(I)), Cells(Cells(Rows.Count, Colonnes(I)).End(xlUp).Row, Colonnes(I))).Copy Range("eo" & Ligne)
    Ligne = Range("L" & Rows.Count).End(xlUp).Row + 1
  Next I
End Sub

merci d'avance

 

[Caillou]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

Bonjour,

Essayes la macro (bouton Go) dans le fichier joint et tiens moi au courant.

Caillou

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

re et re

je viens de penser en voulant le tester qu'il faut aussi que la macro efface la colonne "eo" avant de s'éxecuter sinon elle me recopie les 1eres colonnes plusieurs fois.

merci d'avance si vous connaissez ces bouts de code.

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

hello !

merci pour ta reponse c'est parfait !

en gros tu défini si je comprend bien les colonnes etc avec i j et k ?

et cela recopie tant qu'une valeur et trouver dans la colonne ? genre colonne a puis d etcc jusqu'a ce qu'il ne trouve plus rien ?

 

[Caillou]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

oui en gros c'est ça.
d'où le k=k+3 pour recopier toutes les 3 colonnes !

Caillou

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

par contre dernière question peut on accélerer son fonctionnement ?, car à termes on parle de 600000 lignes en gros a recopier.......

merci 🙂

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

ou eviter qu'il calcul peut être a chaque copie enfin bref tu vois ce que je veux dire ?

 

[Caillou]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

le fichier étant au format xls, la taille de la feuille de calcul est limitée à 65536 lignes !!!!!
pour la vitesse je fais un test

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

faut convertir le fichier en xlsm ?

 

[Caillou]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

oui il faut convertir en xlsm pour avoir environ 1 million de lignes par feuille

je viens de faire un test sur plus d'1 million de lignes ; verdict 45 secondes !

voici le code tres legerement modifié :

Sub classeur_breakers()
  Dim i As Long, j As Long, k As Integer
  Dim fQ As Worksheet, fR As Worksheet
  
  Set fQ = Worksheets("suivi qté")
  Set fR = Worksheets("recherche")
  
  fR.Range("G3") = Time
  
  Application.ScreenUpdating = False
  Application.Calculation = xlCalculationManual
  
  i = 2         'N° ligne feuille Qté
  j = 1         'N° ligne feuille Recherche
  k = 3         'N° colonne feuille Recherche
  
  With fR
    Do While Not IsEmpty(fQ.Cells(i, k))
      Do While Not IsEmpty(fQ.Cells(i, k))
        .Cells(j, 1) = fQ.Cells(i, k)
        i = i + 1
        j = j + 1
      Loop
      i = 2
      k = k + 3
    Loop
  End With

  fR.Range("G4") = Time

  Application.ScreenUpdating = True
  Application.Calculation = xlCalculationAutomatic
  
End Sub

Caillou

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

re !

que dire à part un grand merci pour ton aide !!!!!

grace à toi je vais avoir un sacré gain de temps !

 

[breakers]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

euh dernière question c'est quoi
fR.Range("G3") = Time
fR.Range("G4") = Time

afin de bien comprendre ta macro 🙂

 

[Caillou]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

ça sert à rien ! tu peux supprimer ces 2 lignes.
j'avais mis pour avoir l'heure au debut puis à la fin du traitement comme ça, je pouvais voir la duréee du traitement

 

[Roland_M]

Re : recopier ou regrouper plusieurs colonnes en 1 seul

bonjour à tous,

ne serait-ce pas plus rapide de copier des champs complets plutôt que des cellules une à une !?
comme ceci:

Sub classeur_breakers()
Dim PremLigQ&, DernLigQ&, NoColQ%, PasColQ&, NoColR&
  
fQ$ = "suivi qté"
fR$ = "recherche"
NoColQ = 3: PasColQ = 3: PremLigQ = 2: NoColR = 1

Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual

Sheets(fQ$).Select 'active le feuille de données à copier !
DernLigR = 1
Do While Not IsEmpty(Cells(PremLigQ, NoColQ))
   DernLigQ = Columns(NoColQ).Rows(Rows.Count).End(xlUp).Row
   Application.CutCopyMode = False
   Range(Cells(PremLigQ, NoColQ), Cells(DernLigQ, NoColQ)).Copy
   Sheets(fR$).Cells(DernLigR, NoColR).PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
   DoEvents
   DernLigR = Sheets(fR$).Columns(NoColR).Rows(Rows.Count).End(xlUp).Row + 1
   NoColQ = NoColQ + PasColQ
Loop

Sheets(fR$).Select: Range("A1").Select
Application.CutCopyMode = False
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub