Rechercher plusieurs lignes

[CB49]

Bonjour,

Mon tableau est organisé de la façon suivante :
Colonne A N°
Colonne B Imputation
Colonne C N° moule
Colonne D Référence
Colonne E Désignation
Colonne F Client
Colonne G Fournisseur
Colonne H Détection
Colonne I Constat
Colonne J Cause racine
Colonne K Type d'action
Colonne L Action

J'ai besoin d'extraire dans une autre feuille : les infos ayant le numéro XXX la colonne A. Mais ce numéro peut être attribué plusieurs fois. J'ai essayé avec recherchev mais il s'arrête à la 1ère ligne. Comment est-ce que je peux faire ? Merci de votre aide.

 

[JCGL]

Re : Rechercher plusieurs lignes

Bonjour à tous,
Bienvenue sur XLD,

Voir le fichier exemple sur Index-Equiv vs Recherchev

A + à tous

 

[Robert]

Re : Rechercher plusieurs lignes

Bonjour CB et bienvenue, bonjour JCGL, bonjour le forum,

Un proposition VBA si ça t'intéresse...

 

[R@chid]

Re : Rechercher plusieurs lignes

Bonsoir CB49 et Bienvenu sur XLD,
Bonsoir JC, Bonsoir Robert,
une variante par formule matricielle si j'ai bien compris la demande...
Amicalement

Edit : Ajout de CB49_2.XLSX
du fait que tu es sur Excel2007 donc on écrit la formule autrement...
Amicalement

 

[CB49]

Re : Rechercher plusieurs lignes

Bonjour

Merci pour le fichier c'est exactement ce que je voulais.

Par contre, je n'y connais rien en VBA. Et je voudrais changer la liste de déroulante par une cellule fixe dans lequel je marque moi-même le numéro.
Quel est la donnée que je dois changer ??

A+

Cécile

 

[Robert]

Re : Rechercher plusieurs lignes

Bonjour le fil, bonjour le forum,

En pièce jointe une version 02 avec la marco événementielle Change si dessous. Tape le code dans O1...

Private Sub Worksheet_Change(ByVal Target As Range)
Dim dl As Long 'déclare la variable dl (Dernière Ligne)
Dim pl As Range 'déclare la variable pl (PLage)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim dest As Range 'déclare la variable dest (cellule de DESTination)
Dim cod As String 'déclare la variable cod (CODe)
Dim r As Range 'déclare la variable r (Recherche)
Dim pa As String 'déclare la variable pa (Première Adresse)

If Target.Address <> "$O$1" Then Exit Sub 'si le changement a lieu ailleurs que dans la cellule O1, sort de la procédure
If Selection.Cells.Count > 1 Then Exit Sub 'si plus d'une seule cellule est sélectionnée, sort de la procédure
Sheets("Feuil2").Range("A1").CurrentRegion.Clear 'efface la plage de cellules contiguës à A1 de l'onglet "Feuil2"
With Sheets("Feuil1") 'prend en compte l'onglet "Feuil1" (à adapter à ton cas)
    dl = .Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne dl de la colonne A
    Set pl = .Range("A2:A" & dl) 'définit la plage pl
End With 'fin de la prise en compte de l'onglet "Feuil1"
cod = CStr(Target.Value) 'définit la variable cod
Set r = pl.Find(cod, , xlValues, xlWhole) 'définit la recherche r
If Not r Is Nothing Then 'condition : si il existe au moins une occurrence
    pa = r.Address 'définit la première adresse trouvée
    Do 'exécute
        With Sheets("Feuil2") 'prend en compte l'onglet "Feuil2" (à adapter à ton cas)
            'définit la cellule de destination
            Set dest = IIf(.Range("A1").Value = "", .Range("A1"), .Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0))
        End With 'fin de la prise en compte de l'onglet "Feuil2"
        Rows(r.Row).Copy dest 'copy et colle la ligne de l'occurrence trouvée dans dest
        Set r = pl.FindNext(r) 'redéfinit la recherche R (occurrence suivante)
    Loop While Not r Is Nothing And r.Address <> pa 'boucle tant qu'il exite de nouvelles occurrences ailleurs qu'en pa
End If 'fin de la condition
End Sub

Le fichier :