insertion de photo dans un commentaire

[zoef747]

bonjour,

ca fait toute l'apres midi que je fouille ce forum pour arriver a mes fins...
j'ai deja trouvé quasi tout ce que je voulais, sauf que je voudrais que la macro me propose de choisir la photo dans un repertoir (en locurence D:\DB\) et ca j'y parviens pas !

merci


With ActiveCell
.AddComment
.Comment.Visible = True
.Comment.Shape.Select True
With .Comment.Shape
.Width = 125
.Height = 170
.Fill.UserPicture "D:\BD\alpha08.jpg"
End With
.Comment.Visible = False
End With

 

[zoef747]

Re : insertion de photo dans un commentaire

merci,
je comprends pas tout mais je voudrais pouvoir choisir la photo moi meme car les noms de mes photo n'ont pas de correspondance systematique avec les valeur des cellules de mon tableau...
il faudrait donc si possible que je puisse selectionner le bon fichier (d'une fenetre pop up par ex)

 

[_Thierry]

Re : insertion de photo dans un commentaire

Bonjour Zoef747, Tatiak, le Forum


Voilà ton code auquel j'ai adjoint la méthode "GetOpenFilename" qui devrait faire ce quye tu souhaites :

Sub PictureInComment()
Dim PictureParth As Variant
PictureParth = Application.GetOpenFilename("Pictures Files (*.jpg), *.jpg")
    If PictureParth <> False Then
    
        With ActiveCell
        .AddComment
        .Comment.Visible = True
                With .Comment.Shape
                    .Width = 125
                    .Height = 170
                   .Fill.UserPicture PictureParth
                End With
        .Comment.Visible = False
        End With
        
    End If
End Sub

Bonne Fin de Journée

@+Thierry


​

 

[zoef747]

Re : insertion de photo dans un commentaire

merci,

cela fonctionne bien

est il possible de fignoler pour que le pop up s'ouvre directement dans le dossier D:\DB ?

 

[Compte Supprimé 979]

Re : insertion de photo dans un commentaire

Salut tout le monde,

Moi j'utilise l'API windows qui me permet d'accéder directement au dossier 😉
Voir le fichier joint

A+

 

[zoef747]

Re : insertion de photo dans un commentaire

merci bruno (et thierry et tatiak)

cela fonctionne aussi ( mais la macro est vachement plus longue) et du coup j'y comprend quasi rien ...

cela me plairait mieux d'arriver directement dans le don dossier avec la methode de Thierry

 

[bqtr]

Re : insertion de photo dans un commentaire

Bonjour zoef747, le fil

Modifie le début de la macro de _Thierry comme ceci :

Sub PictureInComment()
Dim PictureParth As Variant
ChDir ("D:\DB")
PictureParth = Application.GetOpenFilename("Pictures Files (*.jpg), *.jpg")
    If PictureParth <> False Then
..../....

La boite de dialogue s'ouvrira direcrement sur le dossier DB du disque D.

A+

 

[_Thierry]

Re : insertion de photo dans un commentaire

Bonsoir à tous

Oui pour le ChDir mais par contre il est toujours préférable de remettre le PC dans l'état où on le trouve avant l'éxécution un code VBA... Car sinon le répertoire du Travail Courant sera changé si on applique uniquement le ChDir.

Je pratique donc ainsi dans ce cas là :

Option Explicit
Sub PictureInComment()
Dim PictureParth As Variant
Dim UserDir As String
Dim UserDrive As String
UserDir = CurDir
UserDrive = Left(CurDir, 1)
ChDrive "I"
ChDir ("I:\mc_prod\Cash\")
 
PictureParth = Application.GetOpenFilename("Pictures Files (*.jpg), *.jpg")
    If PictureParth <> False Then
    
        With ActiveCell
        .AddComment
        .Comment.Visible = True
                With .Comment.Shape
                    .Width = 125
                    .Height = 170
                   .Fill.UserPicture PictureParth
                End With
        .Comment.Visible = False
        End With
        
    End If
 
ChDrive UserDrive
ChDir UserDir
End Sub

Bonne Soirée

@+Thierry
​