Recherche de mots dans tableau

[chris-57]

Salut à tous !

Je voudrais élaborer une recherche simple d'un mot dans une liste, sans tenir compte des majuscules/minuscules.

On tape le mot dans une cellule [E2], on clique sur un bouton et la macro sélectionne la 1ère cellule contenant ce mot, cela dans une plage spécifiée [E5:E275].

Puis en recliquant sur le même bouton, la macro doit sélectionner la cellule suivante contenant ce mot (comme la recherche inclue dans la barre d'outils, mais sans fenêtre qui s'ouvre)

En fouillant dans le forum, j'ai trouvé ça et je l'ai adapté, mais pas moyen de lui faire sélectionner la cellule suivante contenant ce mot.

Sub RECHERCHER()

Dim X As Range
Dim Valeur As String, FirstAddress As String

Valeur = [E2].Value
If Valeur = "" Then Exit Sub

With [E5:E275]
Set X = .Find(Valeur, LookIn:=xlValues)
If Not X Is Nothing Then
FirstAddress = X.Address
Do
X.Select

Set X = .FindNext(After:=ActiveCell)
Loop While Not X Is Nothing And X.Address <> FirstAddress

End If
End With

If FirstAddress = "" Then [E2].select
End Sub

 

[chris-57]

tentative de UP...

 

[PhiBou]

Bonjour Chris-57, le Forum

Tu mets le bouton à côté de la cellule E2 (CommandButton1)
Tu figes les volets ligne 4

Cette macro dans un module :

Public Pointeur As Integer

Sub RechercheChris()
Dim i As Integer
Pointeur = WorksheetFunction.Max(Pointeur, 5)
For i = Pointeur To 275
If UCase(Cells(i, 5)) = UCase(Range("E2")) Then
Cells(i, 5).Select
Pointeur = i + 1
Exit Sub
End If
Next i
MsgBox "Terminé"
Pointeur = 5
End Sub

Et ceci dans Woorksheet de ta Feuille :

Private Sub CommandButton1_Click()
RechercheChris
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$E$2" Then Pointeur = 5
End Sub

Bonne journée

PhiBou

 

[chris-57]

Effectivement ça fonctionne, mais ça ne retrouve que les cellules contenant le mot seul...

En fait j'aimerai retrouver toutes les cellules contenant ce mot parmis d'autres de la même cellule ; exemple :

liste :
1- ta ta
2 - ta ti
3- to tu
4- tu ti
5- ti to

si je cherche "ti" il doit me sélectionner la ligne 2, au click suivant la 4 puis la 5.

Je sais je sais, je suis quelqu'un de compliqué, mais j'aime ça !

 

[PhiBou]

Re Chris le Forum,

Remplace :

If UCase(Cells(i, 5)) = UCase(Range("E2")) Then

Par :

If InStr(1, UCase(Cells(i, 5)), UCase(Range("E2"))) Then

Bon dimanche

PhiBou

 

[chris-57]

ça fonctionne parfaitement !!!

merci !!!