Microsoft 365 Mois, date, heure et minute

[GUERET]

Bonsoir,
Dans ce fichier, j'ai, par trois formules, obtenu le compte à rebours en mois, jours et heures.
Est-il possible de fusionner tout cela en une seule et unique formule en y ajoutant les minutes au quotidien ?
D'avance, merci

https://we.tl/t-MfIgvBtbG0

 

[Deadpool_CC]

@TooFatBoy : Presque bon (à la seconde prêt)

le fichier si tu veux faire d'autres tests

 

[TooFatBoy]

Je n'ai pas Excel sous la main.
Pas grave, je testerai quand je serais rentré chez moi. 😉


[edit]
Pardon, je n'avais pas vu que tu avais testé pour moi.
Merci. 👍
[/edit]

 

[TooFatBoy]

Au fait, n'y a-t-il pas des fonctions heure et minute (voire seconde) qui donnent le résultat sans faire de calcul ?

 

[Deadpool_CC]

En théorie Oui mais vu que ma version d'excel n'implémente pas LET() j'ai pas pu testé pour voir si cela fonctionne => j'ai donc pas remis en cause sa façon de faire .. lol

mais un =HEURE(G4) & "h "& MINUTE(G4) & "m et "& SECONDE(G4)& "s." fonctionne parfaitement :

 

[Deadpool_CC]

Maintenant on va attendre son retour sur ces propres tests d'intégration dans son fichier ... lol

 

[GUERET]

Bonjour,

Peut-être

ss;ENT(MOD(d*24*60;1)*60)

La formule en entier qui fonctionne maintenant
=LET(début;MAINTENANT();fin;B6+C6;m;DATEDIF(début;fin;"ym")&" mois ";j;DATEDIF(début;fin; "md");d;MOD(fin-début;1);h; ENT(d*24);mn;ENT(MOD(d*24;1)*60);ss;ENT(MOD(d*24*60;1)*60);m&SI(j>1;j&" jours ";j&" jour, ")&SI(h>1;h&" heures ";h&" heure ")&SI(mn>1;mn&" minutes ";mn& " minute et ")&SI(ss>1;ss&" secondes ";ss&" seconde "))
Merci et encore MERCI 👍

 

[TooFatBoy]

Merci pour tes réponses Deadpool_CC. 👍

 

[GUERET]

Tu peux tester ma proposition de la même façon, stp, juste histoire que je sache si ça marche ou pas ?

Ça ne donne rien avec ma formule. DSL. Veux-tu que je t'envoie mon fichier afin que tu testes ?

 

[TooFatBoy]

Ça ne donne rien avec ma formule. DSL. Veux-tu que je t'envoie mon fichier afin que tu testes ?

Je ne peux pas tester car je n'ai pas la fonctionnalité LET. 😕

 

[GUERET]

Juste histoire de jeter un œil dessus, pour... on ne sait jamais

 

[Deadpool_CC]

JE vais essayé de faire le calcul sans LET et sans les mois car lors d'un différence on ne tombe pas sur les bons mois (ex : 3 mois juin+juillet+aout = 92 jrs | mais 3 mois Janvier à mars 90 ou 91 jrs selon les années) Donc le nb mois peut être faut :

donc je vais voir à faire sans LET() (uniquement sur sur Office 365) avec Jours, heures minutes et sec.
je post dès que c'est bon.

 

[GUERET]

Ça marche et bon courage

 

[TooFatBoy]

Juste histoire de jeter un œil dessus, pour... on ne sait jamais

Là je suis sur mon tél, donc pas Excel...
Tu peux toujours m'envoyer ton fichier, mais je pense que notre super grenouille aura trouvé avant que je retourne sur mon PC. 😉

 

[Deadpool_CC]

@GUERET
Dsl, Urgence Taff ... je vais pas pouvoir allez plus loin aujourd'hui ...

Mais tu peux tester une simplification de ta formule :

=LET(
début;MAINTENANT();
fin;B6+C6;
m;DATEDIF(début;fin;"ym")&" mois ";
j;DATEDIF(début;fin; "md");
d;MOD(fin-début;1);
h; HEURE(d);
mn;MINUTE(d);
ss;SECONDE(d);
m & SI(j>1;j&" jours ";j&" jour, ")
  & SI(h>1;h&" heures ";h&" heure ")
  & SI(mn>1;mn&" minutes ";mn& " minute et ")
  & SI(ss>1;ss&" secondes ";ss&" seconde."))

 

[TooFatBoy]

Et une petite varian :

=LET(
début;MAINTENANT();
fin;B6+C6;
m;DATEDIF(début;fin;"ym")&" mois ";
j;DATEDIF(début;fin; "md");
d;MOD(fin-début;1);
h; HEURE(d);
mn;MINUTE(d);
ss;SECONDE(d);
m & j & " jour" & SI(j>1;"s ";" ")
  & h & " heure" & SI(h>1;"s ";" ")
  & mn & " minute" & SI(mn>1; "s ";" ")
  & ss & " seconde" & SI(ss>1;"s";""))