ne pas calculer les doublons

[guidub70]

bonjour à tous,

et merci pour vos précieux conseils sur le forum

je souhaite connaitre comment dans un tableau, on ne pas calcul pas des doublon dans le même mois

exemple


A Albert 2/01/09
B Denis 5/01/09
C Jean 6/01/09
A Albert 12/01/09
B Denis 15/01/09

Je souhaite connaitre la formule pour calculer la visite d'albert sur le mois sans le doublon puisque je les vu le 2 et le 12 donc vu 1 fois dans le mois

j'espère avoir été clair,

Merci de vos réponses

A+ Guidub70

 

[BOISGONTIER]

Re : ne pas calculer les doublons

Bonjour,

Voir PJ

=NB(1/FREQUENCE(SI(Nom=D2;EQUIV(MOIS(date);MOIS(date);0));SI(Nom=D2;EQUIV(MOIS(date);MOIS(date);0))))
Valider avec Maj+ctrl+entrée


JB

 

[guidub70]

Re : ne pas calculer les doublons

merci bcp de ta réponse mais elle répond partiellement, car si on attribu une cible a chaque personne je souhaite connaitre si j'ai vu albert en janvier mais seulement mon fichier de départ contient 150 noms avec un ciblage A,B, et C

merci de ton aide

A+ Guidub70

 

[guidub70]

Re : ne pas calculer les doublons

voici le fichier un peu plus clair

merci bcp de ta réponse

A+ guidub70

 

[BOISGONTIER]

Re : ne pas calculer les doublons

Je ne comprends pas

JB

 

[guidub70]

Re : ne pas calculer les doublons

je suis désolé JB, je dois mal m'exprimer...

voici le fichier avec quelques explication, 1000 merci a toi de tes réponses,

A+ guidub70

 

[guidub70]

Re : ne pas calculer les doublons

oups voici le bon fichier, j'espère que cette fois je m'explique correctement

1000 merci...

A+ Guidub70

 

[JHA]

Re : ne pas calculer les doublons

Bonjour guidub, le forum,

Pas tout compris mais en K16, pour connaitre le nombre de albert en Janvier avec A:

=SOMMEPROD(($E$17:$E$40="A")*($F$17:$F$40="Albert")*(MOIS($G$17:$G$40)=1))

JHA

 

[guidub70]

Re : ne pas calculer les doublons

merci bcp JHA, sauf que ta réponse est partielle car j'ai 3 cibles A,B et C avec environ 150 noms donc imagine le travail...
Ya t'il pas une autre solution plus simple, vous les expert d'excel...

merci à toi,

A+ Guidub70

 

[BOISGONTIER]

Re : ne pas calculer les doublons

Voir PJ

=NB(1/FREQUENCE(SI(Cible="A";EQUIV(Nom&MOIS(date);Nom&MOIS(date);0));SI(Cible="A";EQUIV(Nom&MOIS(date);Nom&MOIS(date);0))))
Valider avec Maj+ctrl+entrée

JB

 

[guidub70]

Re : ne pas calculer les doublons

Super, je vient de voir ton message de cet AM cela répond parfaitement à ma demande bravo à toi et encore 1000 merci sauf que si je veux étendre à la ligne 60 par exemple...les champs de cible nom et date comment faire.

A+ Guidub70

 

[BOISGONTIER]

Re : ne pas calculer les doublons

Il faut agrandir les noms de champ ou créer des noms de champ dynamiques.

-Insertion/Nom/Définir
-Cible
=DECALER($A$2;0;0;NBVAL($A:$A)-1)

JB

 

[guidub70]

Re : ne pas calculer les doublons

merci pour tes précieux conseils, j'essai ce soir au calme, car les enfants viennent de rentrer...pas facile de ce concentrer...et je te dit si cela est OK

merci,

A+ Guidub70

 

[JeanMarie]

Re : ne pas calculer les doublons

Bonsoir

On peut simplifier les formules données par JB.

La formule de la cellule F2 devient :

=NB(1/FREQUENCE(SI(Nom=E2;MOIS(date));LIGNE(1:11)))

Je ne vois pas pourquoi tu recherches la position de la valeur MOIS dans la matrice MOIS, il suffit tout bonnement de retourner la valeur MOIS .
C'est la même chose pour la "matrice_intervalles" de la fonction FREQUENCE, dans le cas présent, on parle de mois, Il n'y a que 12 mois. Il suffit de transmettre à cette matrice, une plage de valeur allant de 1 à 11.
Peut importe si il n'y a aucune valeur dans le mois concerné dans le tableau, la belle Gestion d'erreur NB(1/...) fait le reste.

La formule en F8 devient :

=NB(1/FREQUENCE(SI(Cible=E8;EQUIV(Nom&MOIS(date);Nom&MOIS(date);0));LIGNE(1:11)))

Même commentaire sur la plage "matrice_intervalles"

Pour le tableau, il faut savoir :
1) La fonction FREQUENCE est une fonction qui renvoie une série de valeurs, on appelle cette série une matrice.
2) La longueur de la matrice est égale à la longueur de la "matrice_Intervalles". à cette longueur on rajoute une valeur, elle représente les valeurs supérieures à la plus forte valeur de la "matrice_Intervalles" qui se trouveraient dans la plage "tableau_Données"
3) La matrice est sous forme verticale.

Dans le cas de l'exemple :
1) on sélectionne la plage de cellules F21:Q21
2) on colle la formule ci-dessous dans la zone de saisie de la barre d'outils formule.

=TRANSPOSE((FREQUENCE(SI(Nom=$E21;MOIS(date));LIGNE($1:$11))>0)*1)

et on valide la formule par Ctrl+Shift+Entrer

La fonction TRANSPOSE sert pour basculer la matrice sous forme horizontale.

Désolé si les commentaires sur les formules s'adressaient plus à JB.

@+Jean-Marie

 

[guidub70]

Re : ne pas calculer les doublons

il est toujours bon de connaître d'avantage, merci JM pour tes commentaires j'essai d'utiliser tes formules qui me semble plus simple à comprendre et donc utiliser,

1000 merci pour tes précieux conseils,

A+ Guidub70