Recherche n° ligne et colonne d'une cellule

[JORDAN]

Bonsoir tout le monde, le Forum,

Je suis à la recherche d'une formule pour retrouver le numéro de la ligne et de la colonne de la plus grande valeur d'un tableau.
J'ai bien essayer ceci mais erreur dans la formule

=COLONNE(GRANDE.VALEUR(B20:F26;1))
=LIGNE(GRANDE.VALEUR(B20:F26;1))

Par avance merci pour votre aide
Cdt

 

[R@chid]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir,

pour la colonne,

=MIN(SI(B20:F26=MAX(B20:F26);TRANSPOSE(LIGNE(INDIRECT("1:"&COLONNES(B20:F26))))))

pour la ligne,

=MIN(SI(B20:F26=MAX(B20:F26);LIGNE(INDIRECT("1:"&LIGNES(B20:F26)))))

@ valider les 2 formules par Ctrl+Maj+Entree

Amicalement

 

[JORDAN]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir Rachid,

Excellent, merci pour tes formules.
Si je peux me permettre d'abuser de tes compétences, pourrais tu m'expliquer tes formules stp, j'avoue ne pas y comprendre grand chose.
Merci beaucoup
Cdt

 

[R@chid]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir,
Désolé pour les explications c'est pas mon fort, mais l'audit de formule va beaucoup te dire...
Amicalement

 

[JORDAN]

Re : Recherche n° ligne et colonne d'une cellule

oui j'étais en train de le faire mais ce n'est pas vraiment simple
Merci quand même pour ton aide, tu m'as fait le principal, à moi de chercher pour la compréhension maintenant
Cordialement

 

[mapomme]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir JORDAN, R@chid 🙂

Deux autres formules matricielles à recopier vers le bas:
Ligne (en I20 à copier vers le bas):

=ENT(PETITE.VALEUR(SI($B$20:$F$26 = MAX($B$20:$F$26); LIGNE($B$20:$F$26)+ COLONNE($B$20:$F$26)/100000;"");$H20))

Colonne (en J20 à copier vers le bas):

=ARRONDI(100000*MOD(PETITE.VALEUR(SI($B$20:$F$26 = MAX($B$20:$F$26); LIGNE($B$20:$F$26)+ COLONNE($B$20:$F$26)/100000;"");$H20);1);0)

où la colonne H contient les entiers représentant le Nième max du tableau $B$20:$F$26 (On trouve ainsi tous les maximum)

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

Edit v1a : erratum pour formule colonne

 

[R@chid]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir @ tous,
Salut mapomme,
on peut faire les formules très simples comme suite,

Colonne :

=MIN(SI(B20:F26=MAX(B20:F26);COLONNE(B20:F26)-1))

Ligne :

=MIN(SI(B20:F26=MAX(B20:F26);LIGNE(B20:F26)-19))

Toujours Matricielles...

Mais on cas d'ajout de lignes ou colonnes au dessus et @ gauche de tableau il faut les modifier, c'est pour cela j’évite toujours cette écriture...

pour la colonne, on peut écrire,

=MIN(SI(B20:F26=MAX(B20:F26);COLONNE(B20:F26)-COLONNE(A1)))

et on peut ajouter des colonnes @ gauche de tableau sans problème mais je ne l'aime pas je préfère passer par INDIRECT() car cette dernière aussi pose un problème en cas de suppression de la colonne A...

Amicalement

 

[JORDAN]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir,

Merci pour vos compléments d'infos
Cdlt

 

[R@chid]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir @ tous,
pour le fun,
voir PJ
Amicalement

 

[JORDAN]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir tout le monde,

j'ai du pain sur la planche avant de tout comprendre !!! mais ça va me faire progresser

Cdt

 

[R@chid]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir,

tu peux utiliser cette formule pour faire un test sur les combinaisons Ligne/Colonne afin de vérifier qu'il n'y a pas de doublons,

=NB(1/FREQUENCE(EQUIV(I2:I36&J2:J36;I2:I36&J2:J36;0);LIGNE(INDIRECT("1:"&LIGNES(I2:I36)))))

si la valeur renvoyée est inférieure au nombre de valeurs dans le tableau, ça veut dire qu'il y a des doublons et on peut calculer les valeurs en double comme ça ==> NombreDeValeursDansLeTableau-ValeurRenvoyee
le nombre de valeurs de tableau est 35 est la formule renvoie 35 donc tout est correct

Amicalement

 

[JORDAN]

Re : Recherche n° ligne et colonne d'une cellule

Bonsoir, et bientôt bonjour,

Encore une formule de plus à étudier, ça sent la nuit blanche. dur dur au boulot tout à l'heure mais Excel est tellement prenant et passionnant.
Encore merci pour toutes ces formules et infos
Cdt