XL 2016 Formule pour additionner des données

[rom77100]

Bonjour,

J'ai besoin de votre aide s'il vous plaît.
Dans mon tableau ci-joint, j'aimerais calculer les données fin de mois dans l'onglet "synthèse". Pour ce faire, le critère est une liste déroulante.
En effet quand je sélectionne "Données A fin Novembre", j'aimerais pouvoir calculer les données issus de l'onglet Base reportant des données mensuels en additionnant automatiquement les données de janvier à novembre.
Je ne sais pas trop comment m'y prendre.

Un grand merci par avance.
Romain

 

[JHA]

Bonjour à tous,

A essayer en "C6"

=INDEX(Base!$C$3:$N$23;EQUIV(Synthèse!$B6;Base!$B$3:$B$23;0);EQUIV(EQUIV(Synthèse!$C$3;Mois;0);MOIS(1&Base!$C$2:$N$2);0))

validation matricielle
copier vers le bas

JHA

 

[rom77100]

Bonjour à tous,

A essayer en "C6"

=INDEX(Base!$C$3:$N$23;EQUIV(Synthèse!$B6;Base!$B$3:$B$23;0);EQUIV(EQUIV(Synthèse!$C$3;Mois;0);MOIS(1&Base!$C$2:$N$2);0))

validation matricielle
copier vers le bas

JHA

Bonsoir,
Merci pour votre promptitude. Cependant ce n'est pas tout a fait ce que j'attendais. Puisque les données à fin février par expemple doivent additionner les montants de janvier + février. A fin mars, j'aimerais avoir les données de janvier, février et mars.

Merci d'avace pour votre aide. Et désolé si je me suis mal exprimé dans mon précédent message.
Romain

 

[Cousinhub]

Bonsoir,
Un autre essai :

=SOMME(DECALER(Base!$C$2;EQUIV($B9;Base!$B$3:$B$23;0);;;EQUIV($C$3;Mois;0)))

à mettre en C6 de l'onglet Synthèse et à recopier vers le bas
Bonne soirée

 

[rom77100]

Bonsoir,
Un autre essai :

=SOMME(DECALER(Base!$C$2;EQUIV($B9;Base!$B$3:$B$23;0);;;EQUIV($C$3;Mois;0)))

à mettre en C6 de l'onglet Synthèse et à recopier vers le bas
Bonne soirée

C'est la solution à mon problème. Unn grand merci

 

[rom77100]

Bonjour à toutes et tous,

Je vous souhaite tous mes vœux pour cette nouvelle année.

En ce qui concerne mon problème, ce n'est pas tout à fait résolu. en effet, la formule va chercher le premier numéro de compte qu'il trouve, cependant, il peut y avoir plusieurs même numéro de compte. De ce fait ça ne s’additionne pas.

Quelqu'un pourrait m'aider sur le même principe mais qu'il puisse cumuler les données par mois et additionner si il y a plusieurs même numéro de compte.

Merci d'avance pour votre aide.

 

[rom77100]

Bonsoir,
Un autre essai :

=SOMME(DECALER(Base!$C$2;EQUIV($B9;Base!$B$3:$B$23;0);;;EQUIV($C$3;Mois;0)))

à mettre en C6 de l'onglet Synthèse et à recopier vers le bas
Bonne soirée

Bonjour à toutes et tous,

Je vous souhaite tous mes vœux pour cette nouvelle année.

En ce qui concerne mon problème, ce n'est pas tout à fait résolu. en effet, la formule va chercher le premier numéro de compte qu'il trouve, cependant, il peut y avoir plusieurs même numéro de compte. De ce fait ça ne s’additionne pas.

Quelqu'un pourrait m'aider sur le même principe mais qu'il puisse cumuler les données par mois et additionner si il y a plusieurs même numéro de compte.

Merci d'avance pour votre aide.

 

[JHA]

Bonjour à tous,

A essayer

=SOMMEPROD((Compte=Synthèse!$B6)*(DECALER(Base!$C$2;1;;NBVAL(Compte);EQUIV($C$3;Mois;0))))

JHA

 

[rom77100]

Bonjour à tous,

A essayer

=SOMMEPROD((Compte=Synthèse!$B6)*(DECALER(Base!$C$2;1;;NBVAL(Compte);EQUIV($C$3;Mois;0))))

JHA

Merci beaucoup. C'est exactement ce qu'il me fallait. Cependant, si je souhaite ajouter un filtre supplémentaire. Exemple pour un même N° de compte, il peut avoir différents service, donc faire la même formule avec un filtre supplémentaire ?
Ci-joint le fichier avec des exemples.

Merci d'avance.

 

[rom77100]

Merci beaucoup. C'est exactement ce qu'il me fallait. Cependant, si je souhaite ajouter un filtre supplémentaire. Exemple pour un même N° de compte, il peut avoir différents service, donc faire la même formule avec un filtre supplémentaire ?
Ci-joint le fichier avec des exemples.

 

[JHA]

Bonjour à tous,

C'est le même principe

=SOMMEPROD((Compte=Synthèse!$B6)*(DECALER(Compte;;1)=Synthèse!$C6)*(DECALER(Base!$D$2;1;;NBVAL(Compte);EQUIV($D$3;Mois;0))))

JHA