Probleme de formule

[Benoit]

Bonsoir,

J' ai une feuille Base où les données viennent s' empiler.Les noms sont dans la colonne C les dates dans la colonne H. Sur la feuille Stats, je mets 2 dates en F5 et H5. Je voudrais savoir à partir de la feuille Stats, le nombre de fois où l' on trouve dans la feuille Base le nom qui est en g57.
Je mets donc en g58 la formule:
=SOMMEPROD((DECALER(BASE!H$1;;;NBVAL(BASE!H:H))>=F5)*(DECALER(BASE!H$1;;;NBVAL(BASE!H:H))<=H5))*(DECALER(BASE!C$1;;;NBVAL(BASE!C:C))=G57)

Mais le résultat est faux. Auriez-vous une idée ?

Merci.

 

[Monique]

Bonjour,

Dans la formule, il y a une parenthèse en trop après H5
et il en manque une après G57
=SOMMEPROD((DECALER(BASE!H$1;;;NBVAL(BASE!H:H))>=F5)*(DECALER(BASE!H$1;;;NBVAL(BASE!H:H))<=H5)*(DECALER(BASE!C$1;;;NBVAL(BASE!C:C))=G57))

Si tu n'as pas le même nb de valeurs en C et en H, ou bien si tu as des lignes vides :
=SOMMEPROD((BASE!H$1:H$60000>=F5)*(BASE!H$1:H$60000<=H5)*(BASE!C$1:C$60000=G57))
sans forcément aller jusqu'à 60000 (tu adaptes)

 

[Benoit]

Bonjour Monique,

Je viens d' appliquer tes formules et le résultat est le même. Pourtant en colonne H de la feuil Base il y a les dates, et en colonne C les noms. Dans les cellules F5 et H5 de la feuil STAT, il y a les dates et le nom est en G57.

Je ne comprends pas.

 

[Benoit]

Je reviens vite pour m' excuser, j' ai trouvé la bavure. Il y avait un espace avant le nom en G57.

Tant que j' y suis, si je veux trouver plusieurs noms par exemple ceux qui sont en G57, H57 ET J57. Je mets quoi à la fin de la première formule ?
=G57+H57+J57?

Merci. Benoit.

 

[Monique]

Bonjour,

Les 3 critères de la colonne C, tu les rassembles à l'intérieur d'une parenthèse, séparés par des +
=SOMMEPROD((DECALER(BASE!H$1;;;NBVAL(BASE!H:H))>=F5)*(DECALER(BASE!H$1;;;NBVAL(BASE!H:H))<=H5)*((DECALER(BASE!C$1;;;NBVAL(BASE!C:C))=G57)+(DECALER(BASE!C$1;;;NBVAL(BASE!C:C))=H57)+(DECALER(BASE!C$1;;;NBVAL(BASE!C:C))=J57)))

En plus facile à lire :
=SOMMEPROD((ColH>=F5)*(ColH<=H5)*((colC=G57)+(ColC=H57)+(ColC=J57)))

Le signe * équivaut au ET des formules conditionnelles,
le signe + équivaut au OU

 

[Benoit]

Bonsoir,

Merci Monique pour ton aide, tu es la reine des formules.

A bientot. Benoit.