prob. macro recherche

[donpopo]

Bonjour le forum,

Je cherche à créer une macro qui me permettrait de rechercher dans une feuille les lignes correspondants à un nom de client précis ET de les afficher dans une autre feuille.

Je tape un nom de client dans une cellule de la feuille1 et, en-dessous, je souhaite voir s'afficher toutes les lignes concernant ce client (lignes reprises sur la feuille2 et représentant les ventes d'une certaine période pour l'ensemble des clients).

Ci-joint un fichier pour mieux comprendre.

Merci de m'aider.

Donpopo

 

[mromain]

Re : prob. macro recherche

bonjour donpopo

voici un "code de recherche" à coller sur la feuille "Feuil1" (clic droit sur l'onglet --> Visualiser le code)

il s'exécute à chaque changement de "client" en F3 et met la liste à jour.

'macro qui se lance à chanque changement d'une cellule dans la feuille
'Target représente la cellule qui vient de changer
Private Sub Worksheet_Change(ByVal Target As Range)
Dim cellRecherche As Range, premAdresse As String
    
    'si ce n'est pas la cellule F3 qui vient du changer, quitter la macro
    If Not Target(1, 1).Address = "$F$3" Then Exit Sub
    
    'nettoyer la zone d'affichage de la racherche
    Range(Range("B6"), Range("B6").End(xlDown)).Resize(, 7).ClearContents
    
    With ThisWorkbook.Sheets("Feuil2")
        'lancer la recherche
        Set cellRecherche = .Columns("B").Find(Target.Text, , xlValues, xlWhole, , , False)
        'si rien n'est trouvé, quitter la macro
        If cellRecherche Is Nothing Then Exit Sub
        premAdresse = cellRecherche.Address
        Do
            'copier la ligne dans "Feuil1"
            cellRecherche.EntireRow.Copy Range("B" & Rows.Count).End(xlUp).Offset(1, -1)
            'chercher la cellule suivante
            Set cellRecherche = .Columns("B").FindNext(cellRecherche)
        Loop Until cellRecherche.Address = premAdresse
    End With
End Sub

a+

 

[donpopo]

Re : prob. macro recherche

Merci mromain,

c'est exactement ce que je cherche.

Mais, petit problème: lorque je vide la cellule "F3", la macro tourne en boucle. Y aurait il un moyen de combler ce petit problème?

Merci d'avance

Donpopo

 

[mromain]

Re : prob. macro recherche

re,

essaye avec ce code :

'macro qui se lance à chanque changement d'une cellule dans la feuille
'Target représente la cellule qui vient de changer
Private Sub Worksheet_Change(ByVal Target As Range)
Dim cellRecherche As Range, premAdresse As String
    
    'si ce n'est pas la cellule F3 qui vient du changer, quitter la macro
    If Not Target(1, 1).Address = "$F$3" Then Exit Sub
    
    'nettoyer la zone d'affichage de la racherche
    Range(Range("B6"), Range("B6").End(xlDown)).Resize(, 7).ClearContents
    
[B]    'si la cellule est vide, quitter la macro
    If Target.Text = vbNullString Then Exit Sub
[/B]    
    With ThisWorkbook.Sheets("Feuil2")
        'lancer la recherche
        Set cellRecherche = .Columns("B").Find(Target.Text, , xlValues, xlWhole, , , False)
        'si rien n'est trouvé, quitter la macro
        If cellRecherche Is Nothing Then Exit Sub
        premAdresse = cellRecherche.Address
        Do
            'copier la ligne dans "Feuil1"
            cellRecherche.EntireRow.Copy Range("B" & Rows.Count).End(xlUp).Offset(1, -1)
            'chercher la cellule suivante
            Set cellRecherche = .Columns("B").FindNext(cellRecherche)
        Loop Until cellRecherche.Address = premAdresse
    End With
End Sub

a+

 

[donpopo]

Re : prob. macro recherche

Génial mromain,

Un grand merci. Cela correspond exactement à mes souhaits.

Donpopo