Mfc

[Mitch]

Bonjour toujours avec mon planning

j'ai : date début (C) , heure début (D) , date fin (E), heure fin (F), équipe (G)
a l'heure actuelle si je planifie 2 pose le même jour pour la même équipe j'ai une alerte colonne A
=SOMMEPROD(($C$3:$C$2986=$C3)*($D$3:$D$2986=$D3)*($G$3:$G$2986=$G3)*($C3<>""))>1

mais si j'ai 2 petite pose dans la même journée pour la même équipe je voudrais une alerte e colonne B pour ne pas que l'heure de fin de le 1ere pose et l'heure de début de la 2eme ce chevauche , chose qui vient de m'arrivais et la pas top du tout
Merci

 

[job75]

Re : Mfc

Bonjour,

Annulé, mal compris

A+

 

[R@chid]

Re : Mfc

Salut,
Un petit fichier + petite explication : ci c'est possible

 

[job75]

Re : Mfc

Re Mitch, salut Rachid,

Formule MFC en B3 pour alerter sur le chevauchement :

=SOMMEPROD((C3+D3>=C$3:C$2986+D$3:D$2986)*(C3+D3<E$3:E$2986+F$3:F$2986)*( G$3:G$2986=G3))>1

Edit : ou plus élaborée si l'on veut un texte dans la cellule :

=REPT("Chevauchement";SOMMEPROD((C3+D3>=C$3:C$2986+D$3:D$2986)*(C3+D3<E$3:E$2986+F$3:F$2986)*( G$3:G$2986=G3))>1)

A+

 

[Mitch]

Re : Mfc

je vous joint mon fichier
Cijoint.fr - Service gratuit de dépôt de fichiers
dans la feuille planning j'ai Atchoum qui commence le 13/7 a 7h et fini a 14h et ensuite Joyeux le meme jour commence a 11h et fini peut importe
le souci et qu'on ne peut pas commencer joyeux avant d'avoir fini Atchoum c'est pou cela que je voudrais une MFC en colonne B
Merci

 

[Mitch]

Re : Mfc

job75 tu a etait plus rapide que moi , j'essai de suite
Merci

 

[job75]

Re : Mfc

Re,

La formule du post #4 testait la date/heure de début, il faut tester aussi la date/heure de fin :

=SOMMEPROD(((C3+D3>=C$3:C$2986+D$3:D$2986)*(C3+D3<E$3:E$2986+F$3:F$2986)+(E3+F3>C$3:C$2986+D$3:D$2986)*(E3+F3<=E$3:E$2986+F$3:F$2986))*( G$3:G$2986=G3))>2

A+

 

[Mitch]

Re : Mfc

Ouah super je te remercie ca marche nickel
A+

 

[job75]

Re : Mfc

Re,

On s'embrouille facilement avec les intervalles.

Il me semble que cette formule, nettement plus simple, convient :

=SOMMEPROD((C3+D3<E$3:E$2986+F$3:F$2986)*(E3+F3>C$3:C$2986+D$3:D$2986)*( G$3:G$2986=G3))>1

Je vous laisse tester tous les cas de figure.

A+