Rechercher cellule et copier la ligne

[cockers94]

bonjour

j'ai un soucis sous excel
j'ai plusieurs colonnes avec des données. Sur l'une d'elle je fais une recherche de caractère dans ces cellules,
et lorsque la chaine est détectée, je veux copier la ligne entière sur une autre feuille
(pour l'instant je trouve les cellules, je copie sur l'autre feuille mais seulement les cellules
je n'arrive pas à copier la ligne)

Merci de votre aide

 

[GPLIONEL]

Re : Rechercher cellule et copier la ligne

Bonjour cockers99,

Si tu nous donnais un exemple avec ta macro, on pourrait t'aider !!!

 

[cockers94]

Re : Rechercher cellule et copier la ligne

oups

voici ma macro

Sub Recherche_Chaine()

pointeur = 1
chaine = InputBox("Chaine à chercher", "Recherche")
For i = 1 To Range("A65536").End(xlUp).Row
For J = 1 To Len(chaine)
If InStr(Cells(i, 1), Mid(chaine, J, 1)) = 0 Then GoTo Ligne_Suivante
Next J

Feuil2.Cells(pointeur, 1) = Cells(i, 1)
pointeur = pointeur + 1
Ligne_Suivante: Next i

End Sub

Merci

 

[papapaul]

Re : Rechercher cellule et copier la ligne

🙂 Salut,
Faudrait voir ton code pour savoir ou et comment,

Après tes codes qui détecte les cellules
EntireRow.Copy devrait faire l'affaire.

Un petit fichier serait bien venu.

@+

 

[cockers94]

Re : Rechercher cellule et copier la ligne

J ai mis le fichier et la macro

merci

 

[bqtr]

Re : Rechercher cellule et copier la ligne

Bonjour cockers94, papapaul, GPLIONEL

Si je comprends bien, tu recherches une chaine de caractère à l'intérieur d'une cellule, et non une cellule qui correspond à la chaine.

Teste ceci, sur la base de ton fichier exemple :

Sub recherche()

Dim Tablo, i As Long, K
Dim Chaine As String

Tablo = Sheets("Feuil1").Range("A3:A" & Sheets("Feuil1").Range("A65536").End(xlUp).Row)
Chaine = InputBox("Chaine à rechercher", "Recherche")
If Chaine = "" Then Exit Sub

For i = 1 To UBound(Tablo)
 K = InStr(1, Tablo(i, 1), Chaine)
  If K > 0 Then Sheets("Feuil1").Rows(i + 2).Copy Sheets("Feuil2").Range("A65536").End(xlUp).Offset(1, 0)
Next

End Sub

A+

 

[teodormircea]

Re : Rechercher cellule et copier la ligne

Est il possible de faire la meme chose mai sur plusieurs colonnes et puis sortir les donnes separement

 

[bqtr]

Re : Rechercher cellule et copier la ligne

Re, Bonsoir teodormircea

Test ceci :

Sub recherche2()

Dim Tablo, i As Long, j As Integer, k
Dim Chaine As String

Tablo = Sheets("Feuil3").Range("A3:C" & Sheets("Feuil3").Range("A65536").End(xlUp).Row)
Chaine = InputBox("Chaine à rechercher", "Recherche")
If Chaine = "" Then Exit Sub

For i = 1 To UBound(Tablo, 1)
  For j = 1 To UBound(Tablo, 2)
     k = InStr(1, Tablo(i, j), Chaine)
      If k > 0 Then Sheets("Feuil4").Range("A65536").End(xlUp).Offset(1, 0) = Tablo(i, j)
  Next
Next

End Sub

La plage testée est sur la feuille 3 et a trois colonnes. Les données sont extraites cellule par cellule et vont se placer dans la colonne A de la feuille 4 les unes en dessous des autres.

A+

 

[cockers94]

Re : Rechercher cellule et copier la ligne

Merci Bqtr

ça fonctionne nickel

merci aussi à ceux qui se sont penchés sur la question