Masquer les colonnes vierges avec une macro

[enki]

Bonjour,
je souhaite masquer les colonnes vierge avec une macro.

merci de votre aide.

ci-joint un extrait du fichier

 

[JCGL]

Re : Masquer les colonnes vierges avec une macro

Bonjour à tous,

Peux-tu essayer avec :

Option Explicit

Sub Masque()
Dim X As Integer
For X = 2 To 10
If Cells(25, X) = 0 Then Cells(25, X).EntireColumn.Hidden = True
Next
End Sub

A+ à tous

 

[job75]

Re : Masquer les colonnes vierges avec une macro

Bonjour enki, salut JC 🙂

S'il n'y a rien qui gêne à l'extérieur du tableau :

Sub Masque()
Dim col As Range
For Each col In Columns("B:J")
If Application.CountA(col) = 2 Then col.Hidden = True
Next
End Sub

A+

 

[tototiti2008]

Re : Masquer les colonnes vierges avec une macro

Bonjour JC, Bonjour job, Bonjour enki,

Bon, en retard moi...

c'est pas grave, je poste 😉

Sub MasqueColonnne()
Dim Ligne As Long, Colonne As Long, i As Long
    Application.ScreenUpdating = False
    With Range("A4").CurrentRegion
        Ligne = .Rows.Count
        Colonne = .Columns.Count
        For i = 1 To Colonne
            .Cells(Ligne, i).EntireColumn.Hidden = False
            If .Cells(Ligne, i).Value = 0 Then .Cells(Ligne, i).EntireColumn.Hidden = True
        Next i
    End With
    Application.ScreenUpdating = True
End Sub

 

[JCGL]

Re : Masquer les colonnes vierges avec une macro

Bonjour à tous,
Salut Job 🙂,
Salut Toto 🙂,

La mise en application de ma proposition et avec un Affiche / Masque (Bouton Bascule).

A++
A+ à tous

 

[enki]

Re : Masquer les colonnes vierges avec une macro

bonsoir,

merci à tous.
JCGL, j'ai adapté la macro à mon fichier(dommage trop lourd pour l'envoyer)
J'ai créer un bouton a bascule dans la feuille Prévisionnel
j'ai mis dans vbaproject, feuille Prévisionnel :
Option Explicit

Private Sub ToggleButton1_Click()
If ToggleButton1 = False Then Affiche
If ToggleButton1 = True Then Masque
End Sub
dans l'onglet module :
Option Explicit

Sub Masque()
Dim X As Integer
Application.ScreenUpdating = 0
For X = 2 To 172
If Prévisionnel.Cells(127, X) = 0 Then Prévisionnel.Cells(127, X).EntireColumn.Hidden = True
Next
End Sub

Sub Affiche()
Dim X As Integer
Application.ScreenUpdating = 0
For X = 2 To 172
Prévisionnel.Cells(127, X).EntireColumn.Hidden = False
Next

End Sub
j'ai une erreur 424 (Objet requis)
à tu une solution stp ?
peut tu me dire ou je me suis trompé.
Merci

 

[JCGL]

Re : Masquer les colonnes vierges avec une macro

Bonjour à tous,

Il me semble que tu as omis de préciser que "Prévisionnel" était le nom d'une feuille :

Sheets("Prévisionnel").

Option Explicit

Sub Masque()
Dim X As Integer
Application.ScreenUpdating = 0
For X = 2 To 172
If Sheets("Prévisionnel").Cells(127, X) = 0 Then Sheets("Prévisionnel").Cells(127, X).EntireColumn.Hidden = True
Next
End Sub

Sub Affiche()
Dim X As Integer
Application.ScreenUpdating = 0
For X = 2 To 172
Sheets("Prévisionnel").Cells(127, X).EntireColumn.Hidden = False
Next

End Sub

A+ à tous

Édition : je préconise plutôt le Feuil1. (à adapter...) au nom de la feuille qui permet de changer le nom de la feuille par l'onglet sans changer le code (voir différence entre CodeName et Name)

 

[enki]

Re : Masquer les colonnes vierges avec une macro

ok,
je te remercie de ta réponse, ça marche nickel.
Bonne nuit