formule qui affiche la première case vide

[katie]

bonjour à tous,
je recherche une formule qui m'affiche la première case vide
cf. pièce jointe
merci d'avance pour le coup de main ou pluôt le coup de souris

 

[Victor21]

Re : formule qui affiche la première case vide

Bonsoir.

Essayez en A5 :

=DECALER(A5;-1;EQUIV(9^9;B5:M5)+1)

avec éventuellement une condition si le nb de valeurs entre B et M est 12; ou si M n'est pas vide.

Ajout : Ou inscrire ok en N1, N4, N7, N10

 

[job75]

Re : formule qui affiche la première case vide

Bonsoir katie, Patrick

Sur le même principe, formule en A5 à copier en A8 et A11 :

=SI(NB(B5:M5)=12;"ok";INDEX(B4:M4;EQUIV(9^9;B5:M5)+1))

INDEX permet de se passer de DECALER qui est volatile.

Cela évite l'invite à la fermeture.

Fichier joint.

A+

 

[katie]

Re : formule qui affiche la première case vide

merci à vous 2 (victor21 et job75) ça fonctionne impeccable
mille merci
bonne soirée

 

[R@chid]

Re : formule qui affiche la première case vide

Salut,
une variante en A5 :

=INDEX($A$4:$M$4;MAX(($B$5:$M$5<>"")*(COLONNE($B$5:$M$5)))+1)

@ valider en matricielle par Ctrl+Maj+Entree
@ + +
Rachid

 

[JHA]

Re : formule qui affiche la première case vide

Bonjour à tous,

Une toute petite modif sur la formule de Job75 au cas où rien n'est inscrit dans le tableau

=SI(NB(B5:M5)=12;"ok";SI(NB(B5:M5)=0;B4;INDEX(B4:M4;EQUIV(9^9;B5:M5)+1)))

JHA

 

[job75]

Re : formule qui affiche la première case vide

Bonjour JHA, le forum,

Bien d'accord, et l'on peut même dans ce cas simplifier la formule :

=SI(NB(B5:M5)=12;"ok";INDEX(B4:M4;SI(NB(B5:M5);EQUIV(9^9;B5:M5))+1))

Fichier (2).

A+

 

[ndragon]

Re : formule qui affiche la première case vide

Bonjour,
je profite du topic pour demander qu'est ce que c'est que "9^9" dans l'equiv?
il a l'air de permettre de tester si c'est un nombre ou pas mais je comprends pas comment cela fonctionne.

 

[JHA]

Re : formule qui affiche la première case vide

Bonjour,

le calcul 9^9 est égal à "387420489" donc la fonction recherche ce chiffre, comme elle ne le trouve pas, elle renvoie la dernière valeur de la plage de recherche.

JHA

 

[ndragon]

Re : formule qui affiche la première case vide

je comprends pas pourquoi on n'utilise pas uniquement la valeur donnée par NB()?
le EQUIV nous donne un chiffre qu'on a déjà via NB.

 

[R@chid]

Re : formule qui affiche la première case vide

Salut tout le monde,
pourquoi pas plus simple :

=SI(NB(B2:M2)=12;"OK";DECALER($A$1;;NB($B$2:$M$2)+1))

ou

=CHOISIR((NB(B2:M2)<12)+1;"OK";DECALER($A$1;;NB($B$2:$M$2)+1))

@ + +
Rachid