Recherchev ??

[altinea]

Bonsoir, je cherche a récupérer des infos les unes à la suite des autres et les transferer sur un autre document.
J'ai essayé avec recherchev mais à priori ce n'est pas la bonne solution si vous pouviez m'aider merci beaucoup

 

[R@chid]

Re : Recherchev ??

Bonjour,
en H3,

=SIERREUR(INDEX(B$1:B$7;PETITE.VALEUR(SI(A$1:A$7=E$2;LIGNE(A$1:A$7));LIGNES($3:3)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

@ + +

 

[altinea]

Re : Recherchev ??

merci R@chid, je joins à nouveau le fichier car les infos à rechercher sont sur une autre feuille, j'ai compris la formules sauf le
LIGNES($3:3)

merci pour ton aide

 

[st007]

Re : Recherchev ??

Bonjour,

Comme çà ?

 

[altinea]

Re : Recherchev ??

Bonjour,
st007, merci pour ton aide mais non c'est pas ce que je recherche en recherchev, je savais faire comme ça le but étant de rapatrier toutes les cellules ou Paris figure devant.
Alors qu'avec recherchev, il n'y a qu'une qui est renvoyée;
R@chid, m'avait fait une proposition qui fonctionne, le seul inconvénient c'est que je ne comprends pas lignes(3:3) afin qu eje puisse l'adapter à mes besoins

 

[st007]

Re : Recherchev ??

Re , lol

La formule de R@chid adaptée en colonne G à partir de G3 ; ah tiens "3" ben oui, tes rechercheV en colonne H

çà va mieux pour LIGNES($3:3) et note bien le "$" seulement devant le premier 3
étire la formule vers le bas

 

[altinea]

Re : Recherchev ??

re, st007, R@chid, le forum, si je suis ton raisonnement cette formule devrait alors me donner des résultats en G3.
En fait en titre de colonne, la colonne G c'est ce que j'obtenais avec recherchev et en H ce que je souhaitais obtenir aucune relation entre les 2.

je réexplique ma demande, pour ce qui est de la formule sur la meme feuille pas de soucis, apr contre dès que je déplace sur une autre feuille, que je vias chercher les infos sur la feuil2, c'est bien là mon souci c'est que je n'ai pas le résultat en fauil1 en G3

merci encore

 

[Chris401]

Re : Recherchev ??

Bonsoir

=SIERREUR(INDEX(Feuil2!$F$1:$F$15;PETITE.VALEUR(SI(Feuil2!$E$9:$E$15=E$2;LIGNE($9:$15));LIGNES($1:1)));"")

Cordialement
Chris

 

[altinea]

Re : Recherchev ??

RE st007, R@chid, Chris401, la formule fonctionne, je voulais te demander il est obligatoire de commencer en F1, ne peux t'on pas commencer sur une autre ligne??
voici ma ligne de commande :
{=SIERREUR(INDEX(MODOP!AI$1:AI$24;PETITE.VALEUR(SI(MODOP!AH$20:AH$24=D$3;LIGNE($20:$24));LIGNES($29:29)));"")}
ce qui m'aurai arrangé en fait c'est de pouvoir démarrer à partir de AI19, mais je pense que le système ne pourras pas identifier le numéro de la ligne s'il ne commence pas en 1?

merci pour ton aide et ta réponse
cordialement

 

[Chris401]

Re : Recherchev ??

Re

Pourquoi est-ce que cela t'arrangerait ?
Je n'en voit pas l'intérêt, mai si tu y tiens :

=SIERREUR(INDEX(MODOP!AI$19:AI$24;PETITE.VALEUR(SI(MODOP!AH$20:AH$24=D$3;LIGNE($20:$24)-18);LIGNES($1:1)));"")

Tu remarqueras que j'ai remis à la fin de la formule LIGNES($1:1) qui équivaut à 1 pour la 1ère cellule dans laquelle se trouve la formule. LIGNES($29:29) retourne 1 également.

En tirant vers le bas, cela devient LIGNES($1:2) ou LIGNES($29:30) qui retourne 2

Chris

 

[altinea]

Re : Recherchev ??

Re, et bien cela m'arrange car au dessus il y a un autre tableau.
un autre élément, lorsque j'insère une nouvelle ligne dans le code LIGNE($20:$24)-18, les nouvelles lignes ne s'incrémentent pas, contrairement à (INDEX(MODOP!AI$19:AI$24, st ce qu'il y aà une solution?

car dans ce tableau, il ne sera pas fixe et je pourrais soit ajouter soit supprimer des ligne d'où l'interret de cette manip.

merci encore

 

[Chris401]

Re : Recherchev ??

Peux-tu essayer :

=SIERREUR(INDEX(MODOP!AI$20:AI$24;PETITE.VALEUR(SI(MODOP!AH$20:AH$24=D$3;LIGNE(MODOP!AH$20:AH$24)-LIGNE(MODOP!AH$20)+1);LIGNES($1:1)));"")

Chris

 

[st007]

Re : Recherchev ??

Je commence à m'y perdre mais bon ...

 

[R@chid]

Re : Recherchev ??

Bonjour @ tous,
Salut altinea, Salut Chris401, Salut st007,
Correction de la formule sur le fichier en post #3.
en G3,

=SIERREUR(INDEX(Feuil2!F$9:F$15;PETITE.VALEUR(SI(Feuil2!E$9:E$15=E$2;LIGNE(INDIRECT("1:"&LIGNES(E$9:E$15))));LIGNES($3:3)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

@ + +

 

[altinea]

Re : Recherchev ??

re,
merci cela fonctionne, je l'installerai demain sur le fichier final et je te dirai, mais en attendant merci beaucoup
bonne soirée