XL 2016 Mettre un texte spécifique dans une cellule en fonction d'une période

[thunder23]

Bonsoir le forum,

Je fais appelle à vous car je souhaiterais qu'en fonction d'une période donnée dans le temps exemple du 02/04/2023 au 30/04/2023 ça met dans une colonne "AT".

Je pense qu'en macros c'est possible mais je voudrais éviter c'est pour ça que je demande votre aide.

J'ai mis un fichier test pour mieux comprendre.

Merci d'avance

 

[sylvanu]

Bonsoir Thunder,
Un essai en PJ avec :

AT L1 :  =SI(ET(A14>=$H$4;A14<=$I$4);"AT";"")
AT L2 :  =SI(ET(A14>=$H$6;A14<=$I$6);"AT";"")

 

[JHA]

Bonjour à tous,

Si colonne "B" différente de ""

=SI(ET(ESTNUM(EQUIV($A14;LIGNE(INDIRECT($H$4&":"&$I$4));0));$B14<>"");"AT";"")

JHA

 

[thunder23]

Bonjour @sylvanu, bonjour @JHA, bonjour le forum,

Merci pour vos retours néanmoins pour mon soucis je préfère celle de @sylvanu.

Toutefois ton retour @JHA m'intéresse bien et je pense qu'il sera utilisé pour un autre projet

Merci à tous les deux !

 

[thunder23]

Bonsoir Thunder,
Un essai en PJ avec :

AT L1 :  =SI(ET(A14>=$H$4;A14<=$I$4);"AT";"")
AT L2 :  =SI(ET(A14>=$H$6;A14<=$I$6);"AT";"")

Bonsoir @sylvanu, bonsoir le forum,

est-il possible de mettre les deux SI ET dans une seule car j'ai essayé de multiple manières et à chaque fois ça me met #VALEUR ! ?.

Il n'y a que comme cette formule qui fonctionne

=SI(ET($A14>=Planning!$B$7;$A14<=Planning!$C$7);1;0)+SI(ET($A14>=Planning!$B$8;$A14<=Planning!$C$8);1;0)

 

[sylvanu]

Bonjour,
Vous avez deux formules AT L1 = si(ET(... et AT L2 = si(ET(...
On peut les concaténer en faisant : = si(OU(ET(...);ET(...);...

=SI(OU(ET(A14>=$H$6;A14<=$I$6);ET(A14>=$H$4;A14<=$I$4));"AT";"")

 

[job75]

Bonjour thunder23, sylvanu, JHA,

Je comprends que vous recherchez une seule formule pour les 2 colonnes C et D.

A placer en C14 et tirer à droite et vers le bas :

=REPT("AT";($A14>=DECALER($H$4;2*COLONNES($C:C)-2;))*($A14<=DECALER($I$4;2*COLONNES($C:C)-2;)))

La fonction REPT est ici plus simple que la fonction SI.

A+

 

[sylvanu]

Bonjour thunder23, sylvanu, Job,
Ou encore une autre approche :

=SI(ET(A14>=MIN($H$3:$I$6);A14<=MAX($H$3:$I$6));"AT";"")

 

[thunder23]

Bonjour @sylvanu, bonjour @job75, bonjour le forum,

@sylvanu j'avoue que j'ai essayé avec le OU ET mais je ne savais pas que l'on pouvait mettre un autre ET dans une condition c'est bon à savoir
Ton autre formule n'est pas non plus en tout cas je vais garder la première pour mon système

@job75 ta formule avec REPT je ne connaissais pas du tout, je vais regarder de plus près pour l'utiliser plus tard si besoin.

En tout cas merci à tous les deux pour vos retours