Recherche de texte avec fonction matricielle

[SAMWRC]

Bonjour,

J'utilise cette fonction pour des valeurs numeriques, j'aimerais utiliser une fonction similaire pour du texte. Comment puis-je faire ?

"=IF(B2=A,MAX(IF(E:E=K2,IF(F:F=C2,N:N))),"")"

Merci d'avance

 

[Bigfish]

Re : Recherche de texte avec fonction matricielle

Salut,

=IF(B2="A",MAX(IF(E:E=K2,IF(F:F=C2,N:N))),"")

A+ 🙂

 

[SAMWRC]

Re : Recherche de texte avec fonction matricielle

Non non, ce n'est pas cela, pour le A, il s'agit d'une faute de frappe, j'ai remplace ma variable pour que ce soit plus clair. 😉

Ce que je souhaite, c'est que cette formule me retourne une valeur "texte" comme "K", "M", ... La fonction MAX ne s'adapte pas aux chaines de caracteres !

Merci

 

[Bigfish]

Re : Recherche de texte avec fonction matricielle

Re,

ta demande n'est pas claire... j'imagine que si tu as essayé d'utiliser la fonction max c'est que tu recherches quelque chose de maximum mais avec des lettres je ne vois pas !... ou peut etre que tu veux quelque chose capable d'extraire la lettre la plus proche de Z.
Par exemple si ta plage contient :

N1= D
N2 = R
N3 = U

ta formule doit retourner U exact ?

🙂

 

[SAMWRC]

Re : Recherche de texte avec fonction matricielle

J'avoue que c'est pas clair ...

Alors je recommence avec un petit exemple.

A B C

1 10 Bonjour
1 12 Bonsoir
2 23 Au revoir
3 10 Salut

Si je rentre comme parametres A = 1 et B = 10, je veux que l'on me retourne "Bonjour".

J'utilise MAX car je m'en servais pour obtenir des valeurs numeriques mais je ne souhaite pas avoir de valeur maximum dans ce cas precis.

🙂

 

[Tibo]

Re : Recherche de texte avec fonction matricielle

Bonjour,

Une solution avec SOMMEPROD :

=SI(SOMMEPROD((A1:A4=E1)*(B1:B4=F1))=0;"";INDEX(C1:C4;
SOMMEPROD((A1:A4=E1)*(B1:B4=F1)*LIGNE(A1:A4))))

Plage de cellules à adapter

@+

 

[tototiti2008]

Re : Recherche de texte avec fonction matricielle

Bonjour SAMWRC, Bonjour Tibo, Bonjour Bigfish,

après ça, la question est : le couple A = 1 et B = 10 est-il unique dans la liste ?
sans quoi la jolie formule de Tibo risque de ne pas bien fonctionner...

 

[abcd]

Re : Recherche de texte avec fonction matricielle

Bonjour,

Une façon de faire, parmi bien d'autres :

La matrice en A1:C4
=INDIRECT("C"&SOMMEPROD((A1:A4=3)*(B1:B4=10)*LIGNE(1:4))) renvoie Salut

abcd

 

[Tibo]

Re : Recherche de texte avec fonction matricielle

re,

tototiti, effectivement, petit souci si A=1 et B=10 sont présents plusieurs fois.

On revient alors à une vraie matricielle basée sur INDEX / EQUIV :

=SI(ESTNA(EQUIV(D1&"*"&E1;A1:A4&"*"&B1:B4;0));"";
INDEX(C1:C4;EQUIV(D1&"*"&E1;A1:A4&"*"&B1:B4;0)))

Avec en D1 le A et en E1 le B

Matricielle à valider par CTRL + MAJ + ENTREE

@+

 

[SAMWRC]

Re : Recherche de texte avec fonction matricielle

Ok je vais essayer ca, merci beaucoup !

 

[tototiti2008]

Re : Recherche de texte avec fonction matricielle

Bonjour à tous,

Toujours aussi fort, ce Tibo 🙂
ce qui m'ennerve avec les formules matricielles, c'est que je comprend leur logique mais j'ai beaucoup de mal à en faire (sauf trés simple)... je pense que ça viendra, si je m'accroche...