XL 2016 recherche via matrices

[eastwick]

Bonjour à toutes et tous,

Un petit fichier valant mieux qu'une longue explication, vous trouverez l'objet de ma requête dans ledit fichier.
Je vous remercie.
Je privilégie les matrices aux VBA pour le moment.

 

[vgendron]

Hello
en PJ deux propositions avec deux formules différentes
TabData, c'est une plage nommée ==> Voir gestionnaire de noms

 

[eastwick]

merci beaucoup

 

[eastwick]

mais comment obtenez vous la colonne A ? Merci

 

[vgendron]

Euh.. la colonne A est une donnée d'entrée: c'est celle que tu as définie.. sinon comment pourrais je savoir quelles lignes il faut garder??

 

[eastwick]

Je me suis mal fait comprendre, il faut retrouver les lignes entières de la base portant la lettre A en colonne F sauf justement la colonne F à extraire des lignes concernées.

 

[job75]

Bonsoir eastwick, vgendron,,

Voyez le fichier joint et cette formule matricielle en A2 :

=SIERREUR(INDEX(base!A:A;PETITE.VALEUR(SI(base!$F$2:$F$100="A";LIGNE(base!A$2:A$100));LIGNE(A1)));"")

A tirer sur les colonnes A:E.

Même chose en F2 pour les colonnes F:I.

A+

 

[mapomme]

Bonsoir à tous,

J'ai utilisé une colonne auxiliaire (qu'on peut masquer) pour minimiser le nombre de calculs matriciels.

Feuille base, on a défini le nom ColonneF dont la définition est :

=DECALER(base!$F$1;1;0;NBVAL(base!$F:$F)-1;1)

Sur la feuille A, en A1, on a saisi la formule suivante qui renvoie le nom de l'onglet:

=STXT(CELLULE("nomfichier";B1);CHERCHE("]";CELLULE("nomfichier";B1))+1;999)

Sur la feuille A, en A2, on a saisi la formule matricielle qui renvoie le numéro de ligne de Base dont F comprend le nom de l'onglet:

=SIERREUR(PETITE.VALEUR(SI(ColonneF=A$1;LIGNE(ColonneF));LIGNES($1:1));"")

Sur la feuille A, en B2, on a saisi une formule renvoyant la valeur de la base (à copier jusqu'en colonne F)

=SI($A2<>"";INDEX(base!A:A;$A2);"")

Sur la feuille A, en G2, on a saisi une formule renvoyant la valeur de la base (à copier jusqu'en colonne J)

=SI($A2<>"";INDEX(base!G:G;$A2);"")

Il suffit de copier les cellules A2:J2 vers le bas jusqu'à obtenir des cellules vides.

Pour les autres feuilles, il suffit de copier la plage A1:J2 de la feuille A vers les autres feuilles.

 

[job75]

Bonjour eastwick, mapomme, le forum,

Juste quelques remarques sur la solution de mapomme :

- sur les colonnes B:J la validation matricielle est inutile et on peut utiliser RECHERCHEV

- la colonne auxiliaire A est inutile si l'une des colonnes de la feuille base est sans doublon.

A+

 

[mapomme]

sur les colonnes B:J la validation matricielle est inutile

Bonjour @job75,

Hé oui, j'ai été emporté par mon élan .