Ignorer condition - Formule sommeprod

N

Nairolf

XLDnaute Accro

• 23 Août 2016

• #2

Salut,

Essaie avec la formule suivante :

Code:

=SOMMEPROD((A4:A100=H13)*D4:D100+(B4:B100=I13)*D4:D100+(C4:C100=J13)*D4:D100)

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 23 Août 2016

• #3

Bonjour..
sans meme ouvrir le fichier..

Je recherche une formule qui ne prennent pas en compte la ou les conditions manquantes

Cliquez pour agrandir...

euh.. suffirait de ne pas écrire cette condition?

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 23 Août 2016

• #4

Bonjour à tous,

A essayer avec des si()

Code:

=SI(NBVAL($G$2:$I$2)=3;SOMMEPROD((A4:A100=G2)*(B4:B100=H2)*(C4:C100=I2)*D4:D100);SI(ET(NBVAL($G$2:$I$2)=2;$G$2="");SOMMEPROD((B4:B100=H2)*(C4:C100=I2)*D4:D100);SI(ET(NBVAL($G$2:$I$2)=1;$I$2<>"");SOMME.SI(C4:C100;I2;D4:D100);"")))

JHA

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 23 Août 2016

• #5

Bonjour @ tous,

Code:

=SOMME.SI.ENS(D4:D100;A4:A100;SI(H13="";"*";H13);B4:B100;SI(I13="";"*";I13);C4:C100;SI(J13="";"*";J13))

@ + +

 

Vote positif 0 Vote négatif

Iznogood1

XLDnaute Impliqué

• 23 Août 2016

• #6

Bonjour,


Il faut tester les différentes combinaisons.
En logique booléenne, le OU est égal à + et le ET est égal à x
D'où la formule

Code:

=SOMMEPROD((A4:A100=G2)*(B4:B100=H2)*(C4:C100=I2)*D4:D100)+
SOMMEPROD((B4:B100=H2)*(C4:C100=I2)*D4:D100)*ESTVIDE(G2)+
SOMMEPROD((A4:A100=G2)*(C4:C100=I2)*D4:D100)*ESTVIDE(H2)+
SOMMEPROD((A4:A100=G2)*(B4:B100=H2)*D4:D100)*ESTVIDE(I2)+
SOMMEPROD((A4:A100=G2)*D4:D100)*ESTVIDE(H2)*ESTVIDE(I2)+
SOMMEPROD((B4:B100=H2)*D4:D100)*ESTVIDE(G2)*ESTVIDE(I2)+
SOMMEPROD((C4:C100=I2)*D4:D100)*ESTVIDE(G2)*ESTVIDE(H2)

 

Dernière édition: 25 Août 2016

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 23 Août 2016

• #7

sinon. en regardant le fichier.. ;-)
formule matricielle.. à valider par Ctrl+Maj + Entrée (malgré le sommeprod...)
=SOMMEPROD((SI(G2<>"";A4:A100=G2;1))*(SI(H2<>"";B4:B100=H2;1))*(SI(I2<>"";C4:C100=I2;1))*D4😀100)

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 23 Août 2016

• #8

Re,
faites des tests et vous allez trouver que seule qui renvoie les bons résultats pour tous les cas de figures.

 

Vote positif 0 Vote négatif

gourdin

XLDnaute Impliqué

• 23 Août 2016

• #9

Merci à tous,

Je me lance dans les tests dès que possible

Bonne fin d'après midi

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 23 Août 2016

• #10

Bonjour à tous,

Effectivement, j'ai oublié une condition, désolé!

Code:

=SI(NBVAL($G$2:$I$2)=3;SOMMEPROD((A4:A100=G2)*(B4:B100=H2)*(C4:C100=I2)*D4:D100);SI(ET(NBVAL($G$2:$I$2)=2;$G$2="");SOMMEPROD((B4:B100=H2)*(C4:C100=I2)*D4:D100);SI(ET(NBVAL($G$2:$I$2)=2;$H$2="");SOMMEPROD((A4:A100=G2)*(C4:C100=I2)*D4:D100);SI(ET(NBVAL($G$2:$I$2)=1;$I$2<>"");SOMME.SI(C4:C100;I2;D4:D100);""))))

JHA

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 23 Août 2016

• #11

Re,
Salut JHA,
Pour le cas ou juste 2 cellules qui sont renseignées on a 3 cas de figure et aussi quand juste une seule qui est renseignée on a 3 cas de figure, tu en prends que deux pour chaque cas.

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 23 Août 2016

• #12

Re,

Bon, fatigué le gars, je vais me coucher.

JHA

 

Vote positif 0 Vote négatif