Fonction SI

[Gexk5]

Bonsoir le forum, j'ai une formule avec plusieurs SI, mais ca me met une erreur quand je rajoute un autre SI, comment contourner ce problème???
Merci de vos reponses
Ma formule:
=SI(P23="R/H";1;SI(P23="Congés";2;SI(P23="Maladie";3;SI(P23="Glissement / Maladie";4;SI(P23="Glissement / Congés";5;SI(P23="Formation";6;SI(P23="Surcroit";7;SI(P23="Glissement";8))))))))

et je veux rajouter

SI(P23="Absent";9)
et la ERREUR

Excel 2000-2003

 

[Guest]

Re : Fonction SI

Bonsoir,

2 solutions:

=EQUIV(P23;{"R/H"."Congés"."Maladie"."Glissement / Maladie"."Glissement / Congés"."Formation"."Surcroit"."Glissement"."Absent"};0)

Ou en mettant tes valeurs dans une plage nommée:

=Equiv(P23;PlageNommée;0)

A+

 

[ROGER2327]

Re : Fonction SI

Bonjour Gexk5

Essayez ceci :

[COLOR=DarkSlateGray][B]=SI(ESTNA(EQUIV(P23;{"R/H";"Congés";"Maladie";" Glissement / Maladie";"Glissement / Congés";"Formation";"Surcroit";"Glissement";"Absent"};0));"";EQUIV(P23;{"R/H";"Congés";"Maladie";" Glissement / Maladie";"Glissement / Congés";"Formation";"Surcroit";"Glissement";"Absent"};0))[/B][/COLOR]

ROGER2327
#4513

Dimanche 8 As 138 (Saint Rimbe, Oisif, ST)
20 Brumaire An CCXIX
2010-W45-3T17:48:29Z

________________________________
Bonsoir Hasco…

 

[Gorfael]

Re : Fonction SI

Salut Gexk5 et le forum
Petite question : si(condition; nombre) ??? Et si la condition n'est pas remplie...
Une proposition :

= SI(P23="R/H";1;SI(P23="Congés";2;SI(P23="Maladie";3;SI(P23="Formation";6;SI(P23="Surcroit";7;SI(P23="Absent";9;"")))))) & SI(P23="Glissement";8;SI(P23="Glissement / Maladie";4; SI(P23="Glissement / Congés";5;"")))

A+

 

[laurentriv]

Re : Fonction SI

bonsoir, normalement tu peux voir 6 fonction Si imbriquées mais pas plus..apres il faut...etre un pro...lol

 

[Gexk5]

Re : Fonction SI

Re le forum,
Merci a tous pour vos reponses,
Pour repondre a Gorfael, si la condition n'est pas remplie, pas de soucis, la colonne ou est la formule est masquée

Je prend la 1ere soluce de Hasco, mais garde les autres en reserve, ca peut servir.

Encore un grand merci