Modification Macro Recherche de N° identique dans une colonne

[adi399]

Bonjour et un grand merci à tous ceux qui voudront bien m'aider à résoudre mon problème! vous trouverez ci-joint mon fichier avec les détails.

Extrait :

il y a deux n° "1111" ci-contre.
Ma macro me permet de sélectionner un seul numéro identique (le premier) et pas les suivant.
Si je tape 1111, la macro me sélectionne uniquement la première case.

Je n'arrive pas à modifier mon code.
Je voudrai la chose suivante:

si je tape "1111":

- un message s'affiche : " il y a plusieurs réponses à votre demande"
- je clique sur OK : la macro sélectionne la première case avec "1111"
- Je clique à nouveau sur OK : la macro sélectionne la seconde case "1111"
ainsi de suite jusqu'à ce que la boucle soit terminé.
- un message final s'affiche dans ce cas : " Il n'y a pas d'autres numéros".

Merci beaucoup !! je suis à l'écoute de tous vos conseils!
Bonne journée

 

[kjin]

Re : Modification Macro Recherche de N° identique dans une colonne

bonjour,

Sub RECHERCHE_VALEUR()
Dim rng As Range, c As Range, rep$, adresse$, x%
rep = InputBox("Entrez le n° de recherché")
If rep = "" Then Exit Sub
With Sheets("feuil1")
    x = Application.CountIf(.Columns(6), rep)
    If x = 0 Then
        MsgBox "rien"
        Exit Sub
    Else
        MsgBox "il y a " & x & " cellule(s) contenant " & rep
        x = 0
    End If
    Set c = .Columns(6).Find(rep)
    If Not c Is Nothing Then
        adresse = c.Address
        Do
            x = x + 1
            Application.Goto .Range(c.Address)
            MsgBox "cellule" & x
            Set c = .Columns(6).FindNext(c)
        Loop While Not c Is Nothing And c.Address <> adresse
    End If
End With
End Sub

A+
kjin

 

[Lolote83]

Re : Modification Macro Recherche de N° identique dans une colonne

Salut Adi399,
Voir ici pour une solution
Cordialement
Lolote83

 

[adi399]

Re : Modification Macro Recherche de N° identique dans une colonne

Merci bcp Lolote83 et Kjin ! les deux réponses me conviennent parfaitement !!
Bonne journée.

 

[adi399]

Re : Modification Macro Recherche de N° identique dans une colonne

Bonjour à tous,

J'utilise la macro du fichier " copie de adi399 - problème recherche.xls" de lolote83 du 18/02/2013 ( voir ci-joint )
Cette macro fonctionne très bien mais j'observe aujourd'hui un petit problème. J'aurai besoin de votre aide.

Ma colonne de recherche n'est jamais complète à 100%, il y a des cellules non remplies, intercalé entre une série de numéros à 4 chiffres.
Lorsque je souhaite annuler une recherche avec le bouton "annuler", la recherche s'effectue tout de même sur les cellules vides... ce qui peux être très long.

Comment faire pour que :
- le bouton "Annuler" / ou le clique sur "OK" sans taper de numéro dans la barre, ne lance pas de recherche du tout?

J'espère m'être fait comprendre. Je vous remercie énormément par avance!

 

[Lolote83]

Re : Modification Macro Recherche de N° identique dans une colonne

Salut Adi399,
Rajoute la ligne juste avant le 'je cherche décrite dans la partie ci-dessous intitulée "Code modifié"

Original

Sub RECHERCHE_VALEUR2()
    'je demande le texte recherché
    Rep = InputBox("Entrez le n° de recherché")
    'je cherche
    xNbREP = Application.WorksheetFunction.CountIf(Sheets("Feuil1").Range("F10:F" & Sheets("Feuil1").Range("F65536").End(xlUp).Row), Rep)
    If xNbREP = 0 Then

Code modifié

Sub RECHERCHE_VALEUR2()
    'je demande le texte recherché
    Rep = InputBox("Entrez le n° de recherché")
    If Rep = Empty Then Exit Sub
    'je cherche
    xNbREP = Application.WorksheetFunction.CountIf(Sheets("Feuil1").Range("F10:F" & Sheets("Feuil1").Range("F65536").End(xlUp).Row), Rep)
    If xNbREP = 0 Then

 

[adi399]

Re : Modification Macro Recherche de N° identique dans une colonne

merci beaucoup 🙂 rapide et efficace lolote83!
Bonne journée!