generer un rapport PDF

[nicroq]

Bonjour,
je souhaiterai savoir si il est possible de generer un rapport PDF a partir d une macro.
En effet je viens de finir une macro qui me genere plusieur sheet et je souhaiterai que la "sheet1" soit ensuite generer en PDF de facon à ce qu 'elle soit a la fois enregistrer dans un dossier et imprimer en PDF.

En vous remerciant
Nicolas

 

[Dranreb]

Re : generer un rapport PDF

Bonjour,
Il doit bien être possible par macros de l'impprimer comme normalement mais sur l'imprimante virtuelle d'adobe, non ?

 

[nicroq]

Re : generer un rapport PDF

en fait, c'est surtout de faire la sauvegarde en PDF qui est le plus important pour moi

 

[Dranreb]

Re : generer un rapport PDF

en fait, c'est surtout de faire la sauvegarde en PDF qui est le plus important pour moi

Oui, la passerelle Adobe Accrobat vue comme une imprimante de tout application sachant imprimer, vous demande le nom du PDF que vous voulez créer !

 

[kiki29]

Re : generer un rapport PDF

Salut,à partir d'Excel 2007 SP2 la génération de PDF est native pour les versions antérieures il y a Acrobat Distiller ( payant ) ou PDFCreator ( Gratuit ) pour créer des fichiers PDF

Pour Acrobat voir Excel vers PDF avec Acrobat Distiller - Forum des professionnels en informatique

Pour PDFCreator voir Google

PDFCreator dispo sur pdfforge.org | The free PDF Creator and Converter

Au final tu devrais trouver un code du genre

Option Explicit

Sub TstPdfCreator()
Dim JobPDF As Object
Dim sNomPDF As String
Dim sCheminPDF As String
    
    sNomPDF = "commande_" & Range("B13") & ".pdf"
    sCheminPDF = ThisWorkbook.Path & "\"

    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    Set JobPDF = CreateObject("PDFCreator.clsPDFCreator")

    With JobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sCheminPDF
        .cOption("AutosaveFilename") = sNomPDF
        
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx, 5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With

    ActiveWorkbook.PrintOut copies:=1, ActivePrinter:="PDFCreator"

    'Fichier dans la file d'attente
    Do Until JobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
    JobPDF.cPrinterStop = False

    'Attendre que la file d'attente soit vide
    Do Until JobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
    JobPDF.cClose
    Set JobPDF = Nothing
End Sub

 

[Dranreb]

Re : generer un rapport PDF

Ah! mais je le savais bien qu'au final il n'y avait qu'une simple impression dans tout ça !
Oui mais voila, c'est tout ce que je savais, et c'est bien peu, à coté des précieuses indications de kiki29,
devant lesquelles je m'incline bien bas.