Recherche H sur 2 conditions

[bibbip35]

Bonsoir à tous

Je pense que la question a du être posé plusieurs fois; mais malgré mes recherches...je n'ai pas su adapter
le code pour effectuer 1 recherche H sur 2 conditions...

Merci d'avance pour votre aide

Bibbip35

 

[jhlamoustache]

Re : Recherche H sur 2 conditions

Bonsoir
Sur la feuille calendrier, saisis 1/1/14 en A 36 ; 1/2/14 en G 36 etc…
Nomme la plage A36 :F36 (janvier14 par exemple) F36L36 fevrier14 etc…
Sur la feuille TRG…
Formule de E4 =SI($B$4="ACTIF";(RECHERCHEV($E$3;fevrier14;3;FAUX));"0")
formule de E5 =SI($B$5="ACTIF";(RECHERCHEV($E$3;fevrier14;4;FAUX));"0")
formule de E6 =SI($B$6="ACTIF";(RECHERCHEV($E$3;fevrier14;4;FAUX));"0")

 

[bibbip35]

Re : Recherche H sur 2 conditions

Merci beaucoup
Mais ca ne pourra pas fonctionner dans mon cas
Car dans ma feuille trg ...les mois change
Aujourd'hui en d3 c est mai mais demain juin

Merci

 

[jhlamoustache]

Re : Recherche H sur 2 conditions

Bonsoir

La cellule D3 ne peut elle pas être convertie en date? ou n'est elle pas une date?

 

[bibbip35]

Re : Recherche H sur 2 conditions

Bonsoir

Je vous confirme que d3 est bien une date mais qui varie
Tous les mois. ..

Merci

 

[mapomme]

Re : Recherche H sur 2 conditions

Bonsoir bibbip35, à tous,

Un essai avec une formule en D4 à recopier vers la gauche et vers le bas:

=SI($B4="ACTIF";INDEX('Calendrier 2014'!$A$36:$BT$36; 1+EQUIV(D$3;'Calendrier 2014'!$A$1:$BT$1;0) +EQUIV($C4;DECALER('Calendrier 2014'!$A$3;0;EQUIV(D$3;'Calendrier 2014'!$A$1:$BT$1;0)+1;1;4);0));0)

Nota: les dates en D3 à O3 sur la feuille "TRG & Tps dispo." doivent être les dates du 1ier de chaque mois (ex 01/06/2014) pour que la recherche dans le tableau de la feuille "Calendrier 2014" aboutisse.

 

[mapomme]

Re : Recherche H sur 2 conditions

Bonsoir bibbip35, à tous,

En supposant que LE1 à LE4 sont toujours dans le même ordre au sein de la ligne 3 du calendrier,
en nommant DateCal la zone 'Calendrier 2014'!$A$1:$BT$1,
en nommant SommeCal la zone 'Calendrier 2014'!$A$36:$BT$36,

alors la formule devient plus lisible et plus courte:

=SI($B4="ACTIF";INDEX(SommeCal;1+EQUIV(D$3;DateCal;0)+EQUIV($C4;{"LE1"."LE2"."LE3"."LE4"} ;0));0)

Rem:
Si on veut autoriser d'autres dates que les 1iers des mois en D3:O3, on peut (v3):
1) définir le nom AnMoisCal avec la définition:

=SI('Calendrier 2014'!$A$1:$BT$1="";"";ANNEE('Calendrier 2014'!$A$1:$BT$1)&MOIS('Calendrier 2014'!$A$1:$BT$1))

2) mettre la formule suivante en D4 puis la recopier vers la droite et le bas:

=SI($B4="ACTIF";INDEX(SommeCal; 1+EQUIV(ANNEE(D$3)&MOIS(D$3);AnMoisCal;0) +EQUIV($C4;{"LE1"."LE2"."LE3"."LE4"};0));0)

 

[bibbip35]

[Résolu] Recherche H sur 2 conditions

Merci a tous les 2
La solution proposée de mapomme fonctionne parfaitement

Chapeau bas...

Bonne journée

p.s. question idiote mais ou indique t on que le post est résolu

 

[mapomme]

Re : Recherche H sur 2 conditions

Bonjour bibbip35,

[...] p.s. question idiote mais ou indique t on que le post est résolu [...]

L'auteur du fil a le droit d'en modifier le titre en rajoutant par exemple "[Résolu]"