Microsoft 365 VBA : Commentaire en B, C, D après clic droit dans n'importe quelle cellule de cette plage ?

Créer une discussion
Répondre
  • Initiateur de la discussion Initiateur de la discussion anthoYS
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
anthoYS

anthoYS

XLDnaute Barbatruc
bonjour


l'objectif est de pouvoir dimensionner la case du commentaire prêt à être saisi. et d'afficher une case vierge pour commentaire...
et qu'il n'apparaisse qu'au survol.
pourtant ici, il apparaît le dernier toujours ouvert, or ce n'est pas l'objectif...


Comment faire pour que le fond du commentaire soit blanc par défaut et non jaunâtre ?


voici le code:

VB: 
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    ' Applique aux colonnes B, C, D (2, 3, 4)
    If Target.Column >= 2 And Target.Column <= 4 Then
        Cancel = True ' Annule le menu contextuel
       
        ' Configuration de l'affichage des commentaires
        Application.DisplayCommentIndicator = xlCommentIndicatorOnly
       
        ' Crée un nouveau commentaire si nécessaire
        If Target.Comment Is Nothing Then
            Target.AddComment Text:="" ' Crée un commentaire vide
        End If
       
        ' Rend le commentaire visible et éditable
        Target.Comment.Visible = True
        Target.Comment.Shape.Select ' Active l'édition immédiate
    End If
    If Target.Comment Is Nothing Then
    Target.AddComment Text:=""
    ' Ne pas mettre Target.Comment.Visible = True
End If
' Ne pas forcer l'affichage du commentaire
End Sub


Merci par avance
 

Pièces jointes

