formule texte avec "*"

[rafi93]

bonjour à tous
j'essaie d'écrire une formule qui teste si une chaine de caractères commence par ou finit par une certaine chaine, en utilisant le wildcar *
p.ex "ti" dans les 2 exemples ci dessous
=SI($A9="ti*";1;0)
=SI($A9="*ti";1;0)
mais ça ne marche pas, car excel recherche le caractère * pour de vrai

y a t il une "astuce" ? (sans vba)

je sais qu'il y a les fonctions cherche ou trouve, mais c'est galère car il faut traiter le retour #NA, et ça fait des formules à rallonge

merci !!

 

[CISCO]

Re : formule texte avec "*"

Bonsoir

Tu peux faire les deux cas avec

SI(NBCAR(SUBSTITUE(A1;"ti";""))<NBCAR(A1);1;0)

@ plus

 

[rafi93]

Re : formule texte avec "*"

Bonsoir

Tu peux faire les deux cas avec

SI(NBCAR(SUBSTITUE(A1;"ti";""))<NBCAR(A1);1;0)

@ plus

ouaouh !
j'aurais pas trouvé tout seul
merci
j'ai testé, ça donne "contient" (pratique également)
et si je voulais "commence par" ou "finit par" ?

 

[job75]

Re : formule texte avec "*"

Bonjour rafi93, CISCO,

et si je voulais "commence par" ou "finit par" ?

=N(GAUCHE(A1;2)="ti")
=N(DROITE(A1;2)="ti")

PS : la fonction SI "pèse" lourd, il vaut mieux l'éviter quand c'est possible.

A+

 

[david84]

Re : formule texte avec "*"

Bonjour, salut Cisco,

=NB.SI(A1;"*ti*")

ramène 1si la chaîne contient "ti".

Pour voir si la chaîne commence par "ti" :

=SIERREUR(SI(CHERCHE("ti";A1)=1;"commence par";"ne commence pas par");"n'existe pas")

A+

Edit : salut Gérard

 

[rafi93]

Re : formule texte avec "*"

ok parfait merci !
une question : en m'en inspirant j'écris la formule
=GAUCHE(A6;2)="ti"
qui me renvoie "vrai" ou "faux"
qu'est ce qui fait que excel interprète cela ainsi ? (et ne renvoie pas une erreur de syntaxe)

 

[job75]

Re : formule texte avec "*"

Re,

Voyez l'aide Excel sur la fonction N() : les valeurs logiques sont converties en 1 ou 0.

Pour terminer, si l'on veut que la casse soit respectée :

=N(EXACT(GAUCHE(A1;2);"ti"))
=N(EXACT(DROITE(A1;2);"ti"))

Edit : salut David 🙂

A+

 

[rafi93]

Re : formule texte avec "*"

ça j'ai compris
c'était pour la syntaxe
=GAUCHE(A6;2)="ti"
pour laquelle je ne comprends pas pourquoi il retourne vrai ou faux
cette écriture equivaut à un SI ?

 

[job75]

Re : formule texte avec "*"

Re,

Quand vous écrivez =GAUCHE(A6;2)="ti"

Excel, comme pour toutes les formules, évalue tout ce qui est à droite du 1er signe =.

C'est élémentaire non ?

A+

 

[rafi93]

Re : formule texte avec "*"

vu comme ça, je comprends, merci

sinon, par rapport à la question initiale, la solution la plus élégante et la plus compacte est certainement
=NB.SI(A1;"*ti*")
qui permet de jouer avec les * ("contient", "commence par" ou "finit par")
merci à tous !

 

[CISCO]

Re : formule texte avec "*"

Bonjour à tous, bonjour Job75 et David84

Et pourquoi

=A1="*ti*"

ne fonctionne pas ?

@ plus

 

[job75]

Re : formule texte avec "*"

Bonjour CISCO, le forum,

Parce que l'opérateur de comparaison "=" fonctionne comme ça :

- les chaînes de caractères sont comparées littéralement

- les caractères "*" ou "?" ne sont donc pas traités comme "génériques"

- la casse est ignorée.

En VBA il existe l'opérateur Like :

MsgBox [A1] Like "*ti*"

qui respecte la casse [Edit] sauf si l'on utilise Option Compare Text.

Bonne journée.

 

[CISCO]

Re : formule texte avec "*"

Bonjour

Merci Job75.

Bon 1er mai

@ plus