les 3 noms les plus répétés

[spectarus]

bonjour à tous !

je cherche 3 formules qui me donneront les 3 noms les plus répétés dans une plage de noms

j'ai déjà trouvé la formule pour le nom le plus répété de tous, il me reste les deux autres formules pour le 2nd et le 3ème noms les plus répétés

Ci-joint un petit fichier pour bien comprendre...

Merci de prendre en compte le fait que le fichier excel est sans macro...

Merci d'avance de m'avoir consacré du temps.

Bonne journée à toutes et à tous

 

[david84]

Re : les 3 noms les plus répétés

Bonjour,

nommer ta plage "zone" (ou remplacer dans la formule "zone" par ta sélection), se placer en B2=>copier la formule=>appuyer sur la touche F2, valider en matriciel (Ctrl,Maj et entrée) et tirer la formule vers le bas :

=SI(LIGNES($1:1)<=SOMME(SI(zone<>"";1/NB.SI(zone;zone)));INDEX(zone;MIN(SI((NB.SI(zone;zone)*(NB.SI(B$1:B1;zone)=0))=MAX(SI(NB.SI(B$1:B1;zone)=0;NB.SI(zone;zone)));LIGNE(zone))));"")

Sinon, regarde ici une discussion traitant de cette problématique : même si cela est plus complexe puisque le traitement est effectué sur une plage multicolonne, cela peut peut-être t'intéresser.
A+

 

[david84]

Re : les 3 noms les plus répétés

Suite à mon 1er message, autre possibilité en passant la fonction MODE comme utilisé ici par JB :

=SI(LIGNES($1:1)<=SOMME(SI(zone<>"";1/NB.SI(zone;zone)));INDEX(zone;MODE(SI((zone<>"")*(NB.SI(D$1:D1;zone)=0);EQUIV(zone;zone;0))));"")

A+

Edit : bonjour Dranreb !

 

[Dranreb]

Re : les 3 noms les plus répétés

Bonjour.

Houf ! Je croyais bien ne pas m'en sortir.
J'ai même envoyé un MP à Ràchid, formuliste hors pair.
Mais j'ai quand même fini par trouver au moins une solution assez simple :
Validés en matriciel aussi :
En D4:

=INDEX($A$2:$A$21;EQUIV(MAX(NB.SI($A$2:$A$21;$A$2:$A$21)*($A$2:$A$21<>$D$3));NB.SI($A$2:$A$21;$A$2:$A$21);0))

En D5:

=INDEX($A$2:$A$21;EQUIV(MAX(NB.SI($A$2:$A$21;$A$2:$A$21)*($A$2:$A$21<>$D$3)*($A$2:$A$21<>$D$4));NB.SI($A$2:$A$21;$A$2:$A$21);0))

P.S. Je viens après la bataille je vois. Il faut dire que j'ai reçu un MP m'invitant à chercher, alors que je ne me considère plus guère formuliste depuis longtemps…

P.S.2: Ne marcherait d'ailleurs peut être pas si le 2ième et 3ième sont exaequo, à moins de répéter aussi les *($A2$A21>… dans le 2ième terme de EQUIV

 

[spectarus]

Re : les 3 noms les plus répétés

dsl David84 j'ai remplacé zone par la plage désirée mais pour le 2nd et 3ème nom le plus fréquent ça ne marche pas ! pour le 1er nom le plus fréquent y a bcp plus simple comme formule...

=INDEX(A1:A20;EQUIV(MAX(NB.SI(A1:A20;A1:A20));NB.SI(A1:A20;A1:A20);0))

matricielle bien sûr !

 

[spectarus]

Re : les 3 noms les plus répétés

Merci bcp Dranreb de m'avoir consacré du temps la réponse à mon invitation est un geste qui force le respect !

concernant la formule dsl mais elle n'est pas tout à fait au point !

merci comme pour l'effort 🙂

 

[Dranreb]

Re : les 3 noms les plus répétés

La D4 me rend "danny" qui apparait 5 fois,
la D5 me rend "Jean" qui apparait 4 fois.

