list déroulante semi-automatique

[meldja]

Bonjour,
J'ai essayé d'adapter une formule pour liste de validation avec saisie semi-automatique mais je n'y arrive pas.
Le truc qui complique la chose c'est que j'ai essayé de l'adapter à une liste déroulante "dynamique" (la source change en fonction d'une autre liste de validation).
Voici la formule que j'ai trouvé sur le Net :
=SI(A1<>"";DECALER(d_noms;EQUIV(A1&"*";l_noms;0)-1;;SOMME((STXT(l_noms;1;NBCAR(A1))=TEXTE(A1;"0"))*1));l_noms)
en remplaçant A1 par l'identification de la première cellule sélectionnée.

Voici comment j'ai essayé de l'adapter :
=SI(B5<>"";DECALER(debut;EQUIV(B5&"*";list;0)-1;;SOMME((STXT(list;1;NBCAR(B5))=TEXTE(B5;"0"))*1));list)

Voir fichier ci-joint pour plus de compréhension (avec mes plages et formules nommées)
Merci d'avance

 

[meldja]

Re : list déroulante semi-automatique

Re,
C''est bon, j'ai trouvé, fallait juste remplacer :

=SI(B5<>"";DECALER(debut;EQUIV(B5&"*";list;0)-1;;SOMME((STXT(list;1;NBCAR(B5))=TEXTE(B5;"0"))*1));list)

par

=SI(B5<>"";DECALER(list;EQUIV(B5&"*";list;0)-1;;SOMME((STXT(list;1;NBCAR(B5))=TEXTE(B5;"0"))*1));list)

 

[job75]

Re : list déroulante semi-automatique

Bonjour meldja, le forum,

La formule de validation n'est pas correcte en effet car il faut que la recherche se fasse dans le groupe défini en B3. Voici la formule corrigée :

=SI(B5<>"";DECALER(debut;EQUIV(B5&"*";list;0)-1;EQUIV($B$3;groupe;0)-1;SOMME((STXT(list;1;NBCAR(B5))=TEXTE(B5;"0"))*1));list)

Perso je ne vois pas trop l'intérêt de cette saisie semi-automatique.

A+

Edit : posté pendant que votre message arrivait. Bravo meldja, c'est mieux que ma solution !

 

[meldja]

Re : list déroulante semi-automatique

Merci pour ta réponse job75,
Pour répondre à ton interrogation, la liste avec saisie semi-automatique me sera utile pour un fichier où j'ai plein de noms. Le fichier joint ne servait que de test. J'ai déjà adapté à mon fichier avec des listes assez longues.
Bonne journée

 

[Monique]

Re : list déroulante semi-automatique

Bonjour,

Dans cette formule :
=SI(B5<>"";DECALER(list;EQUIV(B5&"*";list;0)-1;;SOMME((STXT(list;1;NBCAR(B5))=TEXTE(B5;"0"))*1));list)

cette partie
SOMME((STXT(list;1;NBCAR(B5))=TEXTE(B5;"0"))*1)

peut être remplacée par
NB.SI(list;B5&"*")

Et ça donne
=SI(B5<>"";DECALER(list;EQUIV(B5&"*";list;0)-1;;NB.SI(list;B5&"*"));list)

 

[Monique]

Re : list déroulante semi-automatique

Re,

Suite...

La plage nommée "List", je crois qu'il vaut mieux la nommer par cette formule :

=DECALER(debut;;EQUIV(Feuil2!$B$3;groupe;0)-1;NBVAL(DECALER(Feuil1!$A:$A;;EQUIV(Feuil2!$B$3;groupe;0)-1))-1)

pour ne pas être limité à un peu moins de 50 noms comme avec la fonction Indirect()

 

[meldja]

Re : list déroulante semi-automatique

Merci Monique,
T'es vraiment une "foundi" comme on dit ici (ça veut dire "Maître" dans le sens qui enseigne).
Bonne soirée

 

[meldja]

Re : list déroulante semi-automatique

Re,
J'ai voulu tester ta formule et ça marche pas.
Il y avait une petite erreur :

=DECALER(debut;;EQUIV($B$3;groupe;0)-1;NBVAL(DECALER(Feuil1!$A:$A;;EQUIV($B$3;groupe;0)-1))-1)

La où j'ai mis du rouge, il y avait écrit "Feuil1" alors que la référence se trouve dans la feuille active (Feuil2)

Après avoir corrigé, ça marchait pour les 2 premiers groupes sélectionnés (G1 et G2) mais pas pour le troisième
Tu l'as testé dans le fichier que j'ai joint ? Si oui, envoie-le SVP.
Merci

 

[Monique]

Re : list déroulante semi-automatique

Re,

Le fichier

 

[meldja]

Re : list déroulante semi-automatique

Désolé Monique, j'ai été déconnecté et j'ai galéré pour me reconnecter (je suis en analogique avec un débit théorique de 45kbits/s... mais en réalité, je ne dépasse pas le 30kbits et ça rame pour se reconnecter et le reste, vu la saturation du réseau).
J'avais une fois de plus plané, ta formule est nickel.
Je viens de faire la même erreur sur un autre post. Je sature autant que notre réseau, je suis devant mon PC depuis le réveil (7h 30... j'ai fait une grasse mat !!) et il est bientôt 19 h chez nous. 12 heures de recherche en tout genre.
Il est temps que je passe à autre chose.
En tout merci de tes lumières et passe une bonne soirée.
Bye