Index conditions multiples

[vashh]

Voila bonjour tout le monde. J'ai une base de données assez conséquentes et j'aimerais la trier. Pour cela, j'utilise une fonction index et sommeprod permettant de faire une recherche sur plusieurs criteres. Voila la formule :

=INDEX(CMJ!$A$2:$M$1880;SOMMEPROD((CMJ!$D$2:$D$1880="Carton 4")*(CMJ!$C$2:$C$1880="Rouge")*(CMJ!$M$2:$M$1880=0)*LIGNE(CMJ!$A$2:$A$1880))-1;1)

Cette fonction fonctionne très bien lorsque mon sommeprod ne pointe qu'une cellule. Le problème est donc lorsque mon sommeprod me renvoie plusieurs valeurs. Du coup, mon index qui ne peut renvoyer qu'une valeur me renvoie #Ref!. Comment puis je faire pour que l'index me renvoie toutes les valeurs trouvés par mon sommeprod.

Je vous remercie d'avance.

 

[job75]

Re : Index conditions multiples

Bonsoir vashh, bienvenue sur XLD,

Voyez les formules matricielles utilisant les fonctions PETITE.VALEUR ou GRANDE.VALEUR.

Il y a pas mal d'exemples d'utilisations de ce genre sur le forum.

A noter que SOMMEPROD ne renvoie toujours qu'une seule valeur : la somme de plusieurs produits.

A+

 

[vashh]

Re : Index conditions multiples

Je te remercie je vais voir ce que je peux faire avec ca.

Je vais vous mettre un exemple pour que vous compreniez. Mon but est de faire qu'avec une formule, je puisse afficher toutes les réfs dont le type est A et dont la taille est 13 par exemple.

Merci d'avance.

BDD :

Réf Type Taille
1 A 12
2 A 13
3 B 18
4 C 15
5 A 13

 

[vashh]

Re : Index conditions multiples

Je ne vois vraiment pas comment faire, j'ai essayé avec la fonction equiv mais ca ne donne rien ...

 

[Tibo]

Re : Index conditions multiples

Bonjour,

Peux-tu nous joindre un vrai fichier Excel avec peut-être une vingtaine de lignes et le résultat attendu ?

On cernera sans doute mieux ton souhait.

A te (re)lire

@+

 

[vashh]

Re : Index conditions multiples

si bien sur, voila le fichier en tres simplifié, en esperant avoir été clair.

 

[job75]

Re : Index conditions multiples

Bonjour vashh, Tibo,

Le 1er exemple avec la formule matricielle en F7 :

=SI(LIGNES(F$7:F7)>SOMME((C$3:C$1000=G$2)*(D$3:D$1000=G$4));"";INDEX(B:B;PETITE.VALEUR(SI((C$3:C$1000=G$2)*(D$3:D$1000=G$4);LIGNE($3:$1000));LIGNES(F$7:F7))))

A+

 

[vashh]

Re : Index conditions multiples

Genial, je te remercie ta solution est parfaite !!!

 

[BOISGONTIER]

Re : Index conditions multiples

Bonjour,

=SI(LIGNES($1:1)<=SOMMEPROD((cont=$I$3)*(nb=$J$3));INDEX(ref;PETITE.VALEUR(SI((cont=$I$3)*(nb=$J$3);LIGNE(INDIRECT("1:"&LIGNES(cont))));LIGNES($1:1)));"")

Voir PJ

JB
Formation Excel VBA JB

 

[job75]

Re : Index conditions multiples

Re, salut JB,

JB nomme les plages ce qui est souvent bien utile.

Mais des références externes (avec le nom de la feuille) peuvent suffire.

En B7 de la feuille "Analyse", toujours matricielle :

=SI(LIGNES(B$7:B7)>SOMME((BDD!C$3:C$1000=C$2)*(BDD!D$3:D$1000=C$4));"";INDEX(BDD!B:B;PETITE.VALEUR(SI((BDD!C$3:C$1000=C$2)*(BDD!D$3:D$1000=C$4);LIGNE($3:$1000));LIGNES(B$7:B7))))

A+