Macro enregistrer sous en 2 formats

[pierre56]

Bonjour à tous,
je suis à la recherche d'une macro qui ne paraît pas trop compliqué mais j'ai des difficultés à la réaliser.

Je souhaiterais installé une InputBox qui me permettrait d'enregistrer mon fichier au format xls et au format CSV. Mon problème vient du nom de l'enregistrement, je souhaiterais que s'affiche: le nom du fichier, un "_" et ensuite la réponse de l'InputBox pour les 2 enregistrements.

Merci d'avance pour votre aide

 

[Pierrot93]

Re : Macro enregistrer sous en 2 formats

Bonjour,

regarde peut être ceci :

Option Explicit
Sub test()
Dim monSuff As String, monfichier As String
monSuff = InputBox("Nom ?")
If monSuff <> "" Then
    With ThisWorkbook
        monfichier = Mid(.FullName, 1, InStrRev(.FullName, ".") - 1) & "_"
        .SaveAs monfichier & monSuff, xlNormal
        .SaveAs monfichier & monSuff, xlCSV
    End With
End If
End Sub

bonne journée
@+

 

[pierre56]

Re : Macro enregistrer sous en 2 formats

Pierrot93, ce code correspond à peu près à ce que je recherche mais j'aurais juste souhaité pouvoir saisir l'emplacement de sauvegarde du fichier car le CSV et le XLS ne vont pas au même endroit. Je ne sais pas où changer celà dans votre code.

Merci d'avance

 

[Pierrot93]

Re : Macro enregistrer sous en 2 formats

Re,

et le chemin tu le trouve où ?? une boite de dialogue ou dans une cellule ??

 

[Pierrot93]

Re : Macro enregistrer sous en 2 formats

Re,

un essai avec une boite de dialogue pour sélection des dossiers :

Option Explicit
Sub test()
Dim monSuff As String, monfichier As String, monchemin As String
monSuff = InputBox("Nom ?")
If monSuff = "" Then Exit Sub
With ThisWorkbook
    monfichier = Mid(.Name, 1, InStrRev(.Name, ".") - 1) & "_"
    monchemin = chemin
    If monchemin <> "" Then .SaveAs monchemin & "\" & monfichier & monSuff, xlNormal
    monchemin = chemin
    If monchemin <> "" Then .SaveAs monchemin & "\" & monfichier & monSuff, xlCSV
End With
End Sub
Function chemin() As String
With Application.FileDialog(msoFileDialogFolderPicker)
    .Show
    If .SelectedItems.Count > 0 Then chemin = .SelectedItems(1)
End With
End Function

 

[pierre56]

Re : Macro enregistrer sous en 2 formats

Le chemin serait fixe. Il faudrait juste écrire dans la macro l'emplacement du dossier où le fichier s'enregistrera. Comme par exemple "C:\Documents and Settings\stagiaire1\Mes documents\". La première macro proposé correspondait au besoin sauf l'emplacement de la sauvegarde

 

[Pierrot93]

Re : Macro enregistrer sous en 2 formats

Re,

as tu essayé le code proposé en post #5 ?

A noter, s'il est fixe tu peux modifier ainsi :

 monchemin = "C:\Documents and Settings\stagiaire1\Mes documents\"

 

[pierre56]

Re : Macro enregistrer sous en 2 formats

Votre méthode fonctionne correctement c'est bien ce que je recherchais.
Merci beaucoup.

Bonne journée