Formule conditions SI-et (simplification)

[JJ1]

Bonjour,
J'ai un tableau où j'ai défini 4 plages différentes: x y z p
Je voudrais faire une condition si avec comme conditions:
- A1 présent 3 fois dans la plage p
- A1 présent 0 ou 1 fois dans les plages x y et z puis 1 fois dans les 3 plages (donc les combinaisons 001 à 111)
ces conditions donnant en résultat les lettres A à F
j'ai commencé la formule pour les combinaisons:

si(et(nb.si(x;A1)=1;nb.si(y;A1)=0;nb.si(z;A1)=0);"A";si(et(nb.si(x;A1)=0;nb.si(y;A1)=1;nb.si(z;A1)=0);"B";si(et((nb.si(x;A1)=0;nb.si(y;A1)=0;nb.si(z;A1)=1);"C";si(et(nb.si(x;A1)=1;nb.si(y;A1)=1;nb.si(z;A1)=0);"D";si(et(nb.si(x;A1)=0;nb.si(y;A1)=1;nb.si(z;A1)=1);"E";si(et((nb.si(x;A1)=1;nb.si(y;A1)=1;nb.si(z;A1)=1);"F";"")
dans ma formule la 1ère condition (plage p) n'y est pas, il faut la rajouter.
Comment faire simple?
merci
bon samedi

 

[Tibo]

Re : Formule conditions SI-et (simplification)

Bonjour,

Avec un petit bout de fichier, ça aurait été quand même plus sympa ...

Peut-être avec une concaténation de SI :

=si(et(nb.si(x;A1)=1;nb.si(y;A1)=0;nb.si(z;A1)=0);"A";"")&
si(et(nb.si(x;A1)=0;nb.si(y;A1)=1;nb.si(z;A1)=0);"B";"")&...

ainsi plus limité par le problème les 7 niveaux d'imbrication.

Apparaît cependant une autre limite : longueur maxi d'une formule : 1024 caractères (8000 et quelques pour Excel 2007 je crois).

@+

 

[Tibo]

Re : Formule conditions SI-et (simplification)

re,

s'il s'agit de modifier ta formule rapidement, tu peux passer par le remplacer :

Remplacer : nb.si(z;A1)=0
par : nb.si(z;A1)=0;nb.si(p;A1)=0

Tu devrais avoir 4 remplacements à faire :

avec z = 0 et p = 0
avec z = 0 et p = 1
avec z = 1 et p = 0
avec z = 1 et p = 1

Mais n'ayant pas forcément compris, suis sûr de rien.

@+

 

[JJ1]

Re : Formule conditions SI-et (simplification)

Bonjour Tibo, Le Forum,
Merci pour ta réponse, je te joins un bout de fichier pour te montrer les conditions, j'ai pris un exemple concret.
ps: le nombre de A1 dans p est fixe et égal à 3 sinon pas de test SI suivant, la cellule U1 passant à "".
merci et bon AM

 

[Tibo]

Re : Formule conditions SI-et (simplification)

re,

Peut-être avec cette formule :

=SI(NB.SI(p;A1)<>3;"";CHOISIR((NB.SI(x;A1)*4)+(NB.SI(y;A1)*2)+NB.SI(z;A1);
"C";"B";"E";"A";"";"D";"F"))

à noter qu'il semble manquer une combinaison : avec x - 1, y - 0 et z - 1

Je te laisse tester, ne sachant pas vraiment à quoi ça doit servir (s'il s'agit du prochain tirage du loto, tu peux m'en parler en toute discrétion en MP 😛😀)

@+

 

[job75]

Re : Formule conditions SI-et (simplification)

Bonjour JJ1, Tibo,

De mon coté une formule assez lourde, utilisant la concaténation des NB.SI et une recherche dans une matrice 2 x 6 :

=SI(ET(NB.SI(p;A1)=3;ESTTEXTE(RECHERCHEV(NB.SI(x;A1)&NB.SI(y;A1)&NB.SI(z;A1);{"100"."A";"010"."B";"001"."C";"110"."D";"011"."E";"111"."F"};2;0)));RECHERCHEV(NB.SI(x;A1)&NB.SI(y;A1)&NB.SI(z;A1);{"100"."A";"010"."B";"001"."C";"110"."D";"011"."E";"111"."F"};2;0);"")

Mais pas testé...

A+

 

[Raja]

Re : Formule conditions SI-et (simplification)

Bonjour,

Regarde dans le fichier joint la partie surlignée en jaune. Je suis passée par une colonne intermédiaire G (évenutuellement à masquer) pour y arriver. A adapter.

édit : salut tibo et job75

 

[JJ1]

Re : Formule conditions SI-et (simplification)

Rebonjour à tous, effectivement pas simple....
j'ai fait un tableau (peu importe les lettres) pour montrer les possibilités.
Voici aussi un lien car j'ai fait une recherche sur le Forum, me souvenant d'un rangement similaire, mais pas simple non plus!

https://www.excel-downloads.com/threads/rangement-sous-12-conditions.83430/

merci à tous.

 

[Tibo]

Re : Formule conditions SI-et (simplification)

re,

Sur la base du fichier que tu avais joint à 15h59, tu nous indiquais que le résultat de la formule devait donner B.

Ce que donne la formule que je t'ai proposé.

As-tu testé avec d'autres combinaisons les différentes formules proposées ?

Sinon, joins nous un fichier (dans le même style que celui de 15h59) avec plusieurs combinaisons et en nousn indiquant les résultats attendus.

Ca sera à mon avis plus simple de contrôler nos formules.

A te (re)lire

@+

 

[Raja]

Re : Formule conditions SI-et (simplification)

Re,

Explique-toi clairement ce que tu veux. Ta table n'est pas non plus très logique.

 

[soenda]

Re : Formule conditions SI-et (simplification)

Bonjour a tous

Au vu du premier poste, je propose la formule suivante:

=CHOISIR((NB.SI(z;A1)=1)*4+(NB.SI(y;A1)=1)*2+(NB.SI(x;A1)=1);"A";"B";"D";"C";"E";"";"F")

A plus

 

[JJ1]

Re : Formule conditions SI-et (simplification)

bonsoir et encore merci pour vos solutions, j'y ai trouvé mon bonheur et le tableau est fini grâce à vous.
Bonne soirée

 

[jeanpierre]

Re : Formule conditions SI-et (simplification)

Bonsoir à tous,

"j'y ai trouvé mon bonheur et le tableau est fini grâce à vous."

C'est parfait donc, mais....

on ne connaitra jamais la réponse.............

 

[JeanMarie]

Re : Formule conditions SI-et (simplification)

Bonjour tout le monde

Une autre proposition, à valider par Ctrl+Shift+Entrer

=SI(NB.SI(A2:F9;A1)>0;STXT("A BDCE  F";SOMME(FREQUENCE(SI(A2:F4=A1;LIGNE(2:4));{2;3})*{1;3;5});1);"")

@+Jean-Marie