Fonctions combinée avec index et equiv

[sophie1313]

Bonjour,

Je suis nouvelle sur ce forum et c'est la première fois que j'en utilise un, alors svp soyez cléments !

Voilà mon problème. Je souhaite utiliser une formule avec les fonction si, equiv et index mais là je ne m'en sors pas. La formule que j'ai essayé (entre autres) :

=SI(F2="Anglais";INDEX(Termes_Français;EQUIV(A6;Chrono3);SI(F2="Français";INDEX(Termes_Anglais;EQUIV(A6;Chrono3);"rien"))))

Ce que je souhaite obtenir : si j'affiche le mot "Français" dans une cellule il doit faire la recherche dans une colonne nommée "Termes_Français" (sur une autre feuille du classeur), si c'est anglais,il doit faire la recherche dans une autre colonne nommée "Termes_Anglais" et me renvoyer l'une ou l'autre valeur !

Cela fonctionne avec la première partie de la formule (il affiche bien les termes en français mais pas avec la deuxième (lorsque je saisi anglais), il affiche "FAUX" ??????

J'espère que ce n'est pas trop brouillon comme explication ????

Cela fait des heures que je suis sur cette formule. Si quelqu'un peut m'aider, please !

 

[JCGL]

Re : Fonctions combinée avec index et equiv

Bonjour à tous,
Bienvenue sur XLD,

Peux-tu déposer ton fichier sur XLD ?

A+ à tous

 

[JHA]

Re : Fonctions combinée avec index et equiv

Bonjour,

peut être:

=SI(F2="Anglais";INDEX(Termes_Français;EQUIV(A6;Chrono3;0));SI(F2="Français";INDEX(Termes_Anglais;EQUIV(A6;Chrono3;0));"rien"))

JHA

 

[sophie1313]

Re : Fonctions combinée avec index et equiv

Re bonjour,


Merci pour votre réponse j'ai envoyé le fichier. J'espère que je ne me suis pas trompée dans l'envoi.

Vous avez peut-être du la recevoir 4 fois. Désolée !!!

Merci

 

[JCGL]

Re : Fonctions combinée avec index et equiv

Bonjour à tous,

Fichier non reçu.

Dans la réponse :

• Aller en mode avancé
• Gérer les pièces jointes
• Parcourir
• Trouver le fichier (moins de 40 Ko ou zipper)
• Envoyer

A+ à tous

 

[sophie1313]

Re : Fonctions combinée avec index et equiv

Re bonjour,

Désolée, je re-essaie. Voilà il a fallu que je réduise considérablement la taille de mon fichier. J'espère que cela a fonctionné, je crois que oui !

Merci par avance.

Cordialement,

 

[JCGL]

Re : Fonctions combinée avec index et equiv

Bonjour à tous,

Peux-tu essayer en A3 et vers le bas :

=SI($F$2="Anglais";RECHERCHEV(A6;Vocabulaire!$A$3:$C$300;2;0);RECHERCHEV(A6;Vocabulaire!$A$3:$C$300;3;0))

A+ à tous

 

[sophie1313]

Re : Fonctions combinée avec index et equiv

Re,

Cela fonctionne très bien ! J'ai soit l'une ou l'autre de mes colonnes (français ou anglais). Je n'ai pas pensé à utiliser la fonction rechercheV. Merci beaucoup pour ton aide JCGL.

Cordialement,

 

[mercibien]

Re : Fonctions combinée avec index et equiv

Bonjour,

Je suis nouvelle sur ce forum et c'est la première fois que j'en utilise un, alors svp soyez cléments !

Voilà mon problème. Je souhaite utiliser une formule avec les fonction si, equiv et index mais là je ne m'en sors pas. La formule que j'ai essayé (entre autres) :

=SI(F2="Anglais";INDEX(Termes_Français;EQUIV(A6;Chrono3);SI(F2="Français";INDEX(Termes_Anglais;EQUIV(A6;Chrono3);"rien"))))

Ce que je souhaite obtenir : si j'affiche le mot "Français" dans une cellule il doit faire la recherche dans une colonne nommée "Termes_Français" (sur une autre feuille du classeur), si c'est anglais,il doit faire la recherche dans une autre colonne nommée "Termes_Anglais" et me renvoyer l'une ou l'autre valeur !

Cela fonctionne avec la première partie de la formule (il affiche bien les termes en français mais pas avec la deuxième (lorsque je saisi anglais), il affiche "FAUX" ??????

J'espère que ce n'est pas trop brouillon comme explication ????

Cela fait des heures que je suis sur cette formule. Si quelqu'un peut m'aider, please !

Bonjour sophie1313 ; bonjour tout le monde;
si j'ai bien compris votre question voilà une proposition à essayer:

=SI(F2=Vocabulaire!$B$3;INDEX(Termes_Français;EQUIV('QUIZ Vocabulaire'!$A6;Chrono3;0);1);INDEX(Termes_Anglais;EQUIV('QUIZ Vocabulaire'!$A6;Chrono3;0);1))

à essayer
Bon courage...
Salut Tibo

 

[ROGER2327]

Re : Fonctions combinée avec index et equiv

Bonsoir à tous

Deux autres essais :

=INDEX(DECALER(Base;;1+($F$2="Anglais");;1);EQUIV(A6;DECALER(Base;;;;1)))

=INDEX(Base;EQUIV(A6;DECALER(Base;;;;1));MAX(($F$2={"Français";"Anglais"})*{2;3}))

La deuxième est plus compliquée, mais pourrait facilement s'étendre à un choix sur plus de deux colonnes.
J'ai choisi de n'utiliser que la plage nommée Base car, en cas de modification, l'utilisation de plusieurs plages nommées oblige à des modifications plus pénibles.​

ROGER2327
#4904

Jeudi 26 Décervelage 138 (Escrime, V)
4 Pluviôse An CCXIX
2011-W03-7T23:13:51Z