Solution
Nicolas JACQUIN
Et un bonus si tu souhaites changer la couleur du texte du com (j'utilise actuellement sur mon calendrier)
je n'ai pas activé mais si tu souhaites

Code: 
Option Explicit
Private lastCmt As Comment

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Const FIRST_COL As Long = 2
    Const LAST_COL  As Long = 4
    
    If Target.Column < FIRST_COL Or Target.Column > LAST_COL Then Exit Sub
    Cancel = True
    Application.DisplayCommentIndicator = xlCommentIndicatorOnly

    If Not lastCmt Is Nothing Then
        If Not lastCmt Is Target.Comment Then lastCmt.Visible = False
        Set lastCmt = Nothing
    End If

    Dim cmt As Comment                     'ou As Object si AddComment2
    If Target.Comment...
Trier par date Trier par votes
Bonjour,

Une idée si j'ai bien compris,

VB: 
Option Explicit
Private lastCmt As Comment

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Column < 2 Or Target.Column > 4 Then Exit Sub
   
    Cancel = True
    Application.DisplayCommentIndicator = xlCommentIndicatorOnly
   
    If Not lastCmt Is Nothing Then
        lastCmt.Visible = False
        Set lastCmt = Nothing
    End If

    If Target.Comment Is Nothing Then
        Target.AddComment "" 'sinon AddComment2 pour Office 365
        With Target.Comment.Shape
            .Width = 180
            .Height = 60
            .Fill.ForeColor.RGB = vbWhite
           ' .Line.Visible = msoFalse
        End With
    End If

    With Target.Comment
        .Visible = True
        .Shape.Select
    End With
   
    Set lastCmt = Target.Comment
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not lastCmt Is Nothing Then
        lastCmt.Visible = False
        Set lastCmt = Nothing
    End If
End Sub
 

Pièces jointes

Vote positif 0 Vote négatif
Bonjour
comment transforme t on les commentaire en postit auto hidden
comme ceci:
VB: 
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    ' Applique aux colonnes B, C, D (2, 3, 4)
    If Target.Column >= 2 And Target.Column <= 4 And Target.Count = 1 Then
        Cancel = True ' Annule le menu contextuel
        
        ' Configuration de l'affichage des commentaires
        Application.DisplayCommentIndicator = False 'il ne s'affiche pas au survol
        
        ' Crée un nouveau commentaire si nécessaire
        If Target.Comment Is Nothing Then
            Target.AddComment Text:="" ' Crée un commentaire vide
        End If
        
        ' Rend le commentaire visible et éditable
        On Error Resume Next
        With Target.Comment
            .Visible = True 'on le met visible d'office (pas besoins du survol)
            With .Shape
                .Width = 200 'on dimensionne le width
                .Height = 150 'on dimensionne le height
                .Select ' Active l'édition immédiate
            End With
        End With
        DoEvents 'ON LAISSE LES EXECUSSIONs AUTRES SE FAIRE UN PEU
        Application.SendKeys " +{Backspace}" 'on tape un espace et un retour en arriere pour que le caret cligonant d'edition soit au debut
        Application.SendKeys "" ' réactive le pavé numérique si besoin
    End If
    ' Ne pas forcer l'affichage du commentaire
End Sub


Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    For Each c In ActiveSheet.Comments
        c.Visible = False
    Next
End Sub
au clickdroit le commentaire est créé (si il n'existe pas) et affiché de force
il est dimensionné
et placer en mode edition immédiatement le curseur clignote
la sélection dans une autre cellule masque les commentaires affichés donc on peut considérer que ca fait office de retractation du commentaire
important le triangle non visible !!! ca bloque l'affichage au survol
terminé
 
Vote positif 0 Vote négatif
Nicolas JACQUIN à dit:
Bonjour,

Une idée si j'ai bien compris,

VB: 
Option Explicit
Private lastCmt As Comment

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Column < 2 Or Target.Column > 4 Then Exit Sub
  
    Cancel = True
    Application.DisplayCommentIndicator = xlCommentIndicatorOnly
  
    If Not lastCmt Is Nothing Then
        lastCmt.Visible = False
        Set lastCmt = Nothing
    End If

    If Target.Comment Is Nothing Then
        Target.AddComment "" 'sinon AddComment2 pour Office 365
        With Target.Comment.Shape
            .Width = 180
            .Height = 60
            .Fill.ForeColor.RGB = vbWhite
           ' .Line.Visible = msoFalse
        End With
    End If

    With Target.Comment
        .Visible = True
        .Shape.Select
    End With
  
    Set lastCmt = Target.Comment
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not lastCmt Is Nothing Then
        lastCmt.Visible = False
        Set lastCmt = Nothing
    End If
End Sub
Cliquez pour agrandir...
C'est exactement ça, merci beaucoup !
 
Vote positif 0 Vote négatif
patricktoulon à dit:
Bonjour
comment transforme t on les commentaire en postit auto hidden
comme ceci:
VB: 
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    ' Applique aux colonnes B, C, D (2, 3, 4)
    If Target.Column >= 2 And Target.Column <= 4 And Target.Count = 1 Then
        Cancel = True ' Annule le menu contextuel
       
        ' Configuration de l'affichage des commentaires
        Application.DisplayCommentIndicator = False 'il ne s'affiche pas au survol
       
        ' Crée un nouveau commentaire si nécessaire
        If Target.Comment Is Nothing Then
            Target.AddComment Text:="" ' Crée un commentaire vide
        End If
       
        ' Rend le commentaire visible et éditable
        On Error Resume Next
        With Target.Comment
            .Visible = True 'on le met visible d'office (pas besoins du survol)
            With .Shape
                .Width = 200 'on dimensionne le width
                .Height = 150 'on dimensionne le height
                .Select ' Active l'édition immédiate
            End With
        End With
        DoEvents 'ON LAISSE LES EXECUSSIONs AUTRES SE FAIRE UN PEU
        Application.SendKeys " +{Backspace}" 'on tape un espace et un retour en arriere pour que le caret cligonant d'edition soit au debut
        Application.SendKeys "" ' réactive le pavé numérique si besoin
    End If
    ' Ne pas forcer l'affichage du commentaire
End Sub


Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    For Each c In ActiveSheet.Comments
        c.Visible = False
    Next
End Sub
au clickdroit le commentaire est créé (si il n'existe pas) et affiché de force
il est dimensionné
et placer en mode edition immédiatement le curseur clignote
la sélection dans une autre cellule masque les commentaires affichés donc on peut considérer que ca fait office de retractation du commentaire
important le triangle non visible !!! ca bloque l'affichage au survol
terminé
Cliquez pour agrandir...
Merci je voudrais un mix des deux svp.

Le problème, c'est que là, il disparaît après quand je change de cellule, le code @Nicolas JACQUIN me convient davantage...

Le souci, c'est qu'il y a débogage, s'il y a clic droit à nouveau, sur la cellule, or je voudrais qu'il permette d'éditer le commentaire existant...



Merci
 
Vote positif 0 Vote négatif
Bonjour à tous

Voici la version corrigée en espérant que ce soit bon et bien expliqué.

VB: 
Option Explicit
Private lastCmt As Comment

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Const FIRST_COL As Long = 2
    Const LAST_COL  As Long = 4
    
    If Target.Column < FIRST_COL Or Target.Column > LAST_COL Then Exit Sub
    Cancel = True
    Application.DisplayCommentIndicator = xlCommentIndicatorOnly

    If Not lastCmt Is Nothing Then
        If Not lastCmt Is Target.Comment Then lastCmt.Visible = False
        Set lastCmt = Nothing
    End If

    Dim cmt As Comment                     'ou As Object si AddComment2
    If Target.Comment Is Nothing Then
        Set cmt = Target.AddComment("")    'AddComment2 pour Office 365 « Comments »
        With cmt.Shape
            .Width = 180   'change la taille ici en largeur
            .Height = 60   'change la taille ici en hauteur
            .Fill.ForeColor.RGB = vbWhite  'fond blanc
            '.Line.Visible = msoFalse       'pas de bordure
        End With
    Else
        Set cmt = Target.Comment
    End If

    On Error Resume Next           'empêche un débordement si déjà sélectionné
    cmt.Visible = True
    cmt.Shape.Select               'place le curseur dans la note
    On Error GoTo 0
    
    Set lastCmt = cmt              'nouvelle « note courante »
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not lastCmt Is Nothing Then
        lastCmt.Visible = False
        Set lastCmt = Nothing
    End If
End Sub
 

Pièces jointes

Vote positif 0 Vote négatif
Et un bonus si tu souhaites changer la couleur du texte du com (j'utilise actuellement sur mon calendrier)
je n'ai pas activé mais si tu souhaites

Code: 
Option Explicit
Private lastCmt As Comment

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Const FIRST_COL As Long = 2
    Const LAST_COL  As Long = 4
    
    If Target.Column < FIRST_COL Or Target.Column > LAST_COL Then Exit Sub
    Cancel = True
    Application.DisplayCommentIndicator = xlCommentIndicatorOnly

    If Not lastCmt Is Nothing Then
        If Not lastCmt Is Target.Comment Then lastCmt.Visible = False
        Set lastCmt = Nothing
    End If

    Dim cmt As Comment                     'ou As Object si AddComment2
    If Target.Comment Is Nothing Then
        Set cmt = Target.AddComment("")    'AddComment2 pour Office 365 « Comments »
        With cmt.Shape
        
        ''''''''BONUS''''''''
        
        '    With .TextFrame
        '        .AutoSize = False
        '        .Characters.Font.Color = RGB(0, 0, 139) ' Bleu foncé (texte)
        '    End With
        
            .Width = 180   'change la taille ici en largeur
            .Height = 60   'change la taille ici en hauteur
            .Fill.ForeColor.RGB = vbWhite  'fond blanc
            '.Line.Visible = msoFalse       'pas de bordure
        End With
    Else
        Set cmt = Target.Comment
    End If

    On Error Resume Next           'empêche un débordement si déjà sélectionné
    cmt.Visible = True
    cmt.Shape.Select               'place le curseur dans la note
    On Error GoTo 0
    
    Set lastCmt = cmt              'nouvelle « note courante »
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not lastCmt Is Nothing Then
        lastCmt.Visible = False
        Set lastCmt = Nothing
    End If
End Sub
 

Pièces jointes

Vote positif 0 Vote négatif
Solution
le select selectionne la shape du ,commentaire c'est tout
faire les 3 sendkeys comme je fait dans mon exemple pour être sur d'avoir le carrêt (tu l'apelle le curseur)clignotant dans le comm si on veut qu'il soit en mode edition
sinon tu est obligé de cliquer dessus pour pourvoir écrire (taper dedans)
 
Vote positif 0 Vote négatif
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

anthoYS
  • Résolu(e)
Microsoft 365 Clic droit en B (Quelle que soit la cellule de cette colonne) : doit créer ou ouvrir une nouvelle note*
2
Réponses
19
Affichages
235
anthoYS
anthoYS
thunder23
  • Résolu(e)
XL 2021 Bug dans code vba
Réponses
8
Affichages
228
thunder23
thunder23
T
  • Résolu(e)
XL 2021 Incompatibilité de type avec un userform
2
Réponses
19
Affichages
899
Bernard38
Bernard38
E
  • Question Question
XL 2013 Erreur de compilation
Réponses
11
Affichages
647
eutrophisation
E
S
  • Question Question
Microsoft 365 Rendre obligatoire le remplissage d'un commentaire
Réponses
2
Affichages
830
sebastien176
S
M
  • Question Question
XL 2013 VBA-Envoyer par email "Plage de cellules collée dans un nouveau classeur en gardant formules de certaines cellules
Réponses
2
Affichages
912
MONTREAL2020
M
anthoYS
  • Résolu(e)
XL 2019 Qu'est-ce qui ne va pas dans le code ... Colorer celulle B en fond vert si "COMPL" en C si date en D, B en fond jaune...
Réponses
1
Affichages
1 K
anthoYS
anthoYS
anthoYS
  • Question Question
Après double clic : délimiter zone de commentaire de (*) ainsi que... (Sujet OK!!!)
Réponses
2
Affichages
994
anthoYS
anthoYS
anthoYS
  • Question Question
Comment préciser de la colonne 3 à 36 si double clic alors insérer commentaire ? [résolu]
Réponses
4
Affichages
1 K
anthoYS
anthoYS
anthoYS
  • Question Question
Colorer de jaune dans un premier clic droit puis un second en vert, puis décolorer, etc.
Réponses
3
Affichages
721
anthoYS
anthoYS
anthoYS
  • Question Question
Colorer les cases par double clic (couleurs différentes à chaque progrès + date jour)
Réponses
9
Affichages
1 K
anthoYS
anthoYS
anthoYS
  • Question Question
[réSoLu] code permettant d'insérer un commentaire par clic droit, non conforme
Réponses
3
Affichages
2 K
anthoYS
anthoYS
anthoYS
  • Question Question
Insérer par clic droit un commentaire dans une plage déterminer
Réponses
1
Affichages
8 K
STephane
S
F
  • Question Question
Insertion Commentaire en auto suivant condition
Réponses
2
Affichages
701
famu
F
anthoYS
  • Question Question
clic droit ne marche plus avec ce code de la feuille. Qui voit la faille ?
Réponses
1
Affichages
12 K
Pierrot93
Pierrot93
klin89
  • Question Question
Conserver la mise en forme dans le commentaire déjà saisi
Réponses
12
Affichages
2 K
klin89
klin89
anthoYS
  • Question Question
[résolu] Code permettant d'ajouter un commentaire préetablit par clic droit
Réponses
2
Affichages
12 K
anthoYS
anthoYS
anthoYS
  • Question Question
Code après clic droit, ligne 1 de A à ZZ... Comment faire svp ? [résolu !]
Réponses
5
Affichages
853
anthoYS
anthoYS
G
  • Question Question
Adapter une macro de Jacques Boisgontier
Réponses
2
Affichages
2 K
georges95
G
C
  • Question Question
Choix de couleure dans une cellule sur clic
Réponses
7
Affichages
2 K
Efgé
Efgé
Retour