Fonction perso

[elect31]

Bonjour à tous
Je cherche à construire une formule en colonne R, qui à partir de la valeur mini d'une ligne donnée dans les colonnes M à S me donnerait la valeur correspondante dans les colonnes U à AA.
Je m'explique : si ma valeur mini de C3:I3 est en C3, il me faut en retour la valeur de K3. Une espèce de =DECALER(MIN(C3:I3);;8) qui ne marche pas avec MIN, sinon je n'aurais pas fait appel à vous.

J'ai essayé de construire ma propre fonction perso APPUIS_BEST_PERF(Perfs) qui a un fonctionnement aléatoire, que je ne comprends pas. cf fichier joint

Merci de votre aide
PS: Sur Xl 2007 ET 2003

 

[Tibo]

Re : Fonction perso

Bonsoir,

Par formule, ça pourrait donner ceci :

=SI(NB(C3:I3)=0;"";INDEX(K3:Q3;EQUIV(MIN(C3:I3);C3:I3;0)))

à recopier vers le bas

Je te laisse tester, notamment pour les lignes où il n'y a pas de valeur dans le 2ème tableau correspondant à la valeur mini du 1er tableau.

@+

 

[Monique]

Re : Fonction perso

Bonjour,

A essayer :

=SI(NB(C3:I3);DECALER(J3;;EQUIV(MIN(C3:I3);C3:I3;0));"")

 

[elect31]

Re : Fonction perso

Je vous remercie tous les deux.
Les deux formules donnent exactement le même résultat.

 

[elect31]

Re : Fonction perso

Sans vouloir abuser, la formule serait au top si elle vérifiait auparavant si à la valeur mini du 1° tableau correspond une valeur au 2° tableau. Si ce n'était pas le cas, il faudrait prendre la 2° valeur mini (à condition qu'elle ait elle aussi une correspondance dans le 2° tableau).
Regardez l'éléve25, dont la valeur mini est 9.1 mais qui n'a pas de valeur en O27. Il faudrait prendre dans ce cas 9.18 en mini et renvoyer 555.
C'est + clair en regardant le fichier joint.
Merci

 

[Monique]

Re : Fonction perso

Re,


=SI(NB(C3:I3);DECALER(J3;;EQUIV(MIN(SI(K3:Q3<>"";C3:I3));C3:I3;0));"")

Formule matricielle, à valider par ctrl, maj et entrée
Reste aussi le cas où le 2ème tableau ne contient aucune valeur ?

 

[elect31]

Re : Fonction perso

Bèh oui t'as raison,... j'en ai besoin aussi...
Tu as une proposition s'il n'y a pas de valeur dans le 2° tableau?
Encore merci de la rapidité et de l'efficacité de tes réponses.

 

[Monique]

Re : Fonction perso

Re,

[FONT=Verdana]=SI(NB(C3:I3)*(MIN(SI(K3:Q3<>"";C3:I3)))>0;DECALER(J3;;EQUIV(MIN(SI(K3:Q3<>"";C3:I3));C3:I3;0));"")[/FONT]

Si le MIN(SI()) renvoie 0, on n’a pas de résultat, sinon, même formule

 

[elect31]

Re : Fonction perso

Là, je pense qu'il n'y a plus de cas à envisager. Je te remercie encore une fois.