Rechercher et afficher par année

[kaki31]

Bonjour;

Dans l'exemple qui suit: je cherche a afficher dans le feuil2 les données a partir de feuil1.

Merci 🙂

 

[Modeste geedee]

Re : Rechercher et afficher par année

Bonsour® kaki31

Dans l'exemple qui suit: je cherche a afficher dans le feuil2 les données a partir de feuil1.

 

[kaki31]

Re : Rechercher et afficher par année

Bonsoir Modeste geedee

Je cherche quelque chose avec formule si c'est possible,

Merci.

 

[david84]

Re : Rechercher et afficher par année

Bonsoir tout le monde,
ci-joint une proposition via macro (filtre avancé) et une autre par formules.
A+

 

[kaki31]

Re : Rechercher et afficher par année

Bonsoir david84

Merci pour votre proposition, mais ma recherche ce fait en feuil2 par Nom H3 puis par année H5 et H7 et H9

Merci.

 

[david84]

Re : Rechercher et afficher par année

Re
Placer en I3 une liste déroulante comportant les années et en H3 celle avec les noms.
à tester :

=SI(LIGNE(1:1)<=SOMME((ANNEE(Feuil1!$B$2:$B$18)=Feuil2!$I$3)*(Feuil1!$A$2:$A$18=Feuil2!$H$3));INDEX(Feuil1!A$2:A$18;PETITE.VALEUR(SI((Feuil1!$A$2:$A$18=Feuil2!$H$3)*(ANNEE(Feuil1!$B$2:$B$18)=Feuil2!$I$3);LIGNE(INDIRECT("1:"&LIGNES(Feuil1!A$2:A$18))));LIGNE(1:1)));"")

Validation matricielle par Ctrl, maj et entrée.
A+

 

[R@chid]

Re : Rechercher et afficher par année

Salut @ tous,
Mets dans les cellules N6, N7, et N8 les annees 2011, 2012 et 2013.
Apres avoir nomme les champs :
Plage_Noms : =Feuil1!$A$2:$A$18
Plage_Dates : =Feuil1!$B$2:$B$18
Plage_Result : =Feuil1!$B$2:$D$18

Pour extraire les noms sans doublons, en P6 :

=SI(LIGNES($6:6)<=SOMME(1/NB.SI(Plage_Noms;Plage_Noms));INDEX(Plage_Noms;MIN(SI(NB.SI(P$5:P5;Plage_Noms)=0;LIGNE(INDIRECT("1:"&LIGNES(Plage_Noms))))));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

Definir un nom de champ comme suite :
ListeNoms_SansDoublons : =DECALER(Feuil2!$P$6;;;SOMMEPROD(N(Feuil2!$P$6:$P$16<>"")))
sert toi de ce nom de champ dynamiques pour la liste de validation en N3

Pour de finir les noms de colonnes du tableau, en A5 :

=CHOISIR(MOD(COLONNE()-1;3)+1;"Date";"Montant";"Ref")

@ tirer vers la droite jusqu'a la colonne L

Formule en A6 :

=SI(MOD(ENT((MOD(COLONNE()-1;12))/3);4)+1<=SOMME((Plage_Noms=$N$3)*(ANNEE(Plage_Dates)=$N6));INDEX(Plage_Result;PETITE.VALEUR(SI((Plage_Noms=$N$3)*(ANNEE(Plage_Dates)=$N6);LIGNE(INDIRECT("1:"&LIGNES(Plage_Noms))));MOD(ENT((MOD(COLONNE()-1;12))/3);4)+1);MOD(COLONNE()-1;3)+1);"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas et vers la droite.

Tu peux Concatener pour mettre les cellules dans une cellules.

Voir PJ, et dis moi combien de "Likes" merites la derniere formule.
Amicalement