Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

[christ-94]

Bonjour

J'ai dans une même cellule les noms et prénoms de personnes , et j'aimerais mettre que le noms des personnes en gras et changer la taille des caractères
ce code est a intègre dans une macro

exemple
chaine jean christophe
cela donne
chaine jean christophe


Merci d'avance

 

[delphine35]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

tu as essayé en mettant les noms dans une colonne et les prenom dans l'autres ? Ensuite tu supprime la bordure droite de la colonne 1 et la bordure gauche de la colonne 2, et tu fait la mise en forme ...

J'ai déjà vu ce problème et je n'ai pas trouvée de meilleurs solutions. 🙁

 

[tbft]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

bonjour

as tu essayé de le faire à la main en enregistrant une macro afin de voir si il peut le faire???

 

[christ-94]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

Bonjour

Merci pour cette réponse
cela n'ai pas possible car il y a une mise en forme sur plusieurs noms qui non pas le même nombres caractères

Il doit y avoir une solution en comptent les caractère avant le caractère espace
on met en gras et plus grand les caractère de la gauche jusqu'au premier espace

mais la je ne suis pas assez bon en programmation

A+

 

[christ-94]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

Salut

oui, ci-joint le code

    Range("D28").Select
    ActiveCell.FormulaR1C1 = "chaine jean christophe"
    With ActiveCell.Characters(Start:=1, Length:=6).Font
        .Name = "Arial"
        .FontStyle = "Gras"
        .Size = 14
        .Strikethrough = False
        .Superscript = False
        .Subscript = False
        .OutlineFont = False
        .Shadow = False
        .Underline = xlUnderlineStyleNone
        .ColorIndex = xlAutomatic
    End With
    With ActiveCell.Characters(Start:=7, Length:=16).Font
        .Name = "Arial"
        .FontStyle = "Normal"
        .Size = 10
        .Strikethrough = False
        .Superscript = False
        .Subscript = False
        .OutlineFont = False
        .Shadow = False
        .Underline = xlUnderlineStyleNone
        .ColorIndex = xlAutomatic
    End With
    Range("D27").Select

Il compte les caracteres, mais cela fonctionne

 

[GeoTrouvePas]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

Bonjour,

Il faut "tout simplement" faire deux boucles imbriquées l'une dans l'autre. La première va faire passer de cellule en cellule et la seconde va prendre le contenu de la cellule lettre par lettre et la mettre en gras jusqu'à ce qu'elle tombe sur un espace.

Par contre tu n'arriveras jamais à contrer le fait que tu puisse avoir des noms et / ou des prénoms composés....

 

[ROGER2327]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

Bonjour christ-94

[B][COLOR="DarkSlateGray"]Sub toto()
    With ActiveCell.Characters(Start:=1, Length:=InStr(1, ActiveCell.Value & " ", " ") - 1).Font
      .FontStyle = "Gras"
      .Size = Application.StandardFontSize + 4
   End With
End Sub[/COLOR][/B]

devrait faire l'affaire pour la cellule sélectionnée.​

ROGER2327
#4039

Dimanche 22 Phalle 137 (Dragonne, pyrophage, SS)
15 Fructidor An CCXVIII
2010-W35-3T13:12:18Z

________________
P.s. : ...et, évidemment, bonjour à tous (toutes) ceux (celles) dont je n'avais pas vu les réponses...

 

[christ-94]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

Bonjour ROGER2327

Merci pour le code
il fonctionne tres bien 🙂

A+

 

[ROGER2327]

Re : Mettre en gras que le nom et pas le prenoms qui sont dans la meme cellule

Suite...

Une version un peu plus élaborée s'appliquant à une sélection de cellules :

[COLOR="DarkSlateGray"][B]Sub toto()
Dim oCel As Range
   Application.ScreenUpdating = False
   For Each oCel In Selection.Cells
      With oCel.Font: .Size = Application.StandardFontSize: .Bold = False: End With
      If Not IsEmpty(oCel) Then
         With oCel.Characters(Start:=1, Length:=InStr(1, oCel.Value & " ", " ") - 1)
            .Text = UCase(.Text)
            With .Font
               .FontStyle = "Gras"
               .Size = Application.StandardFontSize + 3
            End With
         End With
         With oCel.Characters(Start:=InStr(1, oCel.Value & " ", " "), Length:=Len(oCel.Value) - InStr(1, oCel.Value & " ", " ") + 1)
            .Text = WorksheetFunction.Proper(.Text)
         End With
      End If
   Next
   Application.ScreenUpdating = True
End Sub[/B][/COLOR]

Avec ce code,

roger-durand charles édouard​

devient

ROGER-DURAND Charles Édouard​

ROGER2327
#4040

Dimanche 22 Phalle 137 (Dragonne, pyrophage, SS)
15 Fructidor An CCXVIII
2010-W35-3T13:41:08Z