recherche en fonction du jour de la semaine

[terpick]

Bonjour,

J'ai trois messages différents à afficher en fonction du jour de la semaine. Comment faire?

- Le message à afficher dans la case B6
- La date est dans la case A1
- Les types de messages dans les cases G1;G2;G3

Merci pour vos astuces.

 

[hoerwind]

Re : recherche en fonction du jour de la semaine

Bonjour,

Tu ne précises pas ce qu'il y a lieu de renvoyer au cas où le jour en A1 serait autre qu'un mardi, jeudi ou samedi.

En supposant que cela ne puisse arriver :

=DECALER(G1;JOURSEM(A1;2)/2-1;)

Si cette formule ne renvoie pas le résultat escompté, un peu plus de précision s'avère indispensable.

 

[R@chid]

Re : recherche en fonction du jour de la semaine

Salut @ tous,
Salut Hoerwind....
Lundi,Mardi : AAAA
Mercredi,Jeudi : BBBB
Vendredi,Samedi : CCCC

=DECALER(G1;PLAFOND(JOURSEM(A1;2)/2;1)-1;)

si ce n'est pas bon il faut revenir par Plus d'explication

 

[terpick]

Re : recherche en fonction du jour de la semaine

Bonsoir le forum,
hoerwind, Rachid, merci pour vos solutions.

En effet, j'ai manqué un point dans mes explications:

- si le jour en A1 est autre que mardi, jeudi ou samedi, alors B6 est vide.

Merci d'avance, A+

 

[R@chid]

Re : recherche en fonction du jour de la semaine

Salut Terpik,
essayer avec :

=CHOISIR(JOURSEM(A1;2);"";G1;"";G2;"";G3;"")

Amicalement

 

[terpick]

Re : recherche en fonction du jour de la semaine

Ah !!! C'est hallucinant, merci Rachid.

Juste une question sur ta formule. Que veut dire le 2 ?

=CHOISIR(JOURSEM(A1;2);"";G1;"";G2;"";G3;"")

Bonne soirée et @+

 

[R@chid]

Re : recherche en fonction du jour de la semaine

Re,
JOURSEM(A1;2) ==> veut dire que le premier jour de la semaine est le Lundi et JOUSEM(A1;1) ou JOURSEM(A1) veut dire que le premier jour de la semaine et le Dimanche.
Donc JOURSEM(A1;2) renvoie :
1 pour Lundi
2 pour Mardi
3 pour Mercredi
etc....
la fonction CHOISIR va choisir le N renvoye par JOURSEM parmis ses arguments on va se trouver entre 1 et 7, le nombre d'arguments que j'ai mis.

=T(CHOISIR(JOURSEM(A1;2);;G1;;G2;;G3;))

=T(CHOISIR(JOURSEM(A1);;;G1;;G2;;G3))

Tu peux comparer maintenant les deux, elles renvoient le meme resultat.
Amicalement

 

[terpick]

Re : recherche en fonction du jour de la semaine

Bonjour,

Rachid, merci pour ton explication.

Tout est claire maintenant !

Bon week-end,

A+