Microsoft 365 Nombre de cellule consécutive avec la valeur zéro

[dearmilady18]

Bonjour à tous,

J'espère que vous allez bien 🙂

Je cherche une formule pour calculer le nombre de cellule consécutive contenant la valeur 0 dans un tableau. J'ai chercher dans le forum, mais je ne trouve rien qui convient. C'est un peu plus complexe qu'un NB.SI.

Je dois calculer le nombre de semaine ou un employé ne travail pas. À chaque semaine je viens dans le tableau pour ajouter le décompte des jours travaillés de la semaine qui s'est terminé. Tant que l'employé ne travail pas, la formule doit compter le nombre de "0" qui s'accumule semaine sur semaine. Dès que la série de 0 est interrompu par une semaine ou l'employé à travaillé, le décompte des semaines sans travail doit retomber à 0.

Je vous joint un exemple. Les jours de travail se compilent dans le colonne D à I et la formule dont j'ai besoin devra être dans la colonne A, celle en rouge. En attendant j'ai inscrit le résultat escompté.

En vous remerciant d'avance pour vos idées!

Dearmilady

 

[njhub]

Bonjour Dearmilady,

Essayez avec la formule suivante:

=SOMME(MIN.SI($D$3:$AW$3;$D4:$AW4;"="&"");SI(C4=0;-MIN.SI($D$3:$AW$3;$D4:$AW4;"="&0);-MAX.SI($D$3:$AW$3;$D4:$AW4;">"&0)-7))/7

😉

 

[JHA]

Bonjour à tous,

Bonjour @njhub et bravo pour cette formule mais max.si et min.si ne sont pas reconnus avec excel 2019, je dois mettre min.si.ens et max.si.ens pour la faire fonctionner.

=SOMME(MIN.SI.ENS($D$3:$AW$3;$D4:$AW4;"="&"");SI(C4=0;-MIN.SI.ENS($D$3:$AW$3;$D4:$AW4;"="&0);-MAX.SI.ENS($D$3:$AW$3;$D4:$AW4;">"&0)-7))/7

JHA

 

[chris]

Bonjour à tous

Un détail : l'expression des critères peut être simplifiée pour ces cas

=SOMME(MIN.SI.ENS($D$3:$AW$3;$D4:$AW4;"");SI(C4=0;-MIN.SI.ENS($D$3:$AW$3;$D4:$AW4;0);-MAX.SI.ENS($D$3:$AW$3;$D4:$AW4;">0")-7))/7

 

[Hasco]

Bonjour le fil,

Une autre qui semble fonctionner :

(AGREGAT(15;6;COLONNE($D$3:$AW$3)-3/($D4:$AW4="");1)-1)-SIERREUR(AGREGAT(14;6;COLONNE($D$3:$AW$3)-3/($D4:$AW4>0);1);0)

Cordialement

 

[dearmilady18]

Un grand merci à tous, ça fonctionne!