Index Equiv et Grande.valeur = problème

[zemixx]

Bonjour à tous,

Je regarde pas mal le forum pour obtenir de l'aide mais en vain.
J'ai un petit fichier qui me pose énormément de problème et je ne doute pas que plusieurs d'entre vous vont trouver la solution facilement.

Je joins un fichier faciliter la compréhension.

Mon objectif est de trouver le TOP 3 des valeurs, en fonction de 2 critères, la semaine et la ligne.
A partir de là, une fois que j'ai ce top 3, je dois faire une équivalence pour dire la valeur 100 = La ref A = Désgination XX.

En éspérant avoir été clair dans mon explication,

Merci d'avance

 

[job75]

Re : Index Equiv et Grande.valeur = problème

Bonjour zemixx, bienvenue sur XLD,

En I9, formule matricielle à copier vers le bas :

=GRANDE.VALEUR(($C$2:$C$11=$I$5)*($E$2:$E$11=$I$4)*$D$2:$D$11;LIGNES(I$9:I9))

En J9 (colonne auxiliaire masquée), formule matricielle à copier vers le bas :

=GRANDE.VALEUR(($C$2:$C$11=$I$5)*($E$2:$E$11=$I$4)*($D$2:$D$11-LIGNE($D$2:$D$11)/10000000);LIGNES(J$9:J9))

En K9, formule matricielle à copier sur L9 et vers le bas :

=INDEX(A$2:A$11;EQUIV(VRAI;$J9=$D$2:$D$11-LIGNE($D$2:$D$11)/10000000;0))

Toutes ces formules sont à valider par Ctrl+Maj+Entréee.

LIGNE($D$2:$D$11)/10000000 permet de distinguer les prix égaux.

Fichier joint.

A+

 

[job75]

Re : Index Equiv et Grande.valeur = problème

Re,

La colonne auxiliaire permet de comprendre les formules et de voir ce qui se passe.

Mais bien sûr on peut la supprimer et entrer en J9, toujours en matriciel :

=INDEX(A$2:A$11;EQUIV(VRAI;GRANDE.VALEUR(($C$2:$C$11=$I$5)*($E$2:$E$11=$I$4)*($D$2:$D$11-LIGNE($D$2:$D$11)/10000000);LIGNES(J$9:J9))=$D$2:$D$11-LIGNE($D$2:$D$11)/10000000;0))

Fichier (2).

A+

 

[zemixx]

Re : Index Equiv et Grande.valeur = problème

Merci beaucoup Job75,

C'est parfait, tu me sauves la vie. Encore merci

 

[leo1357]

Re : Index Equiv et Grande.valeur = problème

Bonjour à tous!

N'ayant pas trouvé de réponses à mes recherches, je me permets de poser ma question ici.
Voilà, je me suis largement inspiré du fichier de zemixx pour créer un top 5 des produits présents en grandes quantités en stock et cela en fonction de la semaine dernière et de l'année en cours. Jusqu'à la tout fonctionne.

Le problème vient du fait que les formules utilisées dans le fichier de zemixx concerne une plage définie ; hors pour ma part, ma plage sera variable, le fichier s'incrémentant automatiquement chaque semaine.

Étant plutôt novice à Excel, quelqu'un pourrait il m'aider à transformer les plages fixes en plages variables?

Je joins mon fichier qui sera peut être plus clair que mes explications.

Merci d'avance !!!

Léo

 

[CISCO]

Re : Index Equiv et Grande.valeur = problème

Bonsoir

Tu peux remplacer tes plages, par ex $C$2:$C$11, par des plages dynamiques définies à l'aide du gestionnaire de noms. Par ex, pour $C2:$C$11 utilise

=DECALER(Test!$C$2;;;EQUIV(9^9;Test!C:C;1)-1)

@ plus

 

[leo1357]

Re : Index Equiv et Grande.valeur = problème

Merci de ta réponse!! Cela fonctionne !!!

Bonne soirée !

A++