Recherche du prix en fonction de la date la plus récente&

[clergeon.arnaud@free.fr]

Bonjour à tous.

Mon but est qu'à partir d'un tableau excel comprenant le nom d'une pièce je vienne chercher sont prix le plus récent, sachant que nous l'actualisons tous les mois.

Je vous joins un fichier excel en démonstration, la feuille 1 correspondant à la base de donnée ou toutes les pièces et les prix en fonction des dates sont écrit.
La feuille 2 correspond quand à elle à une sélection de pièces (forme un ensemble pour nous) et sur lequel nous voulons savoir en temps réelle combien il nous coûte, et donc biensur en aillant toujours automatiquement les prix les plus récent.

Merci d'avance à tous ceux qui pourront m'aider.

Cordialement

 

[david84]

Re : Recherche du prix en fonction de la date la plus récente&

Bonjour,
à tester :

=MAX(SI(Feuil1!A$2:A$6=Feuil2!A2;Feuil1!B$2:E$6))

Formule matricielle à valider par Ctrl, Maj et entrée.
A+
Edit : la formule ne convient pas à ta demande, j'y regarde de plus près.
Telles que tes valeurs sont présentées,

=RECHERCHE(9^9;Feuil1!B2:E2)

peut suffire je pense...

 

[david84]

Re : Recherche du prix en fonction de la date la plus récente&

Re
si les fournisseurs de la feuille2 ne sont pas dans le même ordre :

=RECHERCHE(9^9;INDIRECT("Feuil1!"&"B"&EQUIV(A2;Feuil1!A$2:A$6;0)+1&":G"&EQUIV(A2;Feuil1!A$2:A$6;0)+1))

.
A+

 

[R@chid]

Re : Recherche du prix en fonction de la date la plus récente&

Re
si les fournisseurs de la feuille2 ne sont pas dans le même ordre :

=RECHERCHE(9^9;INDIRECT("Feuil1!"&"B"&EQUIV(A2;Feuil1!A$2:A$6;0)+1&":G"&EQUIV(A2;Feuil1!A$2:A$6;0)+1))

.
A+

c'est la formule juste parmis les autres, car MAX(SI()) donne le prix max et ca peut etre le plus ancien et ce que notre ami ne veut pas...
l'Excel avec vous et trop doux n'est pas conseile pour moi du fait que je suis diabetique😀😉
Merci
@+
Rachid

 

[job75]

Re : Recherche du prix en fonction de la date la plus récente&

Bonjour arnaud, salut David et Rachid 🙂

Autre formule, de fait ni plus simple ni plus compliquée que celle de David :

=DECALER(Feuil1!A$1;EQUIV(A2;Feuil1!A:A;0)-1;EQUIV(9^9;DECALER(Feuil1!$1:$1;EQUIV(A2;Feuil1!A:A;0)-1;))-1)

Edit : un petit plus pour David cependant : la sienne utilise 96 octets mémoire, la mienne 100 🙂

A+

 

[R@chid]

Re : Recherche du prix en fonction de la date la plus récente&

salut tout le monde,
une autres plus simple en B2 :

=DECALER(Feuil1!A1;EQUIV(Feuil2!A2;Feuil1!A2:A6;0);NBVAL(Feuil1!B2:E2))

a recopier vers le bas

 

[job75]

Re : Recherche du prix en fonction de la date la plus récente&

Re,

Non, ta formule ne va pas Rachid.

Feuil1!B2:E2 suppose que les fournisseurs sont dans le même ordre dans les 2 feuilles.

Dans ce cas la dernière formule de David au post #2 fait l'affaire :

=RECHERCHE(9^9;Feuil1!B2:E2)

A+

 

[R@chid]

Re : Recherche du prix en fonction de la date la plus récente&

Ah..!!!!!
pardon j'ai pas fait attention

@+
Rachid

 

[job75]

Re : Recherche du prix en fonction de la date la plus récente&

Re,

Ah mais voilà qui est mieux :

=RECHERCHE(9^9;DECALER(Feuil1!$1:$1;EQUIV(A2;Feuil1!A:A;0)-1;))

Elle ne "pèse" que 58 octets.

Mais merci David, cette formule est juste une adaptation de ta dernière formule du post #2.

A+

 

[R@chid]

Re : Recherche du prix en fonction de la date la plus récente&

Salut,
peut etre cellci fonctionne bien :

=DECALER(Feuil1!$A$1;EQUIV(Feuil2!A2;Feuil1!$A$2:$A$6;0);NBVAL(INDIRECT("Feuil1!B"&EQUIV(Feuil2!A2;Feuil1!$A$2:$A$6;0)+1&":"&"E"&EQUIV(Feuil2!A2;Feuil1!$A$2:$A$6;0)+1)))

complique mais ....!

@+
Rachid
Edit : on peut faire aussi plus simple

=DECALER(Feuil1!$A$1;EQUIV(Feuil2!A2;Feuil1!$A$2:$A$6;0);NBVAL(DECALER(Feuil1!$1:$1;EQUIV(Feuil2!A2;Feuil1!$A$2:$A$6;0);))-1)

 

[clergeon.arnaud@free.fr]

Re : Recherche du prix en fonction de la date la plus récente&

Super les gars, c'est vraiment génial. Cela marche à merveille.

Un grand merci à vous 3 pour avoir répondu rapidement.

Salut tout le monde

:-D