Microsoft 365 Mettre date au format jj/mm/aaaa

[libellule85]

Bonjour le forum,
J'aurais besoin de vos compétences pour résoudre mon problème :
J'ai récupéré une BDD de + de 453 000 références. A l'intérieur de cette BDD les dates sont comme ceci 19820718 et je voudrais les mettre au format jj/mm/aaaa
D'avance merci pour votre aide.
Bien cordialement

 

[riton00]

Bonjour,
A tester puis tirer la formule

=DATE(GAUCHE(D7;4);STXT(D7;5;2);DROITE(D7;2))

Slts

 

[Bernard_XLD]

Bonjour libellule85, riton00, le forum

le plus simple, utilisez la fonction Excel dédiée convertir

Cordialement

 

[Bernard_XLD]

Re,

avec une macro pour automatiser, définir la colonne à traiter en colonne_cible.

Cordialement

Sub Convertir_Dates()
    Dim Colonne_Cible$
    Colonne_Cible = "A"
    Range(Colonne_Cible & "1:" & Colonne_Cible & Range(Colonne_Cible & Rows.Count).End(xlUp).Row).TextToColumns FieldInfo:=Array(1, 5)
End Sub

 

[mapomme]

Bonjour à tous ,

Allez, une petite macro qui permet de sélectionner la ou les zone(s) à convertir.

Sub AAAAMMJJenDate()
Dim plage As Range, zone, d, x, y
   Application.ScreenUpdating = True: On Error Resume Next 'True pour sélectionner la (multi)plage
   Set plage = Application.InputBox("Sélectionnez la plage à traiter (ou multiplages), svp", _
            Type:=8)                      ' acquisition de la (multi)plage
   If plage Is Nothing Then Exit Sub      ' si erreur d'acquisition, on ne fait rien et on quitte
   Application.ScreenUpdating = False     ' on fige l'écran
   Set plage = Intersect(plage.Parent.UsedRange, plage)  ' on limite à la zone utile
   For Each zone In plage.Areas           ' pour chaque zone de la sélection
      For Each x In zone.Cells            ' pour chaque cellule de la zone
         y = CStr(x)                      ' on convertit la valeur de la cellule en texte
         If y Like String(8, "#") Then    ' si texte est de la forme AAAAMMJJ
            d = "": d = DateSerial(Left(y, 4), Mid(y, 5, 2), Right(y, 2))  ' conversion de y en date
            ' si d est une date alors on efface la cellule, on la formate en date et on y place la date
            If IsDate(d) Then x.ClearContents: x.NumberFormat = "dd/mm/yyyy": x.HorizontalAlignment = 1: x.Value = d
         End If
      Next x   ' cellule suivante de la zone
   Next zone   ' zone suivante
   Application.ScreenUpdating = True
End Sub

Cliquez sur le bouton AAAMMJJ.

 

[dysorthographie]

bonjour,
pourquoi tu nous fais partir des données importées et pas des données bruit avant import.

on pourrait de proposer un import qui tient compte des forma date ou autre

dim d as date 
d=format(y,"0000-00-00")

 

[libellule85]

Bonjour Riton00, Bernard_XLD, mapomme, dysorthographie,

Merci à tous pour vos réponses, je vais les essayer toutes.
Mais la réponse de Bernard_XLD par la conversion est quand même la plus simple !
A un grand merci à vous tous.
Bien cordialement

 

[mapomme]

Mais la réponse de Bernard_XLD par la conversion est quand même la plus simple !

Et la plus rapide😉...