Recherchev ? decaler ? La est la question !

[manwholooklikedude]

Bonjour les topains, ça roule ?

mon fichier faisant 95Mo, je l'ai hébergé là:

Free - Envoyez vos documents



je travaille toujours sur mon petit problème d'EAN, merci pour tous ceux qui ont répondu à mes autres posts..

..Le nouveau problème est le suivant:

il faut en colonne I une formule qui recherche l'EAN13 de la colonne E dans la feuille "EAN produits", et qu'il me mette le nombre de cellules corespondant à cet EAN à coté.

Exemple: il faut qu'il me recherche 4057640224045 , et qu'il me dispose en I les 6 lignes de "EAN produit qui y correspondent..

Bon encore une fois je ne suis pas trés clair mais j'arrive pas à faire mieux !

merci d'avance

 

[Samantha]

Re : Recherchev ? decaler ? La est la question !

Bonsoir,

6 lignes dans une cellule ?

Oh bé alors, là je sais pas faire.

Je verrais mieux un tableau de récap de I à U avec des sommeprod

Je cherche je reviens


Entre temps, pour permettre la lisibilité de ton tableau je verrais mieux une amélioration de tes formules existantes :

• en E :

  =SI(D5="";"";SI(ESTERREUR(CNUM(D5));"la valeur en D ne corresponds pas à un code EAN";CNUM(D5)))[/CODE
  [*]en F : [CODE]=SI(E5="";"";SI(ESTNA(RECHERCHEV(E5;'EAN produits'!$C:$M;10;FAUX));"pas de donnée";(RECHERCHEV(E5;'EAN produits'!$C:$M;10;FAUX))))

• en G :

  =SI(E5="";"";SI(ESTNA(RECHERCHEV(E5;'EAN produits'!$C:$M;11;FAUX));"pas de donnée";RECHERCHEV(E5;'EAN produits'!$C:$M;11;FAUX)))

• en H :

  =SI(F5="";"";SI(ESTERREUR(ADRESSE(F5;4;1;VRAI;"'EAN produits'!"));"pas de donnée";(ADRESSE(F5;4;1;VRAI;"'EAN produits'!"))))

A te lire


Sam

 

[Monique]

Re : Recherchev ? decaler ? La est la question !

Bonjour,

Je pense que ça ne tient pas la route, (ça va être illisible, les résultats en ligne) mais on peut essayer

Colonne D : l'effacer

E5 :
=SI(ESTERR(STXT(B5;5;13)*1);"";STXT(B5;5;13)*1)

F5 :
=SI(OU(E5="";NB.SI('EAN produits'!C:C;E5)=0);"";EQUIV(E5;'EAN produits'!$C:$C;0))

G5 :
=SI(F5="";"";NB.SI('EAN produits'!$C:$C;E5))

H5, pas besoin mais on peut mettre (ne pas ajouter ! ni apostrophes) :
=SI(F5="";"";ADRESSE(F5;4;;;"EAN produits"))

I5 à copier-coller vers la droite :
=SI(OU($F5="";COLONNES($I5:I5)>$G5);"";INDIRECT(ADRESSE($F5+COLONNES($I5:I5)-1;4;;;"EAN produits")))

Puis copier-coller tout ça vers le bas

 

[manwholooklikedude]

Re : Recherchev ? decaler ? La est la question !

merci à tous, c'est vraiment cool !