XL 2021 Recherche d'une formule pour trouver la valeur la moins représentée dans une plage

djidji59430 à dit:

Bonjour à tous,

essaye
=INDEX(E1:E4;EQUIV(MIN(NB.SI(E1:E4;E1:E4));NB.SI(E1:E4;E1:E4);0))

E1:E4 plage des valeurs
S'il y a des exæquos, c'est la première valeur qui est affichée

Crdlmt

Cliquez pour agrandir...

job75 à dit:

Bonjour le forum,

La concaténation des ex-aequo ne vous intéresse pas ?

Voici la formule pour éliminer les cellules vides :

Code:

=SIERREUR(JOINDRE.TEXTE(" ; ";VRAI;SI(NB.SI(plage;plage)=PETITE.VALEUR(SI(NON(ESTVIDE(plage));NB.SI(plage;plage));1);plage;""));"")

A+

Cliquez pour agrandir...

bourcier1952 à dit:

Petite précision : je n'ai pas besoin de toutes les valeurs les plus faibles concaténées mais uniquement de la valeur la plus faible.

Cliquez pour agrandir...

=SIERREUR(MIN(SI(NB.SI(plage;plage)=PETITE.VALEUR(SI(ESTNUM(plage);NB.SI(plage;plage));1);plage));"")

job75 à dit:

Je comprends que votre formule recherche une fréquence de 1.

Mais la fréquence minimum peut être 2, 3 ou plus ?

Cliquez pour agrandir...

=LET(
    plg; B4:B14;
    p; FILTRE(plg; plg <> "");
    f; EXCLURE(FREQUENCE(p; p); -1);
    MIN(FILTRE(p; f = MIN(SI(f <> 0; f; ""))))
)

Cousinhub à dit:

Hélas, Exclure non dispo sous 2021...

Cliquez pour agrandir...

=LET(
    plg; B4:B14;
    p; FILTRE(plg; plg <> "");
    f; FREQUENCE(p; p);
    MIN(SI(f = MIN(SI(f <> 0; f; "")); p; ""))
)