Moyenne, max, min et nb selon critère mois

chemist · 2 Février 2011

Bonjour

je cherche les formules pour avoir la moyenne, max, min et nb d'une colonne (B) en fonction des mois de la colonne (A).

J'ai trouvé pour le max mais la même formule ne fonctionne pas pour le min.
le nb fonctionne pas pour janvier mais fonctionne pour les autre mois ?
pour la moyenne j'ai utilisé sommeprod/nb ça fonctionne si nb est bon

Voici un fichier pour mieux comprendre

merci

Tibo · 2 Février 2011

Re : Moyenne, max, min et nb selon critère mois

Bonjour,

Le problème rencontré pour janvier vient du fait que les cellules vides sont considérées comme contenant la valeur 0

Or, pour Excel, en matière de date, le 0 équivaut au 0 janvier 1900, date qui n'existe pas, mais pour laquelle la fonction MOIS retourne 1

Pour le MIN, ça donne cette formule matricielle :

Code:

=MIN(SI(($H$3:$H$1000<>"")*(MOIS($H$3:$H$1000)=B3);$I$3:$I$1000))

validation matricielle par CTRL + MAJ + ENTREE

Pour la moyenne, le même problème se pose. Il faut également vérifier s'il se trouve au moins une donnée pour le mois analysé.

En corrigeant la formule de la colonne NB ainsi :

Code:

=SOMMEPROD((MOIS($H$3:$H$1000)=B3)*($H$3:$H$1000<>""))

La formule MOYENNE devient (en matricielle) :

Code:

=SI(D3=0;"";MOYENNE(SI(($H$3:$H$1000<>"")*(MOIS($H$3:$H$1000)=B3);$I$3:$I$1000)))

En se passant de la colonne NB, la formule MOYENNE devient :

Code:

=SI(SOMME((MOIS($H$3:$H$1000)=B3)*($H$3:$H$1000<>""))=0;"";MOYENNE(SI(($H$3:$H$1000<>"")*(MOIS($H$3:$H$1000)=B3);$I$3:$I$1000)))

Je te laisse tester tout ceci

@+

chemist · 2 Février 2011

Re : Moyenne, max, min et nb selon critère mois

Merci ca fonctionne très bien

Pour la moyenne les 2 solutions proposées fonctionnent et la formule que j'avais fonctionne également. Cependant votre formule est préférable car ne rapporte pas des div/0 lorsqu'il n'y a pas encore de valeur de nb

merci encore

Moyenne, max, min et nb selon critère mois

chemist

Guest

Pièces jointes

Tibo

XLDnaute Barbatruc

chemist

Guest

Discussions similaires

Moyenne, max, min et nb selon critère mois

chemist

Guest

Pièces jointes

Tibo

XLDnaute Barbatruc

chemist

Guest

Discussions similaires

Privacy & Transparency

Privacy & Transparency