Numérotation de différentes feuilles dans une cellule

[castor123456]

Bonjour à tous les forumeurs.
Débutant en matière de macro, je sollicite votre savoir faire pour me renseigner. J'ai déjà cherché dans les anciens post mais je n'ai rien trouvé pouvant correspondre. Je suis sous excel 2003. Dans le cadre de mon travail, je dois réaliser un fichier excel permettant de stocker des données toutes les semaines sur une période juillet à début septembre (le nombre de semaine est variable). Toutes les semaines, je crée une nouvelle feuille à partir d'une feuille modèle existante. La 1ère feuille du classeur s'appelle "accueil", la seconde "modèle". Je désirerai, si possible, avoir le code permettant de numéroter chaque feuille créée (hormis la feuille "accueil" et "modèle") dans la cellule A6 de chaque des feuilles respectives. La 1ère feuille créée portera le numéro 01, la 2ème le numéro 02... Le numéro de la nouvelle feuille devra tenir compte de la feuille précédente. Il est possible que je sois amené à supprimer une feuille donc il faudrait que la numérotation se refasse correctement pour qu'il ne manque pas de numéro.
Je ne sais pas si j'ai été clair. n'hésitez pas à me demander des compléments d'information si nécessaire.
Je vous remercie d'avance.

 

[JCGL]

Re : Numérotation de différentes feuilles dans une cellule

Bonjour à tous,

Dans un Module Standard :

Option Explicit

Sub Archivage()
    Sheets("Modèle").Copy After:=Sheets(2)
    With ActiveSheet
        .Name = Format(Sheets.Count - 2, "00")
        .Range("A6") = Format(Sheets.Count - 2, "00")
    End With
    Sheets("Accueil").Select
End Sub

A+ à tous

 

[ROGER2327]

Re : Numérotation de différentes feuilles dans une cellule

Bonjour castor123456, JCGL

À placer dans le module de la feuille "Accueil" (et à associer éventuellement à un bouton sur cette feuille) :

Sub nouvelle()
Dim i&, j&, tmp$, sh As Worksheet, num()
  ReDim num(0)
  num(0) = "Modèle"
  For Each sh In Worksheets
    If sh.Name Like "##" Then
      ReDim Preserve num(UBound(num) + 1)
      num(UBound(num)) = sh.Name
      sh.Tab.ColorIndex = Worksheets("Modèle").Tab.ColorIndex '-4142 = aucune couleur
    End If
  Next
  For i = 1 To UBound(num) - 1
    tmp = num(i)
    For j = i + 1 To UBound(num)
      If num(j) < tmp Then num(i) = num(j): num(j) = tmp: tmp = num(i)
    Next j
  Next i
  For i = 1 To UBound(num)
    If Worksheets(num(i)).Name <> Format(i, "00") Then Exit For
  Next
  Worksheets("Modèle").Copy Before:=Sheets(num(0))
  With ActiveSheet: tmp = Format(i, "00"): .Name = tmp: .Tab.ColorIndex = 33: .Range("A6") = "'" & .Name: End With
  For i = i To UBound(num): Sheets(num(i)).Move Before:=Sheets(num(0)): Next
  Sheets(tmp).Activate 'ou bien :
'  Me.Activate
End Sub

​

ROGER2327
#4984

Mardi 3 Pédale 138 (Saint Ellen, hile, SQ)
7 Ventôse An CCXIX
2011-W08-5T23:57:23Z

 

[kjin]

Re : Numérotation de différentes feuilles dans une cellule

Bonsoir,
Autant capturer l'événement Delete, ou plutot l'appui sur le bouton supprimer du menu feuille, est envisageable, autant le click sur le bouton de confirmation de la boite qui apparait lorsqu'on supprime une feuille...eh bé nada ! Or on peut toujours annuler l'opération...
A+
kjin

 

[castor123456]

Re : Numérotation de différentes feuilles dans une cellule

Les 2 solutions fonctionnent très bien et répondent à ma demande. Je vous en remercie.
PS : je n'aurai jamais réussit à écrire ce genre de code, trop peu de connaissance.