XL 2016 Recherche sur zone

[gg13]

Bonjour,
Je voudrais utiliser une formule qui recherche dans une zone une valeur et renvoie un autre valeur de la même ligne.
Je sais faire pour une recherche sur une colonne mais pas une zone.

Le fichier joint est certainement plus compréhensible que mon explication.
Merci de votre aide.
GG13

 

[sylvanu]

Bonjour GG,
Contrairement à ce que vous affirmez, votre formule ne marche pas.

=EQUIV(J17;$D$4:$D$43;0)

Ne renvoie pas la valeur de la colonne B mais le N° de ligne où cette valeur est trouvée.
Dans votre cas c'est bon puisque en B on trouve le N° de ligne du tableau.
Regardez en PJ j'ai mis 1234 en B21. 🙂
La bonne formule peut être :

=INDEX(B4:B43;EQUIV(I25;D4:D43;0))

EQUIV (EQUIV, fonction) - Support Microsoft

Comment utiliser la fonction MATCH dans Excel pour rechercher un élément spécifié dans une plage de cellules, en retournant la position relative de cet élément dans la plage.

support.microsoft.com

INDEX (INDEX, fonction) - Support Microsoft

Comment utiliser la fonction INDEX dans Excel pour renvoyer une valeur ou une référence à une valeur dans un tableau ou une plage.

support.microsoft.com

 

[gg13]

Sylvanu
Merci pour ces explications.
Mais la recherche doit se faire sur une zone et pas une colonne.
La valeur rechercher est dans une cellule de la zone C4:E43 sans savoir laquelle.
GG13

 

[sylvanu]

Re,
Il y a peut être plus simple mais cette formule est ok :

=SIERREUR(INDEX($B$4:$B$43;SIERREUR(EQUIV(I25;$C$4:$C$43;0);SIERREUR(EQUIV(I25;$D$4:$D$43;0);SIERREUR(EQUIV(I25;$E$4:$E$43;0);""))));"Non trouvé")

 

[JHA]

Bonjour à tous,

A essayer

JHA

 

[job75]

Bonjour gg13, sylvanu, JHA;

Formule matricielle en I23 :

=INDEX(B:B;PETITE.VALEUR(SI(C4:E43=I22;LIGNE(C4:E43));1))

Formule matricielle en I24 :

=INDEX(C3:E3;EQUIV(I22;INDEX(C:E;PETITE.VALEUR(SI(C4:E43=I22;LIGNE(C4:E43));1););0))

Fonctionnent quel que soit le nombre d'occurrences : c'est celle de la 1ère ligne trouvée qui est récupérée.

A+

 

[gg13]

Merci pour toutes ces solutions qui fonctionnent.

J’ai testé plusieurs formules avant de poster la question et je m’aperçois que je n’aurais
jamais trouvé.
Avec une macro j’arrivais au résultat mais c’est beaucoup plus lourd que vos formules.
Encore merci pour votre aide efficace et rapide.

GG13