XL 2021 liaison entre deux tableaux

job75 à dit:

Bonsoir brunocean,

Il y a plusieurs tableaux dans le fichier source, lequel copiez-vous ?

A+

Cliquez pour agrandir...

job75 à dit:

Téléchargez le dossier zip joint et extrayez son contenu sur le bureau.

Ouvrez le fichier tests.xlsm, cette macro dans ThisWorkbook s'exécute automatiquement :

VB:

Private Sub Workbook_Activate()
Dim chemin$, source As Worksheet, nf$
chemin = Me.Path & "\Sauvegarde\" 'sous-dossier
Set source = Sheets("BUDGET")
nf = source.Name
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
On Error Resume Next
With Workbooks.Open(chemin & nf & ".xlsx") 'ouverture du fichier sauvegardé
    If Err Then
        MsgBox "Le fichier '" & chemin & nf & ".xlsx' est introuvable", 48
    Else
        .Sheets(nf).Cells.Copy source.Cells(1)
        If Err Then MsgBox "Le fichier '" & nf & ".xlsx' doit contenir une feuille '" & nf & "'", 48
        With source.Cells(1).MergeArea
            .Copy .Cells 'allège la mémoire
            .Merge 'refusionne si nécessaire
        End With
        .Close False 'fermeture du fichier sauvegardé
    End If
End With
Application.EnableEvents = True 'réactive les évènements
End Sub

Le fichier dans le sous-dossier "Sauvegarde" est copié vers la feuille source avec les modifications que vous y aurez faites.

A+

Cliquez pour agrandir...

job75 à dit:

Bon si vous tenez à une formule en H3 j'ai renommé les feuilles des fichiers sauvegardés et utilisé :

Code:

=SUBSTITUE(STXT(CELLULE("filename";A1);TROUVE("]";CELLULE("filename";A1))+1;99);"BUDGET ";"")

Cliquez pour agrandir...

job75 à dit:

Une liste déroulante pour faire quoi ? La macro étudie toutes les feuille
Il faut que vous soyez plus clair : "lorsque je fait enregistrer cela ferme le classeur" n'a guère de senDans

Cliquez pour agrandir...

brunocean à dit:

si j'ouvre dans sauvegarde : bernard j'ajoute des montants , test est ouvert aussi et quand je fait enregistrer bernard se ferme

Cliquez pour agrandir...

job75 à dit:

Non, BERNARD.xlsx se ferme quand on active tests.xlsm c'est normal puisqu'alors la macro se déclenche.

Cliquez pour agrandir...

job75 à dit:

J'ai amélioré la macro, dans le cas où le fichier sauvegardé est déjà ouvert on ne le ferme plus :

VB:

Private Sub Workbook_Activate()
Dim chemin$, w As Worksheet, wb As Workbook, ouvert As Boolean
chemin = Me.Path & "\Sauvegarde\" 'sous-dossier
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
For Each w In Worksheets
    On Error Resume Next
    Set wb = Nothing: ouvert = False
    Set wb = Workbooks(w.Name & ".xlsx")
    If Err = 0 Then 'si le fichier est ouvert
        If wb.Saved Then 'et a été enregistré
            ouvert = True
        Else
            If MsgBox("Le fichier '" & w.Name & ".xlsx' est ouvert et a été modifié, voulez-vous enregistrer les modifications ?", vbYesNo + vbQuestion) = vbYes Then
                wb.Save 'enregistre le fichier
                ouvert = True
            Else
                wb.Close False 'ferme le fichier
            End If
        End If
    End If
    If Not ouvert Then Err = 0: Set wb = Workbooks.Open(chemin & w.Name & ".xlsx") 'ouverture du fichier sauvegardé
    If Err = 0 Then
        wb.Sheets(1).Cells.Copy w.Cells(1)
        With w.Cells(1).MergeArea
            .Copy .Cells 'allège la mémoire
            .Merge 'refusionne si nécessaire
        End With
        wb.Saved = True 'en effet la fonction CELLULE est volatile et a été recalculée
        If Not ouvert Then wb.Close 'ferme le fichier s'il n'était pas ouvert
    End If
Next w
Application.EnableEvents = True 'réactive les évènements
End Sub

C'est quand même plus compliqué à comprendre...

Cliquez pour agrandir...