Plage nommée dynamique valeur absolue

[beann]

Bonjour,

J'ai crée une liste de champ déroulant via validation des données. Cette validation fait référence donc à une plage nommée qui utilise la fonction DECALER pour que cette liste soit dynamique et calculée uniquement sur les données saisies délaissant les cellules vides.

Ci-dessous la formule utilisée pour la plage.
='Decompte temps'!$A$7😀ECALER('Decompte temps'!$H$7;nbligne-1;😉

Mon souci aujourd'hui est que quand je supprime la première ligne, celle inscrite dans la formule, donc ligne 7, la formule ne retrouve plus ses repères et note à la place de $a$7 et $h$7, REF.

J'aimerais savoir comment faire pour l'éviter, pouvoir supprimer cette ligne sans qu'il y ait un dysfonctionnement et que la formule prenne en compte la nouvelle ligne 7.

 

[JCGL]

Re : Plage nommée dynamique valeur absolue

Bonjour à tous,

Peux-tu utiliser les balises (# dans la BO) pour déposer du code ou des formules ?

Il me semble que ton DECALER() ne respecte pas la syntaxe.

A+ à tous

 

[beann]

Re : Plage nommée dynamique valeur absolue

Oui pardon,

='Decompte temps'!$A$7:DECALER('Decompte temps'!$H$7;nbligne-1;;)

Mais ce n'est pas un problème de syntaxe, la formule fonctionne. Sauf pr le problème cité.

 

[Compte Supprimé 979]

Re : Plage nommée dynamique valeur absolue

Bonjour Beann,
Salut JC

La fonction DECALER() est à utiliser comme suit
DECALER(Ref;Lignes;Colonnes;[hauteur];[largeur])

Donc pour moi la formule devrait plutôt être

=DECALER('Decompte temps'!$A$7;;;NbLigne-1;8)

Par contre, si la 1ère ligne est supprimée la référence de la première cellule ne sera plus A7, mais A6, etc ...

A+

 

[Efgé]

Re : Plage nommée dynamique valeur absolue

Bonjour beann, BrunoM45, JCGL 🙂,
Peut être qu'avec un NBVAL, on évitera le problème de suppression de ligne ?

=DECALER('Decompte temps'!$A$7;;;NBVAL('Decompte temps'$A:$A)[COLOR=red][B]-6[/B][/COLOR])

Faute d'exemple le -6 en rouge est à adapter.
Cordialement

 

[beann]

Re : Plage nommée dynamique valeur absolue

En fait nbligne est une de mes plages nommees qui fait appel à la fonction nbval justement. J'aurais peut etre du le préciser.

Si j'entre un peu plus ds le détail, j'ai une 1ere plage "plagecompte" correspondante aux cellules $A$7:$A$65536.

Une 2nde plage "nbligne" qui est une cellule dans laquelle se trouve la formule Nbval(plagecompte).

et la 3e plage donc, "listeplagesource" qui fait référence au code cité:

='Decompte temps'!$A$7:DECALER('Decompte temps'!$H$7;nbligne-1;;)

 

[Guest]

Re : Plage nommée dynamique valeur absolue

Bonjour à tous,

Pour être sûr que la formule retourne quelque chose quoiqu'il advienne des données(sauf suppression de A7):

1 - En incluant l'entête

=DECALER('Decompte temps'!$A$7;;;MAX(1;NBVAL('Decompte temps'!$A$7:$A$65536));2)

2 - Sans l'entête

=DECALER('Decompte temps'!$A$7;1;;MAX(1;NBVAL('Decompte temps'!$A$7:$A$65536)-1);2)

3 - Pour éviter l'erreur en cas de suppression de la ligne A7:

=DECALER(INDIRECT("'Decompte temps'!$A$" & 7);;;MAX(1;NBVAL('Decompte temps'!$A$7:$A$65536));2)

Où 2 est le nombre de colonnes pour l'exemple

A+ tout le monde

 

[beann]

Re : Plage nommée dynamique valeur absolue

Ton code 3 est parfait Hasco.
Un grand bravo et merci! 😉