Oups. C'est un hazard car erreur de manip; j'ai commencé par dupliquer la D3 et comme les références de lignes n'étaient pas absolues le A1 s'est retrouvé A2 et le A20 A21. Je cherche encore…

 

[spectarus]

Re : les 3 noms les plus répétés

je sais ! mais en changeant quelques noms histoire de voir si ça marche toujours ça m'a donné des résultats eronnés

regarde par toi même !

 

[david84]

Re : les 3 noms les plus répétés

dsl David84 j'ai remplacé zone par la plage désirée mais pour le 2nd et 3ème nom le plus fréquent ça ne marche pas ! pour le 1er nom le plus fréquent y a bcp plus simple comme formule...

=INDEX(A1:A20;EQUIV(MAX(NB.SI(A1:A20;A1:A20));NB.SI(A1:A20;A1:A20);0))

matricielle bien sûr !

Avant de dire "ça ne marche pas !" il faut être sûr de tester correctement (cf. fichier) !
Quant au fait d'avoir une formule plus simple mais matricielle, quel en est l'intérêt si tu peux avoir une formule qui traite le tout ?
A+

 

[spectarus]

Re : les 3 noms les plus répétés

la proposition 1 fait face à toutes epreuves 🙂 la seconde bug à certains changements !

Seulement même la proposition 1 reste difficile à inclure dans ma base de données (la raison pour laquelle je cherche une formule plus simple Merci infiniment comme même 😀

je continue ma recherche...

 

[david84]

Re : les 3 noms les plus répétés

Re

la proposition 1 fait face à toutes epreuves la seconde bug à certains changements !

Donc cela fonctionne !

Seulement même la proposition 1 reste difficile à inclure dans ma base de données (la raison pour laquelle je cherche une formule plus simple Merci infiniment comme même

Si tu ne nous en dis pas plus sur tes difficultés (vitesse d'exécution de la formule, données diverses, ...) difficile de t'aider d'avantage...si ta zone ne contient pas de cellules vides alors pas besoin de passer par une formule matricielle pour trouver la fréquence la plus grande :

=INDEX(zone;MODE(EQUIV(zone;zone;0)))

suffit (si je tiens compte de l'exemple que tu as fourni).
A+

 

[spectarus]

Re : les 3 noms les plus répétés

il n'y a pas de données particulière à prendre en considération que (je vous cache) je parle seulement de 4 gros tableau l'un au dessous de l'autre avec bcp d'autres données qui n'ont rien à voir avec ceux dont fait l'objet ce poste.

la formule que tu me donnes trop simple et hyper efficace (MERCI !!!!) je voulais remplacer MODE par GRANDE.VALEUR et changé l'indice 1 à 2 et 3 pour (le 1er, le 2nd et le 3ème nom le plus répété) mais ça ne marche pas ! voilà à quoi je fais référence quand je dis que je cherche une formule simple (ce genre là) mais je commence à croire que c'est pas faisable avec GRANDE.VALEUR !

si tu as une idée sur la question je te serais vraiment reconnaissant 🙂

Bien à toi 🙂

 

[BOISGONTIER]

Re : les 3 noms les plus répétés

Bonjour,

Avec fonction perso (+rapide)

Formules Matricielles

jb

 

[david84]

Re : les 3 noms les plus répétés

Re

Le plus simple est d'utiliser une colonne intermédiaire et 2 formules non matricielles :
- entrer en B1 (par exemple) :

=SI(A1="";"";SI(NB.SI(A$1:A1;A1)>1;"";NB.SI(zone;A1)))

tirer cette formule vers le bas

- entrer en C1 :

=INDEX(zone;EQUIV(GRANDE.VALEUR(B$1:B$20;LIGNE(1:1));B$1:B$20;0))

et tirer vers le bas.
Sinon passer par du VBA (mais apparemment tu veux éviter).
A+

 

[spectarus]

Re : les 3 noms les plus répétés

BOISGONTIER ça marche trop bien !

c'est exactement ce que je voulais ! Mille merci !

Bon week end à tous même si c'est après demain 😀