Listbox et filtre

[Lu K]

bonjour à tous,

Encore une question :

Je voudrais créer dans des listebox une sorte de filtre.
Je m'explique, en selectionnant un client dans la 1ère listbox celle-ci devra faire un filtre sur d'autres feuilles et renseigner automatiquement les autres listebox devis et facture. D'abord je ne sais pas créer une action dans une listbox en double cliquant sur le nom d'un client, est-ce possible ?

Je joint un possible exemple.

Merci d'avance pour vos réponse.

 

[Robert]

Re : Listbox et filtre

Bonjour Lu K, bonjour le forum,

En pièce jointe ton fichier modifié avec la macro ci-dessous :

Private Sub ListBox1_Click()
Dim cel As Range 'déclare la variable cel (CELlule)
 
Me.ListBox2.Clear 'vide la ListBox2
Me.ListBox3.Clear 'vide la ListBox3

With Sheets("Devis") 'prend en compte l'onglet "Devis"
    'boucle sur toute les cellules éditées de la colonne A
    For Each cel In .Range("A1:A" & .Range("A65536").End(xlUp).Row)
        'si la valeur de la cellule correspond avec la valeur de l'élément sélectionné de la ListBox1,
        'ajoute la cellule adjacente à la Listbox2
        If cel.Value = Me.ListBox1.Value Then Me.ListBox2.AddItem cel.Offset(0, 1).Value
    Next cel 'prochaine cellule de la boucle
End With 'fin de la prise en compote de l'onglet "Devis"

With Sheets("Facture") 'prend en compte l'onglet "Facture"
    'boucle sur toute les cellules éditées de la colonne A
    For Each cel In .Range("A1:A" & .Range("A65536").End(xlUp).Row)
        'si la valeur de la cellule correspond avec la valeur de l'élément sélectionné de la ListBox1,
        'ajoute la cellule adjacente à la Listbox3
        If cel.Value = Me.ListBox1.Value Then Me.ListBox3.AddItem cel.Offset(0, 1).Value
    Next cel 'prochaine cellule de la boucle
End With 'fin de la prise en compote de l'onglet "Facture"
End Sub

 

[Lu K]

Re : Listbox et filtre

Mille merci a toi Robert, je suis surpris de voir que tu peut faire autant de chose avec un si petit code ! Moi j'étais partis sur beaucoup plus compliqué et moins éfficace.

Un grand merci pour ton code.