Ne pas avoir zéro

[Clochard]

Bonjour le Forum,


J'aimerais bien savoir si d'après vous.... avec cette formule

=SI(ESTNA(RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX));"";RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX))

Il est possible, s'il n'y a rien dans la cellule visée... de ne pas avoir 0 comme réponse....

Ne rien avoir serait l'idéal

Merci et bonne journée à toutes et tous du Forum
Clochard

 

[Excel-lent]

Re : Ne pas avoir zéro

Bonsoir Clochard,


Je ne suis pas sûr d'avoir bien compris ta question.

A la première lecture (faute de fichier pour bien te comprendre), ta formule fait déjà ce que tu veux!

Si ta fonction RECHERCHEV ne trouve pas la solution, grâce à ta fonction ESTNA accouplé à "" il te met rien dans ta cellule non?

Personnellement j'utilise ESTERREUR au lieu de ESTNA, mais le résultat doit être identique non? (n'ayant pas ton fichier pour vérifier, je te laisse le soin de le faire 😀)

avec cette formule

=SI(ESTNA(RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX));"";RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX))

Il est possible, s'il n'y a rien dans la cellule visée... de ne pas avoir 0 comme réponse....

Ne rien avoir serait l'idéal

Merci et bonne journée à toutes et tous du Forum
Clochard

A la seconde lecture, après déduction, tu dois donc avoir des cas où ta fonction RECHERCHEV trouve la ligne, mais comme dans la colonne correspondante (la 5ème) est vide, alors il te met 0, alors que toi tu veux "" ???????????

Pourquoi ne pas avoir mis un fichier exemple? grrrr!

Je suppose que tu voulais dire ça?

Si oui, il y a une solution tout bête (a tester quand même avant) :

=SI(RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX)=0;"";SI(ESTNA(RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX));"";RECHERCHEV($G$1&LIGN E()-14;'Rendez-vous'!$B$3:$H$100;5;FAUX)))

Partie non modifié
Partie rajouté

Bonne soirée

 

[Monique]

Re : Ne pas avoir zéro

Bonjour,

On peut masquer les 0 par un format de nombre personnalisé
Un format quelconque suivi de ;;

Standard;;
0;;

ou bien
[=0]"";Standard
[=0]"";0

Ou bien utiliser un format conditionnel

 

[Excel-lent]

Re : Ne pas avoir zéro

Bonsoir Monique, Clochard, le fil,

On peut masquer les 0

également ainsi :
cliquer sur "Outils" / "Options" / onglet "Affichage" / décocher "valeurs zéro" (se trouve dans la zone "fenêtres" en bas au milieu)

(différence avec les solutions proposées par Monique qui ne s'applique pas à une zone précise de ta feuille, celle ci-dessus s'applique à TOUT ton classeur)

Bonne soirée à tous

 

[Monique]

Re : Ne pas avoir zéro

Re,

C’est plus court comme ça :

=SI(NB.SI('Rendez-vous'!$B$3:$B$100;$G$1&LIGNE()-14)=0;"";RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;0))

Si le résultat attendu est du texte, mettre 2 guillemets à la fin de la formule masque les 0
=SI(NB.SI('Rendez-vous'!$B$3:$B$100;$G$1&LIGNE()-14)=0;"";RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;0)&"")

 

[Clochard]

Re : Ne pas avoir zéro

Merci Monique et Excel-lent

J'étais à faire un fichier pour le mettre sur le fil.... mais voilà que Monique me donne la solution à ma demande....

=SI(NB.SI('Rendez-vous'!$B$3:$B$100;$G$1&LIGNE()-14)=0;"";RECHERCHEV($G$1&LIGNE()-14;'Rendez-vous'!$B$3:$H$100;5;0)&"")

est exactement ce que j'espérais

Merci beaucoup Monique et Excel-ent

Votre aide est très appréciée...

Bonne journée
Clochard