XL 2021 Recherche d'une formule pour trouver la valeur la moins représentée dans une plage

[bourcier1952]

Bonjour,
Je recherche une formule pour trouver la valeur la moins représentée dans une plage. Merci de votre aide. Patrick.

 

[djidji59430]

Bonjour à tous,

essaye
=INDEX(E1:E4;EQUIV(MIN(NB.SI(E1:E4;E1:E4));NB.SI(E1:E4;E1:E4);0))

E1:E4 plage des valeurs
S'il y a des exæquos, c'est la première valeur qui est affichée

Crdlmt

 

[job75]

Bonsoir bourcier1952, [edit] bonsoir djidji59430,

Si la plage à étudier est nommée plage utiliser :

=JOINDRE.TEXTE(" ; ";VRAI;SI(NB.SI(plage;plage)=MIN(NB.SI(plage;plage));plage;""))

C'est une formule matricielle mais sur Excel 2021 la validation matricielle n'est pas nécessaire.

A+

 

[bourcier1952]

Bonjour à tous,

essaye
=INDEX(E1:E4;EQUIV(MIN(NB.SI(E1:E4;E1:E4));NB.SI(E1:E4;E1:E4);0))

E1:E4 plage des valeurs
S'il y a des exæquos, c'est la première valeur qui est affichée

Crdlmt

Merci beaucoup de ta réponse.
Petite difficulté supplémentaire : dans la plage, je souhaiterai ignorer les cellules vides.
Comment dois-je modifier la formule pour y parvenir ?
Merci d'avance.
Patrick

 

[job75]

Bonjour le forum,

La concaténation des ex-aequo ne vous intéresse pas ?

Voici la formule pour éliminer les cellules vides :

=SIERREUR(JOINDRE.TEXTE(" ; ";VRAI;SI(NB.SI(plage;plage)=PETITE.VALEUR(SI(NON(ESTVIDE(plage));NB.SI(plage;plage));1);plage;""));"")

A+

 

[bourcier1952]

Bonjour le forum,

La concaténation des ex-aequo ne vous intéresse pas ?

Voici la formule pour éliminer les cellules vides :

=SIERREUR(JOINDRE.TEXTE(" ; ";VRAI;SI(NB.SI(plage;plage)=PETITE.VALEUR(SI(NON(ESTVIDE(plage));NB.SI(plage;plage));1);plage;""));"")

A+

Merci beaucoup de tes réponses.
Petite précision : je n'ai pas besoin de toutes les valeurs les plus faibles concaténées mais uniquement de la valeur la plus faible. Quelle serait alors la formule ? Merci.

 

[job75]

Petite précision : je n'ai pas besoin de toutes les valeurs les plus faibles concaténées mais uniquement de la valeur la plus faible.

Alors utilisez :

=SIERREUR(MIN(SI(NB.SI(plage;plage)=PETITE.VALEUR(SI(ESTNUM(plage);NB.SI(plage;plage));1);plage));"")

 

[djidji59430]

re
=INDEX(E1:E4;EQUIV(AGREGAT(15;6;NB.SI(E1:E4;E1:E4)/(NB.SI(E1:E4;E1:E4)<>0);1);NB.SI(E1:E4;E1:E4);0))

Crdlmt

 

[JFL_XLD]

Bonjour à tous !
Une autre approche ?

=LET(plg;C4:C13;f;FILTRE(plg;plg<>"");MIN(SI(FREQUENCE(f;f)=1;f;"")))

Avec C4:C13 plage des valeurs à analyser.

 

[job75]

Bonjour JFJ_XLD,

Je comprends que votre formule recherche une fréquence de 1.

Mais la fréquence minimum peut être 2, 3 ou plus ?

A+

 

[JFL_XLD]

Bonjour à tous de nouveau !

Je comprends que votre formule recherche une fréquence de 1.

Mais la fréquence minimum peut être 2, 3 ou plus ?

Alors pour une formule plus généraliste, je vous propose de tester :

=LET(
    plg; B4:B14;
    p; FILTRE(plg; plg <> "");
    f; EXCLURE(FREQUENCE(p; p); -1);
    MIN(FILTRE(p; f = MIN(SI(f <> 0; f; ""))))
)

 

[Cousinhub]

Bonjour,
Hello JF ✋
Hélas, Exclure non dispo sous 2021...
Dommage
Bonne journée

 

[JFL_XLD]

Bonjour à tous de nouveau !
Hello Cousinhub 😉

Hélas, Exclure non dispo sous 2021...

Alors pour les environnements chichement dotés (...😇...) :

=LET(
    plg; B4:B14;
    p; FILTRE(plg; plg <> "");
    f; FREQUENCE(p; p);
    MIN(SI(f = MIN(SI(f <> 0; f; "")); p; ""))
)