Fonctions Val et Replace

Pino12 · 6 Octobre 2014

Bonjour,

Afin de mieux comprendre les mécanismes d'une macro je cherche les équivalents en formule excel des formules Vba "Val" et "Replace", si de tels équivalents existent. Pouvez-vous m'aider ?

Merci d'avance,

john · 6 Octobre 2014

Re : Fonctions Val et Replace

Bonjour,

Si je dis pas de bêtise

en B1 =CNUM(A1) ==> pour val(A1) (en A1 j'y ai inscris '25) et
en B2 =SUBSTITUE(A2;"is";"c'est") (dans A2 j'y ai inscris "coucou is moi")

John

Pino12 · 6 Octobre 2014

Re : Fonctions Val et Replace

C'est bien ce que je cherchais, merci !

job75 · 6 Octobre 2014

Re : Fonctions Val et Replace

Bonjour Pino12, john,

D'accord avec john pour l'équivalent de Replace.

Mais pas du tout pour l'équivalent de Val, c'est beaucoup plus compliqué.

Pour cela on peut utiliser cette formule matricielle, validée par Ctrl+Maj+Entrée :

Code:

=--GAUCHE(0&A1;EQUIV(1;(STXT(0&A1&" ";LIGNE(INDIRECT("1:"&NBCAR(0&A1&" ")));1)<>STXT(1/10;2;1))*((STXT(0&A1&" ";LIGNE(INDIRECT("1:"&NBCAR(0&A1&" ")));1)<"0")+(STXT(0&A1&" ";LIGNE(INDIRECT("1:"&NBCAR(0&A1&" ")));1)>"9"));0)-1)

Elle fonctionne quel que soit le séparateur décimal de l'ordi.

A+

job75 · 6 Octobre 2014

Re : Fonctions Val et Replace

Re,

Et encore, la formule précédente ne fonctionne que pour les nombres positifs (sans signe).

A+

job75 · 6 Octobre 2014

Re : Fonctions Val et Replace

Re,

Fichier joint avec cette formule qui fonctionne aussi sur les nombres négatifs :

Code:

=SI(GAUCHE(A1)="-";-GAUCHE(DROITE(A1;NBCAR(A1)-1)&" ";EQUIV(1;(STXT(DROITE(A1;NBCAR(A1)-1)&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)));1)<>STXT(1/10;2;1))*((STXT(DROITE(A1;NBCAR(A1)-1)&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)));1)<"0")+(STXT(DROITE(A1;NBCAR(A1)-1)&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)));1)>"9"));0)-1);--GAUCHE(0&A1;EQUIV(1;(STXT(0&A1&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)+2));1)<>STXT(1/10;2;1))*((STXT(0&A1&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)+2));1)<"0")+(STXT(0&A1&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)+2));1)>"9"));0)-1))

A+

mapomme · 6 Octobre 2014

Re : Fonctions Val et Replace

Bonsoir à tous ,

Un essai avec une autre formule matricielle:

Code:

=SIERREUR(0+GAUCHE(A1;-PETITE.VALEUR(SI(ESTNUM((0+STXT(A1;1;LIGNE(INDIRECT("1:" & NBCAR(A1))))));-LIGNE(INDIRECT("1:" & NBCAR(A1))));1));"")

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

job75 · 6 Octobre 2014

Re : Fonctions Val et Replace

Bonsoir mapomme,

Ah oui, bravo, c'est beaucoup plus simple.

Alors perso j'utiliserai plutôt :

Code:

=SIERREUR(--GAUCHE(A13;MAX(ESTNUM((-STXT(A13;1;LIGNE(INDIRECT("1:" & NBCAR(A13))))))*LIGNE(INDIRECT("1:" & NBCAR(A13)))));0)

encore plus simple, et qui colle mieux à la fonction Val.

A+

Pino12 · 7 Octobre 2014

Re : Fonctions Val et Replace

Ok c'est bien plus compliqué que je le pensais^^ Merci !

Fonctions Val et Replace

Pino12

XLDnaute Junior

john

XLDnaute Impliqué

Pino12

XLDnaute Junior

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

mapomme

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pino12

XLDnaute Junior

Discussions similaires